<html><head><meta name="color-scheme" content="light dark"></head><body><pre style="word-wrap: break-word; white-space: pre-wrap;">#!/usr/bin/perl -w
# $Revision: 1.7 $
# Lists the zipfile given as a first argument and tests CRC's.
# Usage:
#	perl ziptest.pl zipfile.zip

use strict;

use Archive::Zip qw(:ERROR_CODES :CONSTANTS);

package CRCComputingFileHandle;
use Archive::Zip::MockFileHandle;

use vars qw( @ISA );
@ISA = qw( Archive::Zip::MockFileHandle );

my $crc;

sub writeHook {
    my $self   = shift;
    my $bytes  = shift;
    my $length = length($bytes);
    $crc = Archive::Zip::computeCRC32($bytes, $crc);
}

sub resetCRC { $crc = 0 }

sub crc { $crc }

package main;

die "usage: $0 zipfile.zip\n"
  if (scalar(@ARGV) != 1);

my $zip    = Archive::Zip-&gt;new();
my $status = $zip-&gt;read($ARGV[0]);
exit $status if $status != AZ_OK;

print " Length    Size         Last Modified         CRC-32  Name\n";
print "-------- --------  ------------------------  -------- ----\n";

my $fh = CRCComputingFileHandle-&gt;new();
my @errors;

foreach my $member ($zip-&gt;members()) {
    my $compressedSize = $member-&gt;compressedSize();
    $fh-&gt;resetCRC();
    $member-&gt;desiredCompressionMethod(COMPRESSION_STORED);
    $status = $member-&gt;extractToFileHandle($fh);
    exit $status if $status != AZ_OK;
    my $crc = $fh-&gt;crc();

    my $ct = scalar(localtime($member-&gt;lastModTime()));
    chomp($ct);

    printf(
        "%8d %8d  %s  %08x %s\n",
        $member-&gt;uncompressedSize(),
        $compressedSize, $ct, $member-&gt;crc32(), $member-&gt;fileName());

    if ($member-&gt;crc32() != $crc) {
        push(
            @errors,
            sprintf(
                "Member %s CRC error: file says %08x computed: %08x\n",
                $member-&gt;fileName(), $member-&gt;crc32(), $crc
            ));
    }
}

if (scalar(@errors)) {
    print join("\n", @errors);
    die "CRC errors found\n";
} else {
    print "All CRCs check OK\n";
}
</pre></body></html>