<html><head><meta name="color-scheme" content="light dark"></head><body><pre style="word-wrap: break-word; white-space: pre-wrap;"># Copyright (c) 1997-2007 Graham Barr &lt;gbarr@pobox.com&gt;. All rights reserved.
# This program is free software; you can redistribute it and/or
# modify it under the same terms as Perl itself.
#
# Maintained since 2013 by Paul Evans &lt;leonerd@leonerd.org.uk&gt;

package Scalar::Util;

use strict;
use warnings;
require Exporter;

our @ISA       = qw(Exporter);
our @EXPORT_OK = qw(
  blessed refaddr reftype weaken unweaken isweak

  dualvar isdual isvstring looks_like_number openhandle readonly set_prototype
  tainted
);
our $VERSION    = "1.63";
$VERSION =~ tr/_//d;

require List::Util; # List::Util loads the XS
List::Util-&gt;VERSION( $VERSION ); # Ensure we got the right XS version (RT#100863)

# populating @EXPORT_FAIL is done in the XS code
sub export_fail {
  if (grep { /^isvstring$/ } @_ ) {
    require Carp;
    Carp::croak("Vstrings are not implemented in this version of perl");
  }

  @_;
}

# set_prototype has been moved to Sub::Util with a different interface
sub set_prototype(&amp;$)
{
  my ( $code, $proto ) = @_;
  return Sub::Util::set_prototype( $proto, $code );
}

1;

__END__

=head1 NAME

Scalar::Util - A selection of general-utility scalar subroutines

=head1 SYNOPSIS

    use Scalar::Util qw(blessed dualvar isdual readonly refaddr reftype
                        tainted weaken isweak isvstring looks_like_number
                        set_prototype);
                        # and other useful utils appearing below

=head1 DESCRIPTION

C&lt;Scalar::Util&gt; contains a selection of subroutines that people have expressed
would be nice to have in the perl core, but the usage would not really be high
enough to warrant the use of a keyword, and the size would be so small that 
being individual extensions would be wasteful.

By default C&lt;Scalar::Util&gt; does not export any subroutines.

=head2 Core Perl C&lt;builtin&gt; Functions

Many functions in this module have served as the inspiration for a new
experimental facility in recent versions of Perl. From various development
versions, starting at 5.35.7, equivalent functions to many of these utilities
are available in the C&lt;builtin::&gt; package.

    use Scalar::Util qw(blessed);

    $class = blessed $obj;

    $class = builtin::blessed $obj;  # equivalent

For more information, see the documentation on L&lt;builtin&gt;.

=cut

=head1 FUNCTIONS FOR REFERENCES

The following functions all perform some useful activity on reference values.

=head2 blessed

    my $pkg = blessed( $ref );

If C&lt;$ref&gt; is a blessed reference, the name of the package that it is blessed
into is returned. Otherwise C&lt;undef&gt; is returned.

    $scalar = "foo";
    $class  = blessed $scalar;           # undef

    $ref    = [];
    $class  = blessed $ref;              # undef

    $obj    = bless [], "Foo";
    $class  = blessed $obj;              # "Foo"

Take care when using this function simply as a truth test (such as in
C&lt;if(blessed $ref)...&gt;) because the package name C&lt;"0"&gt; is defined yet false.

I&lt;Since Perl version 5.35.7&gt; an equivalent function is available as
C&lt;builtin::blessed&gt;.

=head2 refaddr

    my $addr = refaddr( $ref );

If C&lt;$ref&gt; is reference, the internal memory address of the referenced value is
returned as a plain integer. Otherwise C&lt;undef&gt; is returned.

    $addr = refaddr "string";           # undef
    $addr = refaddr \$var;              # eg 12345678
    $addr = refaddr [];                 # eg 23456784

    $obj  = bless {}, "Foo";
    $addr = refaddr $obj;               # eg 88123488

I&lt;Since Perl version 5.35.7&gt; an equivalent function is available as
C&lt;builtin::refaddr&gt;.

=head2 reftype

    my $type = reftype( $ref );

If C&lt;$ref&gt; is a reference, the basic Perl type of the variable referenced is
returned as a plain string (such as C&lt;ARRAY&gt; or C&lt;HASH&gt;). Otherwise C&lt;undef&gt;
is returned.

    $type = reftype "string";           # undef
    $type = reftype \$var;              # SCALAR
    $type = reftype [];                 # ARRAY

    $obj  = bless {}, "Foo";
    $type = reftype $obj;               # HASH

Note that for internal reasons, all precompiled regexps (C&lt;qr/.../&gt;) are
blessed references; thus C&lt;ref()&gt; returns the package name string C&lt;"Regexp"&gt;
on these but C&lt;reftype()&gt; will return the underlying C structure type of
C&lt;"REGEXP"&gt; in all capitals.

I&lt;Since Perl version 5.35.7&gt; an equivalent function is available as
C&lt;builtin::reftype&gt;.

=head2 weaken

    weaken( $ref );

The lvalue C&lt;$ref&gt; will be turned into a weak reference. This means that it
will not hold a reference count on the object it references. Also, when the
reference count on that object reaches zero, the reference will be set to
undef. This function mutates the lvalue passed as its argument and returns no
value.

This is useful for keeping copies of references, but you don't want to prevent
the object being DESTROY-ed at its usual time.

    {
      my $var;
      $ref = \$var;
      weaken($ref);                     # Make $ref a weak reference
    }
    # $ref is now undef

Note that if you take a copy of a scalar with a weakened reference, the copy
will be a strong reference.

    my $var;
    my $foo = \$var;
    weaken($foo);                       # Make $foo a weak reference
    my $bar = $foo;                     # $bar is now a strong reference

This may be less obvious in other situations, such as C&lt;grep()&gt;, for instance
when grepping through a list of weakened references to objects that may have
been destroyed already:

    @object = grep { defined } @object;

This will indeed remove all references to destroyed objects, but the remaining
references to objects will be strong, causing the remaining objects to never be
destroyed because there is now always a strong reference to them in the @object
array.

I&lt;Since Perl version 5.35.7&gt; an equivalent function is available as
C&lt;builtin::weaken&gt;.

=head2 unweaken

    unweaken( $ref );

I&lt;Since version 1.36.&gt;

The lvalue C&lt;REF&gt; will be turned from a weak reference back into a normal
(strong) reference again. This function mutates the lvalue passed as its
argument and returns no value. This undoes the action performed by
L&lt;/weaken&gt;.

This function is slightly neater and more convenient than the
otherwise-equivalent code

    my $tmp = $REF;
    undef $REF;
    $REF = $tmp;

(because in particular, simply assigning a weak reference back to itself does
not work to unweaken it; C&lt;$REF = $REF&gt; does not work).

I&lt;Since Perl version 5.35.7&gt; an equivalent function is available as
C&lt;builtin::unweaken&gt;.

=head2 isweak

    my $weak = isweak( $ref );

Returns true if C&lt;$ref&gt; is a weak reference.

    $ref  = \$foo;
    $weak = isweak($ref);               # false
    weaken($ref);
    $weak = isweak($ref);               # true

B&lt;NOTE&gt;: Copying a weak reference creates a normal, strong, reference.

    $copy = $ref;
    $weak = isweak($copy);              # false

I&lt;Since Perl version 5.35.7&gt; an equivalent function is available as
C&lt;builtin::is_weak&gt;.

=head1 OTHER FUNCTIONS

=head2 dualvar

    my $var = dualvar( $num, $string );

Returns a scalar that has the value C&lt;$num&gt; in a numeric context and the value
C&lt;$string&gt; in a string context.

    $foo = dualvar 10, "Hello";
    $num = $foo + 2;                    # 12
    $str = $foo . " world";             # Hello world

=head2 isdual

    my $dual = isdual( $var );

I&lt;Since version 1.26.&gt;

If C&lt;$var&gt; is a scalar that has both numeric and string values, the result is
true.

    $foo = dualvar 86, "Nix";
    $dual = isdual($foo);               # true

Note that a scalar can be made to have both string and numeric content through
standard operations:

    $foo = "10";
    $dual = isdual($foo);               # false
    $bar = $foo + 0;
    $dual = isdual($foo);               # true

The C&lt;$!&gt; variable is commonly dual-valued, though it is also magical in other
ways:

    $! = 1;
    $dual = isdual($!);                 # true
    print("$!\n");                      # "Operation not permitted"

B&lt;CAUTION&gt;: This function is not as useful as it may seem. Dualvars are not a
distinct concept in Perl, but a standard internal construct of all scalar
values. Almost any value could be considered as a dualvar by this function
through the course of normal operations.

=head2 isvstring

    my $vstring = isvstring( $var );

If C&lt;$var&gt; is a scalar which was coded as a vstring, the result is true.

    $vs   = v49.46.48;
    $fmt  = isvstring($vs) ? "%vd" : "%s"; #true
    printf($fmt,$vs);

=head2 looks_like_number

    my $isnum = looks_like_number( $var );

Returns true if perl thinks C&lt;$var&gt; is a number. See
L&lt;perlapi/looks_like_number&gt;.

=head2 openhandle

    my $fh = openhandle( $fh );

Returns C&lt;$fh&gt; itself, if C&lt;$fh&gt; may be used as a filehandle and is open, or if
it is a tied handle. Otherwise C&lt;undef&gt; is returned.

    $fh = openhandle(*STDIN);           # \*STDIN
    $fh = openhandle(\*STDIN);          # \*STDIN
    $fh = openhandle(*NOTOPEN);         # undef
    $fh = openhandle("scalar");         # undef

=head2 readonly

    my $ro = readonly( $var );

Returns true if C&lt;$var&gt; is readonly.

    sub foo { readonly($_[0]) }

    $readonly = foo($bar);              # false
    $readonly = foo(0);                 # true

=head2 set_prototype

    my $code = set_prototype( $code, $prototype );

Sets the prototype of the function given by the C&lt;$code&gt; reference, or deletes
it if C&lt;$prototype&gt; is C&lt;undef&gt;. Returns the C&lt;$code&gt; reference itself.

    set_prototype \&amp;foo, '$$';

=head2 tainted

    my $t = tainted( $var );

Return true if C&lt;$var&gt; is tainted.

    $taint = tainted("constant");       # false
    $taint = tainted($ENV{PWD});        # true if running under -T

=head1 DIAGNOSTICS

Module use may give one of the following errors during import.

=over

=item Vstrings are not implemented in this version of perl

The version of perl that you are using does not implement Vstrings, to use
L&lt;/isvstring&gt; you will need to use a newer release of perl.

=back

=head1 KNOWN BUGS

There is a bug in perl5.6.0 with UV's that are &gt;= 1&lt;&lt;31. This will
show up as tests 8 and 9 of dualvar.t failing

=head1 SEE ALSO

L&lt;List::Util&gt;

=head1 COPYRIGHT

Copyright (c) 1997-2007 Graham Barr &lt;gbarr@pobox.com&gt;. All rights reserved.
This program is free software; you can redistribute it and/or modify it
under the same terms as Perl itself.

Additionally L&lt;/weaken&gt; and L&lt;/isweak&gt; which are

Copyright (c) 1999 Tuomas J. Lukka &lt;lukka@iki.fi&gt;. All rights reserved.
This program is free software; you can redistribute it and/or modify it
under the same terms as perl itself.

Copyright (C) 2004, 2008  Matthijs van Duin.  All rights reserved.
Copyright (C) 2014 cPanel Inc.  All rights reserved.
This program is free software; you can redistribute it and/or modify
it under the same terms as Perl itself.

=cut
</pre></body></html>