<html><head><meta name="color-scheme" content="light dark"></head><body><pre style="word-wrap: break-word; white-space: pre-wrap;">package Algorithm::Merge;

use Algorithm::Diff ();
use Carp;
use strict;
use Data::Dumper;

use vars qw(@EXPORT_OK @ISA $VERSION $REVISION);

$VERSION = '0.08';

$REVISION = (qw$Revision: 1.11 $)[-1];

@EXPORT_OK = qw(diff3 merge traverse_sequences3);

@ISA = qw(Exporter);

sub diag {
    main::diag(@_) if($Algorithm::Merge::DEBUG);
}

sub diff3 {
    my $pivot             = shift;                                  # array ref
    my $doca              = shift;                                  # array ref
    my $docb              = shift;                                  # array ref
    my $keyGen            = shift;

    my @ret;

    if(@$doca == 0 &amp;&amp; @$docb == 0 &amp;&amp; @$pivot == 0) {
      return [ [ ] ];
    }

    my $no_change;

#    if($keyGen) {
#        $no_change = sub {
#            if($keyGen-&gt;($pivot -&gt; [$_[0]]) ne $keyGen-&gt;($doca -&gt; [$_[1]])
#               || $keyGen-&gt;($pivot -&gt; [$_[0]]) ne $keyGen-&gt;($docb -&gt; [$_[2]])
#               || $keyGen-&gt;($doca -&gt; [$_[1]]) ne $keyGen-&gt;($docb -&gt; [$_[2]]))
#            {
#               croak "No change detected, but elements differ between sequences.  Please submit a bug report to jsmith\@cpan.org with a description of the set of sequences which lead to this error.\n";
#            }
#            push @ret, [ 'u', $pivot -&gt; [$_[0]], $doca -&gt; [$_[1]], $docb -&gt; [$_[2]] ];
#        };
#    }
#    else {
        $no_change = sub {
#            if($pivot -&gt; [$_[0]] ne $doca -&gt; [$_[1]]
#               || $pivot -&gt; [$_[0]] ne $docb -&gt; [$_[2]]
#               || $doca -&gt; [$_[1]] ne $docb -&gt; [$_[2]])
#            {
#               croak "No change detected, but elements differ between sequences.  Please submit a bug report to jsmith\@cpan.org with a description of the set of sequences which lead to this error.\n";
#            }
            push @ret, [ 'u', $pivot -&gt; [$_[0]], $doca -&gt; [$_[1]], $docb -&gt; [$_[2]] ];
        };
#    }

    my $conflict = sub {
        my($a, $b, $c);
        $a = $pivot -&gt; [$_[0]] if defined $_[0];
        $b = $doca -&gt; [$_[1]] if defined $_[1];
        $c = $docb -&gt; [$_[2]] if defined $_[2];
        push @ret, [ 'c', $a, $b, $c ];
    };

    my $diff_a = sub {
        if(@_ == 1) {
            push @ret, [ 'o', $pivot -&gt; [$_[0]], undef, undef ];
        }
        elsif(@_ == 2) {
            push @ret, [ 'o', undef, $doca -&gt; [$_[0]], $docb -&gt; [$_[1]] ];
        }
        elsif(@_ == 3) {
            push @ret, [ 'o', $pivot -&gt; [$_[0]], $doca -&gt; [$_[1]], $docb -&gt; [$_[2]] ];
        }
    };

    my $diff_b = sub {
        if(@_ == 1) {
            push @ret, [ 'l', undef, $doca -&gt; [$_[0]], undef ];
        }
        elsif(@_ == 2) {
            push @ret, [ 'l', $pivot -&gt; [$_[0]], undef, $docb -&gt; [$_[1]] ];
        }
        elsif(@_ == 3) {
            push @ret, [ 'l', $pivot -&gt; [$_[0]], $doca -&gt; [$_[1]], $docb -&gt; [$_[2]] ];
        }
    };

    my $diff_c = sub {
        if(@_ == 1) {
            push @ret, [ 'r', undef, undef, (defined($_[0]) ? $docb -&gt; [$_[0]] : undef) ];
        }
        elsif(@_ == 2) {
            push @ret, [ 'r', (defined($_[0]) ? $pivot -&gt; [$_[0]] : undef), (defined($_[1]) ? $doca -&gt; [$_[1]] : undef), undef ];
        }
        elsif(@_ == 3) {
            push @ret, [ 'r', (defined($_[0]) ? $pivot -&gt; [$_[0]] : undef), (defined($_[1]) ? $doca -&gt; [$_[1]] : undef), (defined($_[0]) ? $docb -&gt; [$_[2]] : undef)];
        }
    };

    traverse_sequences3(
        $pivot, $doca, $docb, 
        {
            NO_CHANGE =&gt; $no_change,
            A_DIFF  =&gt; $diff_a,
            B_DIFF  =&gt; $diff_b,
            C_DIFF   =&gt; $diff_c,
            CONFLICT  =&gt; $conflict,
        }, 
        $keyGen, @_
    );

    if(wantarray) {
        return @ret;
    }
    else {
        return \@ret;
    }
}

use constant A =&gt; 4;
use constant B =&gt; 2;
use constant C =&gt; 1;
use constant D =&gt; 8;  # should be an undef

use constant AB_A =&gt; 32;
use constant AB_B =&gt; 16;
use constant AC_A =&gt;  8;
use constant AC_C =&gt;  4;
use constant BC_B =&gt;  2;
use constant BC_C =&gt;  1;
use constant CB_C =&gt;  3;  # not used in calculations
use constant CB_B =&gt;  5;  # not used in calculations

my @abc_s;
$abc_s[(A|B)*8+A] = AB_A;
$abc_s[(A|B)*8+B] = AB_B;
$abc_s[(A|C)*8+A] = AC_A;
$abc_s[(A|C)*8+C] = AC_C;
$abc_s[(B|C)*8+B] = BC_B;
$abc_s[(B|C)*8+C] = BC_C;

sub traverse_sequences3 {
    my $adoc      = shift;                                  # array ref
    my $bdoc      = shift;                                  # array ref
    my $cdoc      = shift;                                  # array ref
    my $callbacks = shift || {};
    my $keyGen    = shift;
    my $a_diff     = $callbacks-&gt;{'A_DIFF'} || sub { };
    my $b_diff     = $callbacks-&gt;{'B_DIFF'} || sub { };
    my $c_diff     = $callbacks-&gt;{'C_DIFF'} || sub { };
    my $no_change = $callbacks-&gt;{'NO_CHANGE'} || sub { };
    my $conflict  = $callbacks-&gt;{'CONFLICT'} || sub { };

    my $b_len = scalar(@{$bdoc});
    my $c_len = scalar(@{$cdoc});
    my $target_len = $b_len &lt; $c_len ? $b_len : $c_len;
    my $bc_different_lengths = $b_len != $c_len;

    my(@bdoc_save, @cdoc_save);

    # make these into traverse_sequences calls
    my($left, $right);
    my %diffs;

    my $ts_callbacks = {
        DISCARD_A =&gt; sub { # discard left
            push @{$diffs{$left}}, $_[0];
        },
        DISCARD_B =&gt; sub { # discard right
            push @{$diffs{$right}}, $_[1];
        },
    };

    @diffs{(AB_A, AB_B)} = ([], []);
    $left = AB_A; $right = AB_B;
    Algorithm::Diff::traverse_sequences( $adoc, $bdoc, $ts_callbacks, $keyGen, @_);

    @diffs{(AC_A, AC_C)} = ([], []);
    $left = AC_A; $right = AC_C;
    Algorithm::Diff::traverse_sequences( $adoc, $cdoc, $ts_callbacks, $keyGen, @_);

    if($bc_different_lengths) {
        
        @diffs{(CB_C, CB_B)} = ([], []);
        $left = CB_C; $right = CB_B;
        Algorithm::Diff::traverse_sequences( $cdoc, $bdoc, $ts_callbacks, $keyGen, @_);

        @diffs{(BC_B, BC_C)} = ([], []);  
        $left = BC_B; $right = BC_C; 
        Algorithm::Diff::traverse_sequences( $bdoc, $cdoc, $ts_callbacks, $keyGen, @_);

        if(join(",", @{$diffs{&amp;CB_B}}) ne join(",", @{$diffs{&amp;BC_B}}) ||
           join(",", @{$diffs{&amp;CB_C}}) ne join(",", @{$diffs{&amp;BC_C}}))
        {
            @bdoc_save = splice @{$bdoc}, $target_len;
            @cdoc_save = splice @{$cdoc}, $target_len;
            
            carp "Algorithm::Diff::diff is not symmetric for second and third sequences - results might not be correct";
        }

        @diffs{(BC_B, BC_C)} = ([], []);
        $left = BC_B; $right = BC_C;
        Algorithm::Diff::traverse_sequences( $bdoc, $cdoc, $ts_callbacks, $keyGen, @_);

        if(scalar(@bdoc_save) || scalar(@cdoc_save)) {
            push @{$diffs{&amp;BC_B}}, ($target_len .. $b_len) if $target_len &lt; $b_len;
            push @{$diffs{&amp;BC_C}}, ($target_len .. $c_len) if $target_len &lt; $c_len;
        
            push @{$bdoc}, @bdoc_save; undef @bdoc_save;
            push @{$cdoc}, @cdoc_save; undef @cdoc_save;
        }
    }
    else {
        @diffs{(BC_B, BC_C)} = ([], []);
        $left = BC_B; $right = BC_C;
        Algorithm::Diff::traverse_sequences( $bdoc, $cdoc, $ts_callbacks, $keyGen, @_);
    }

    my @pos;
    @pos[A, B, C] = (0, 0, 0);

    my @sizes;
    @sizes[A, B, C] = ( scalar(@{$adoc}), scalar(@{$bdoc}), scalar(@{$cdoc}) );

    my @matches;
    $#matches = 32;

    my $callback = 0;

    my $noop = sub { };

# Callback_Map is indexed by the sum of AB_A, AB_B, ..., as indicated by @matches
# this isn't the most efficient, but it's a bit easier to maintain and 
# read than if it were broken up into separate arrays
# half the entries are not $noop - it would seem then that no 
# entries should be $noop.  I need patterns to figure out what the 
# other entries are.

    my @Callback_Map = (
      [ $no_change,     A, B, C ], # 0  - no matches
      #[ $noop,                  ], # 1  -                          BC_C
      [ $b_diff,        A,    C ], # 1  -                          BC_C
      [ $b_diff,           B    ], #*2  -                     BC_B
      [ $noop,                  ], # 3  -                     BC_B BC_C
      [ $noop,                  ], # 4  -                AC_C
      [ $c_diff,              C ], # 5  -                AC_C      BC_C
      [ $noop,                  ], # 6  -                AC_C BC_B
      [ $noop,                  ], # 7  -                AC_C BC_B BC_C
      [ $a_diff,        A       ], # 8  -           AC_A
      [ $noop,                  ], # 9  -           AC_A           BC_C
      [ $c_diff,        A, B    ], # 10 -           AC_A      BC_B
      [ $c_diff,        A, B,   ], # 11 -           AC_A      BC_B BC_C
      [ $noop,                  ], # 12 -           AC_A AC_C
      [ $noop,                  ], # 13 -           AC_A AC_C      BC_C
      [ $c_diff,        A, B,   ], # 14 -           AC_A AC_C BC_B
      [ $c_diff,        A, B, C ], # 15 -           AC_A AC_C BC_B BC_C
      [ $noop,                  ], # 16 -      AB_B
      [ $no_change,             ], # 17 -      AB_B                BC_C
      [ $b_diff,           B    ], # 18 -      AB_B           BC_B
      [ $noop,                  ], # 19 -      AB_B           BC_B BC_C
      [ $a_diff,           B, C ], # 20 -      AB_B      AC_C
      [ $noop,                  ], # 21 -      AB_B      AC_C      BC_C
      [ $noop,                  ], # 22 -      AB_B      AC_C BC_B
      [ $conflict,      D, B, C ], # 23 -      AB_B      AC_C BC_B BC_C
      [ $b_diff,           B    ], # 24 -      AB_B AC_A
      [ $noop,                  ], # 25 -      AB_B AC_A           BC_C
      [ $c_diff,        D, B, C ], # 26 -      AB_B AC_A      BC_B
      [ $noop,                  ], # 27 -      AB_B AC_A      BC_B BC_C
      [ $a_diff,           B, C ], # 28 -      AB_B AC_A AC_C
      [ $noop,                  ], # 29 -      AB_B AC_A AC_C      BC_C
      [ $noop,                  ], # 30 -      AB_B AC_A AC_C BC_B
      [ $b_diff,           B    ], # 31 -      AB_B AC_A AC_C BC_B BC_C
      [ $no_change,     A, B, C ], # 32 - AB_A
      [ $b_diff,        A,    C ], # 33 - AB_A                     BC_C
      [ $noop,                  ], # 34 - AB_A                BC_B
      [ $b_diff,        A,    C ], # 35 - AB_A                BC_B BC_C
      [ $noop,                  ], # 36 - AB_A           AC_C
      [ $noop,                  ], # 37 - AB_A           AC_C      BC_C
      [ $noop,                  ], # 38 - AB_A           AC_C BC_B
      [ $noop,                  ], # 39 - AB_A           AC_C BC_B BC_C
      [ $a_diff,        A,      ], # 40 - AB_A      AC_A
      [ $noop,                  ], # 41 - AB_A      AC_A           BC_C
      [ $a_diff,        A       ], # 42 - AB_A      AC_A      BC_B
      [ $noop,                  ], # 43 - AB_A      AC_A      BC_B BC_C
      [ $noop,                  ], # 44 - AB_A      AC_A AC_C
      [ $c_diff,        A, D, C ], # 45 - AB_A      AC_A AC_C      BC_C
      [ $noop,                  ], # 46 - AB_A      AC_A AC_C BC_B
      [ $noop,                  ], # 47 - AB_A      AC_A AC_C BC_B BC_C
      [ $noop,                  ], # 48 - AB_A AB_B
      [ $b_diff,        A,    C ], # 49 - AB_A AB_B                BC_C
      [ $noop,                  ], # 50 - AB_A AB_B           BC_B
      [ $b_diff,        A, B, C ], # 51 - AB_A AB_B           BC_B BC_C
      [ $a_diff,           B, C ], # 52 - AB_A AB_B      AC_C
      [ $noop,                  ], # 53 - AB_A AB_B      AC_C      BC_C
      [ $noop,                  ], # 54 - AB_A AB_B      AC_C BC_B
      [ $c_diff,              C ], # 55 - AB_A AB_B      AC_C BC_B BC_C
      [ $b_diff,        A,    C ], # 56 - AB_A AB_B AC_A
      [ $noop,                  ], # 57 - AB_A AB_B AC_A           BC_C
      [ $b_diff,        A, B, D ], # 58 - AB_A AB_B AC_A      BC_B
      [ $noop,                  ], # 59 - AB_A AB_B AC_A      BC_B BC_C
      [ $a_diff,        A, B, C ], # 60 - AB_A AB_B AC_A AC_C
      [ $conflict,      A, D, C ], # 61 - AB_A AB_B AC_A AC_C      BC_C
      [ $conflict,      A, B, D ], # 62 - AB_A AB_B AC_A AC_C BC_B
      [ $conflict,      A, B, C ], # 63 - AB_A AB_B AC_A AC_C BC_B BC_C
    );

    my $t; # temporary values

    # while we have something to work with...
    while((grep { scalar(@{$_}) &gt; 0 } values %diffs) 
          &amp;&amp; (grep { $pos[$_] &lt; $sizes[$_] } (A, B, C))) 
    {

        @matches[AB_A, AB_B, AC_A, AC_C, BC_B, BC_C] = undef;

        foreach my $i (A, B, C) {
            foreach my $j (A, B, C) {
                next if $i == $j;
                $t = $abc_s[($i|$j) * 8 | $i];
                $matches[$t] = 1 if @{$diffs{$t}} &amp;&amp; $pos[$i] == $diffs{$t} -&gt; [0];
            }
        }
   
        $callback = 0;
        $callback |= $_ foreach grep { $matches[$_] } ( AB_A, AB_B, AC_A, AC_C, BC_B, BC_C );

        my @args = @{$Callback_Map[$callback]};
        diag("&gt;&gt;&gt;&gt;&gt;&gt;    We hit a noop") if @args == 1;
        my $f = shift @args;
        diag(join "", "callback: $callback - \@pos: ", join(", ", @pos[A, B, C]), "\n");
        diag("&gt;&gt;&gt;&gt;&gt;&gt;    Callback is a no-op") unless @args;
        diag(join "", "  matches: ", join(", ", map { defined($_) ? $_ : 'undef' } @matches[AB_A, AB_B, AC_A, AC_C, BC_B, BC_C]), "\n");
        diag(join "", " diffs: ", join(", ", map { defined($_) ? $_ : 'undef' } map { $diffs{$_}-&gt;[0] } (AB_A, AB_B, AC_A, AC_C, BC_B, BC_C)), "\n");
        diag(join "", "args: ", join(", ", map { (qw(- C B - A - - - D))[$_] } @args), "(", join(", ", map { defined($_) ? $_ : 'undef' } @pos[@args]), ")\n");
        diag('--------------------');
        &amp;{$f}(@pos[@args]);
        foreach (@args) {
            $pos[$_]++ unless $_ == D;
            if($_ eq A) {
                shift @{$diffs{&amp;AB_A}} while @{$diffs{&amp;AB_A}} &amp;&amp; $diffs{&amp;AB_A}[0] &lt; $pos[$_];# if $matches[AB_A];
                shift @{$diffs{&amp;AC_A}} while @{$diffs{&amp;AC_A}} &amp;&amp; $diffs{&amp;AC_A}[0] &lt; $pos[$_];#if $matches[AC_A];
            } elsif($_ eq B) {
                shift @{$diffs{&amp;AB_B}} while @{$diffs{&amp;AB_B}} &amp;&amp; $diffs{&amp;AB_B}[0] &lt; $pos[$_];#if $matches[AB_B];
                shift @{$diffs{&amp;BC_B}} while @{$diffs{&amp;BC_B}} &amp;&amp; $diffs{&amp;BC_B}[0] &lt; $pos[$_];#if $matches[BC_B];
            } elsif($_ eq C) {
                shift @{$diffs{&amp;AC_C}} while @{$diffs{&amp;AC_C}} &amp;&amp; $diffs{&amp;AC_C}[0] &lt; $pos[$_];#if $matches[AC_C];
                shift @{$diffs{&amp;BC_C}} while @{$diffs{&amp;BC_C}} &amp;&amp; $diffs{&amp;BC_C}[0] &lt; $pos[$_];#if $matches[BC_C];
            }
        }
        last unless @args;
    }

    my $switch;
    my @args;

    while(grep { $pos[$_] &lt; $sizes[$_] } (A, B, C)) {
        $switch = 0;
        @args = ();
        foreach my $i (A, B, C) {
            if($pos[$i] &lt; $sizes[$i]) {
                #warn "$i: $pos[$i] &lt; $sizes[$i]\n";
                $switch |= $i;
                #warn "switch: $switch\n";
                push @args, $pos[$i]++;
            }
        }

        my $match = $switch;
        $switch = ( 0, 5, 24, 17, 34, 8, 10, 0 )[$switch];
        #main::diag(join"", "callback: $switch - \@pos: ", join(", ", @pos[A, B, C]));
        #main::diag(join"", "  match: $match");
        &amp;{$Callback_Map[$switch][0]}(@args)
            if $Callback_Map[$switch];
    }
}

sub merge {
    my $pivot             = shift;                                  # array ref
    my $doca              = shift;                                  # array ref
    my $docb              = shift;                                  # array ref
    my $callbacks         = shift || {};
    my $keyGen            = shift;

    my $conflictCallback  = $callbacks -&gt; {'CONFLICT'} || sub ($$) { (
        q{&lt;!-- ------ START CONFLICT ------ --&gt;},
        (@{$_[0]}),
        q{&lt;!-- ---------------------------- --&gt;},
        (@{$_[1]}),
        q{&lt;!-- ------  END  CONFLICT ------ --&gt;},
    ) };

    my $diff = diff3($pivot, $doca, $docb, $keyGen, @_);

#    print Data::Dumper -&gt; Dump([$diff]), "\n";

    my @ret;

    my @conflict = ( [], [] );

    foreach my $h (@{$diff}) {
        my $i = 0;
        #print "op: ", $h -&gt; [0];
        if($h -&gt; [0] eq 'c') { # conflict
            push @{$conflict[0]}, $h -&gt; [2] if defined $h -&gt; [2];
            push @{$conflict[1]}, $h -&gt; [3] if defined $h -&gt; [3];
        }
        else {
            if(@{$conflict[0]} || @{$conflict[1]}) {
                push @ret, &amp;$conflictCallback(@conflict);
                @conflict = ( [], [] );
            }
            if($h -&gt; [0] eq 'u') { # unchanged
                push @ret, $h -&gt; [2] || $h -&gt; [3];
            }
            elsif($h -&gt; [0] eq 'o') { # added
                push @ret, $h -&gt; [2] if defined $h -&gt; [2];
            }
            elsif($h -&gt; [0] eq 'l') { # added by left
                push @ret, $h -&gt; [2] if defined $h -&gt; [2];
            }
            elsif($h -&gt; [0] eq 'r') { # added by right
                push @ret, $h -&gt; [3] if defined $h -&gt; [3];
            }
        }
        #print " : ", join(" ", @ret), " [$$h[1],$$h[2],$$h[3]]\n";
    }

    if(@{$conflict[0]} || @{$conflict[1]}) {
        push @ret, &amp;$conflictCallback(@conflict);
    }

    if(wantarray) {
        return @ret;
    }
    return \@ret;
}


__END__
#
# For testing:
#
sub main::diag {
    warn join("", @_) , "\n";
}

print join(" ", merge(
#print Data::Dumper -&gt; Dump([
#    merge(
#    #[qw(a b c d       h i j)], # ancestor
#    #[qw(a b c d   f   h i j)], # left
#    #[qw(a b c   e   g      )], # right
    [qw(0 1 2 3 4 7 9 b)],
    [qw(0 6       8 a b)],
    [qw(0 1 2 3 5 8 a b)],
##
    {
        CONFLICT =&gt; sub ($$) { (
            q{&lt;}, @{$_[0]}, q{|}, @{$_[1]}, q{&gt;}
        ) },
    },
)), "\n";
#)]), "\n";
#print join(" ", @{
#    [qw(0 1 @ &lt; 3 | # &gt; 6)]
#  }), "\n";

1;
__END__


1;

__END__

=head1 NAME

Algorithm::Merge - Three-way merge and diff

=head1 SYNOPSIS

 use Algorithm::Merge qw(merge diff3 traverse_sequences3);

 @merged = merge(\@ancestor, \@a, \@b, { 
               CONFLICT =&gt; sub { } 
           });

 @merged = merge(\@ancestor, \@a, \@b, { 
               CONFLICT =&gt; sub { } 
           }, $key_generation_function);

 $merged = merge(\@ancestor, \@a, \@b, { 
               CONFLICT =&gt; sub { } 
           });

 $merged = merge(\@ancestor, \@a, \@b, { 
               CONFLICT =&gt; sub { } 
           }, $key_generation_function);

 @diff   = diff3(\@ancestor, \@a, \@b);

 @diff   = diff3(\@ancestor, \@a, \@b, $key_generation_function);

 $diff   = diff3(\@ancestor, \@a, \@b);

 $diff   = diff3(\@ancestor, \@a, \@b, $key_generation_function);

 @trav   = traverse_sequences3(\@ancestor, \@a, \@b, { 
               # callbacks
           });

 @trav   = traverse_sequences3(\@ancestor, \@a, \@b, { 
               # callbacks
           }, $key_generation_function);

 $trav   = traverse_sequences3(\@ancestor, \@a, \@b, { 
               # callbacks
           });

 $trav   = traverse_sequences3(\@ancestor, \@a, \@b, { 
               # callbacks
           }, $key_generation_function);


=head1 USAGE

This module complements L&lt;Algorithm::Diff|Algorithm::Diff&gt; by 
providing three-way merge and diff functions.

In this documentation, the first list to C&lt;diff3&gt;, C&lt;merge&gt;, and 
C&lt;traverse_sequences3&gt; is 
called the `original' list.  The second list is the `left' list.  The 
third list is the `right' list.

The optional key generation arguments are the same as in 
L&lt;Algorithm::Diff|Algorithm::Diff&gt;.  See L&lt;Algorithm::Diff&gt; for more 
information.

=head2 diff3

Given references to three lists of items, C&lt;diff3&gt; performs a 
three-way difference.

This function returns an array of operations describing how the 
left and right lists differ from the original list.  In scalar 
context, this function returns a reference to such an array.

Perhaps an example would be useful.

Given the following three lists,

  original: a b c   e f   h i   k
      left: a b   d e f g   i j k
     right: a b c d e     h i j k

     merge: a b   d e   g   i j k

we have the following result from diff3:

 [ 'u', 'a',   'a',   'a' ],
 [ 'u', 'b',   'b',   'b' ],
 [ 'l', 'c',   undef, 'c' ],
 [ 'o', undef, 'd',   'd' ],
 [ 'u', 'e',   'e',   'e' ],
 [ 'r', 'f',   'f',   undef ], 
 [ 'o', 'h',   'g',   'h' ],
 [ 'u', 'i',   'i',   'i' ],
 [ 'o', undef, 'j',   'j' ],
 [ 'u', 'k',   'k',   'k' ]

The first element in each row is the array with the difference:

 c - conflict (no two are the same)
 l - left is different 
 o - original is different
 r - right is different
 u - unchanged

The next three elements are the lists from the original, left, 
and right arrays respectively that the row refers to (in the synopsis,
these are C&lt;@ancestor&gt;, C&lt;@a&gt;, and C&lt;@b&gt;, respectively).

=head2 merge

Given references to three lists of items, C&lt;merge&gt; performs a three-way 
merge.  The C&lt;merge&gt; function uses the C&lt;diff3&gt; function to do most of 
the work.

The only callback currently used is C&lt;CONFLICT&gt; which should be a 
reference to a subroutine that accepts two array references.  The 
first array reference is to a list of elements from the left list.  
The second array reference is to a list of elements from the right list.
This callback should return a list of elements to place in the merged 
list in place of the conflict.

The default C&lt;CONFLICT&gt; callback returns the following:

 q{&lt;!-- ------ START CONFLICT ------ --&gt;},
 (@left),
 q{&lt;!-- ---------------------------- --&gt;},
 (@right),
 q{&lt;!-- ------  END  CONFLICT ------ --&gt;},

=head2 traverse_sequences3

This is the workhorse function that goes through the three sequences 
and calls the callback functions.

The following callbacks are supported.

=over 4

=item NO_CHANGE

This is called if all three sequences have the same element at the 
current position.  The arguments are the current positions within each 
sequence, the first argument being the current position within the 
first sequence.

=item A_DIFF

This is called if the first sequence is different than the other two 
sequences at the current position.
This callback will be called with one, two, or three arguments.

If one argument, then only the element at the given position from the 
first sequence is not in either of the other two sequences.

If two arguments, then there is no element in the first sequence that 
corresponds to the elements at the given positions in the second and 
third sequences.

If three arguments, then the element at the given position in the first 
sequence is different than the corresponding element in the other two 
sequences, but the other two sequences have corresponding elements.

=item B_DIFF

This is called if the second sequence is different than the other two 
sequences at the current position.
This callback will be called with one, two, or three arguments.   

If one argument, then only the element at the given position from the 
second sequence is not in either of the other two sequences.

If two arguments, then there is no element in the second sequence that 
corresponds to the elements at the given positions in the first and 
third sequences.

If three arguments, then the element at the given position in the second 
sequence is different than the corresponding element in the other two 
sequences, but the other two sequences have corresponding elements.

=item C_DIFF

This is called if the third sequence is different than the other two 
sequences at the current position.
This callback will be called with one, two, or three arguments.   

If one argument, then only the element at the given position from the 
third sequence is not in either of the other two sequences.

If two arguments, then there is no element in the third sequence that 
corresponds to the elements at the given positions in the first and 
second sequences.

If three arguments, then the element at the given position in the third 
sequence is different than the corresponding element in the other two 
sequences, but the other two sequences have corresponding elements.

=item CONFLICT

This is called if all three sequences have different elements at the 
current position.  The three arguments are the current positions within 
each sequence.

=back

=head1 BUGS

Most assuredly there are bugs.  If a pattern similar to the above 
example does not work, send it to &lt;jsmith@cpan.org&gt; or report it on 
&lt;http://rt.cpan.org/&gt;, the CPAN bug tracker.

L&lt;Algorithm::Diff|Algorithm::Diff&gt;'s implementation of 
C&lt;traverse_sequences&gt; may not be symmetric with respect to the input 
sequences if the second and third sequence are of different lengths.  
Because of this, C&lt;traverse_sequences3&gt; will calculate the diffs of 
the second and third sequences as passed and swapped.  If the differences 
are not the same, it will issue an `Algorithm::Diff::diff is not symmetric 
for second and third sequences...' warning.  It will try to handle 
this, but there may be some cases where it can't.

=head1 SEE ALSO

L&lt;Algorithm::Diff&gt;.

=head1 AUTHOR

James G. Smith, &lt;jsmith@cpan.org&gt;

=head1 COPYRIGHT

Copyright (C) 2003, 2007  Texas A&amp;M University.  All Rights Reserved.

This module is free software; you may redistribute it and/or
modify it under the same terms as Perl itself.
</pre></body></html>