<html><head><meta name="color-scheme" content="light dark"></head><body><pre style="word-wrap: break-word; white-space: pre-wrap;">package # This is JSON::backportPP
    JSON::PP;

# JSON-2.0

use 5.005;
use strict;

use Exporter ();
BEGIN { @JSON::backportPP::ISA = ('Exporter') }

use overload ();
use JSON::backportPP::Boolean;

use Carp ();
#use Devel::Peek;

$JSON::backportPP::VERSION = '4.12';

@JSON::PP::EXPORT = qw(encode_json decode_json from_json to_json);

# instead of hash-access, i tried index-access for speed.
# but this method is not faster than what i expected. so it will be changed.

use constant P_ASCII                =&gt; 0;
use constant P_LATIN1               =&gt; 1;
use constant P_UTF8                 =&gt; 2;
use constant P_INDENT               =&gt; 3;
use constant P_CANONICAL            =&gt; 4;
use constant P_SPACE_BEFORE         =&gt; 5;
use constant P_SPACE_AFTER          =&gt; 6;
use constant P_ALLOW_NONREF         =&gt; 7;
use constant P_SHRINK               =&gt; 8;
use constant P_ALLOW_BLESSED        =&gt; 9;
use constant P_CONVERT_BLESSED      =&gt; 10;
use constant P_RELAXED              =&gt; 11;

use constant P_LOOSE                =&gt; 12;
use constant P_ALLOW_BIGNUM         =&gt; 13;
use constant P_ALLOW_BAREKEY        =&gt; 14;
use constant P_ALLOW_SINGLEQUOTE    =&gt; 15;
use constant P_ESCAPE_SLASH         =&gt; 16;
use constant P_AS_NONBLESSED        =&gt; 17;

use constant P_ALLOW_UNKNOWN        =&gt; 18;
use constant P_ALLOW_TAGS           =&gt; 19;

use constant OLD_PERL =&gt; $] &lt; 5.008 ? 1 : 0;
use constant USE_B =&gt; $ENV{PERL_JSON_PP_USE_B} || 0;
use constant CORE_BOOL =&gt; defined &amp;builtin::is_bool;

my $invalid_char_re;

BEGIN {
    $invalid_char_re = "[";
    for my $i (0 .. 0x01F, 0x22, 0x5c) { # '/' is ok
        $invalid_char_re .= quotemeta chr utf8::unicode_to_native($i);
    }

    $invalid_char_re = qr/$invalid_char_re]/;
}

BEGIN {
    if (USE_B) {
        require B;
    }
}

BEGIN {
    my @xs_compati_bit_properties = qw(
            latin1 ascii utf8 indent canonical space_before space_after allow_nonref shrink
            allow_blessed convert_blessed relaxed allow_unknown
            allow_tags
    );
    my @pp_bit_properties = qw(
            allow_singlequote allow_bignum loose
            allow_barekey escape_slash as_nonblessed
    );

    # Perl version check, Unicode handling is enabled?
    # Helper module sets @JSON::PP::_properties.
    if ( OLD_PERL ) {
        my $helper = $] &gt;= 5.006 ? 'JSON::backportPP::Compat5006' : 'JSON::backportPP::Compat5005';
        eval qq| require $helper |;
        if ($@) { Carp::croak $@; }
    }

    for my $name (@xs_compati_bit_properties, @pp_bit_properties) {
        my $property_id = 'P_' . uc($name);

        eval qq/
            sub $name {
                my \$enable = defined \$_[1] ? \$_[1] : 1;

                if (\$enable) {
                    \$_[0]-&gt;{PROPS}-&gt;[$property_id] = 1;
                }
                else {
                    \$_[0]-&gt;{PROPS}-&gt;[$property_id] = 0;
                }

                \$_[0];
            }

            sub get_$name {
                \$_[0]-&gt;{PROPS}-&gt;[$property_id] ? 1 : '';
            }
        /;
    }

}



# Functions

my $JSON; # cache

sub encode_json ($) { # encode
    ($JSON ||= __PACKAGE__-&gt;new-&gt;utf8)-&gt;encode(@_);
}


sub decode_json { # decode
    ($JSON ||= __PACKAGE__-&gt;new-&gt;utf8)-&gt;decode(@_);
}

# Obsoleted

sub to_json($) {
   Carp::croak ("JSON::PP::to_json has been renamed to encode_json.");
}


sub from_json($) {
   Carp::croak ("JSON::PP::from_json has been renamed to decode_json.");
}


# Methods

sub new {
    my $class = shift;
    my $self  = {
        max_depth   =&gt; 512,
        max_size    =&gt; 0,
        indent_length =&gt; 3,
    };

    $self-&gt;{PROPS}[P_ALLOW_NONREF] = 1;

    bless $self, $class;
}


sub encode {
    return $_[0]-&gt;PP_encode_json($_[1]);
}


sub decode {
    return $_[0]-&gt;PP_decode_json($_[1], 0x00000000);
}


sub decode_prefix {
    return $_[0]-&gt;PP_decode_json($_[1], 0x00000001);
}


# accessor


# pretty printing

sub pretty {
    my ($self, $v) = @_;
    my $enable = defined $v ? $v : 1;

    if ($enable) { # indent_length(3) for JSON::XS compatibility
        $self-&gt;indent(1)-&gt;space_before(1)-&gt;space_after(1);
    }
    else {
        $self-&gt;indent(0)-&gt;space_before(0)-&gt;space_after(0);
    }

    $self;
}

# etc

sub max_depth {
    my $max  = defined $_[1] ? $_[1] : 0x80000000;
    $_[0]-&gt;{max_depth} = $max;
    $_[0];
}


sub get_max_depth { $_[0]-&gt;{max_depth}; }


sub max_size {
    my $max  = defined $_[1] ? $_[1] : 0;
    $_[0]-&gt;{max_size} = $max;
    $_[0];
}


sub get_max_size { $_[0]-&gt;{max_size}; }

sub boolean_values {
    my $self = shift;
    if (@_) {
        my ($false, $true) = @_;
        $self-&gt;{false} = $false;
        $self-&gt;{true} = $true;
        if (CORE_BOOL) {
            BEGIN { CORE_BOOL and warnings-&gt;unimport(qw(experimental::builtin)) }
            if (builtin::is_bool($true) &amp;&amp; builtin::is_bool($false) &amp;&amp; $true &amp;&amp; !$false) {
                $self-&gt;{core_bools} = !!1;
            }
            else {
                delete $self-&gt;{core_bools};
            }
        }
    } else {
        delete $self-&gt;{false};
        delete $self-&gt;{true};
        delete $self-&gt;{core_bools};
    }
    return $self;
}

sub core_bools {
    my $self = shift;
    my $core_bools = defined $_[0] ? $_[0] : 1;
    if ($core_bools) {
        $self-&gt;{true} = !!1;
        $self-&gt;{false} = !!0;
        $self-&gt;{core_bools} = !!1;
    }
    else {
        $self-&gt;{true} = $JSON::PP::true;
        $self-&gt;{false} = $JSON::PP::false;
        $self-&gt;{core_bools} = !!0;
    }
    return $self;
}

sub get_core_bools {
    my $self = shift;
    return !!$self-&gt;{core_bools};
}

sub unblessed_bool {
    my $self = shift;
    return $self-&gt;core_bools(@_);
}

sub get_unblessed_bool {
    my $self = shift;
    return $self-&gt;get_core_bools(@_);
}

sub get_boolean_values {
    my $self = shift;
    if (exists $self-&gt;{true} and exists $self-&gt;{false}) {
        return @$self{qw/false true/};
    }
    return;
}

sub filter_json_object {
    if (defined $_[1] and ref $_[1] eq 'CODE') {
        $_[0]-&gt;{cb_object} = $_[1];
    } else {
        delete $_[0]-&gt;{cb_object};
    }
    $_[0]-&gt;{F_HOOK} = ($_[0]-&gt;{cb_object} or $_[0]-&gt;{cb_sk_object}) ? 1 : 0;
    $_[0];
}

sub filter_json_single_key_object {
    if (@_ == 1 or @_ &gt; 3) {
        Carp::croak("Usage: JSON::PP::filter_json_single_key_object(self, key, callback = undef)");
    }
    if (defined $_[2] and ref $_[2] eq 'CODE') {
        $_[0]-&gt;{cb_sk_object}-&gt;{$_[1]} = $_[2];
    } else {
        delete $_[0]-&gt;{cb_sk_object}-&gt;{$_[1]};
        delete $_[0]-&gt;{cb_sk_object} unless %{$_[0]-&gt;{cb_sk_object} || {}};
    }
    $_[0]-&gt;{F_HOOK} = ($_[0]-&gt;{cb_object} or $_[0]-&gt;{cb_sk_object}) ? 1 : 0;
    $_[0];
}

sub indent_length {
    if (!defined $_[1] or $_[1] &gt; 15 or $_[1] &lt; 0) {
        Carp::carp "The acceptable range of indent_length() is 0 to 15.";
    }
    else {
        $_[0]-&gt;{indent_length} = $_[1];
    }
    $_[0];
}

sub get_indent_length {
    $_[0]-&gt;{indent_length};
}

sub sort_by {
    $_[0]-&gt;{sort_by} = defined $_[1] ? $_[1] : 1;
    $_[0];
}

sub allow_bigint {
    Carp::carp("allow_bigint() is obsoleted. use allow_bignum() instead.");
    $_[0]-&gt;allow_bignum;
}

###############################

###
### Perl =&gt; JSON
###


{ # Convert

    my $max_depth;
    my $indent;
    my $ascii;
    my $latin1;
    my $utf8;
    my $space_before;
    my $space_after;
    my $canonical;
    my $allow_blessed;
    my $convert_blessed;

    my $indent_length;
    my $escape_slash;
    my $bignum;
    my $as_nonblessed;
    my $allow_tags;

    my $depth;
    my $indent_count;
    my $keysort;


    sub PP_encode_json {
        my $self = shift;
        my $obj  = shift;

        $indent_count = 0;
        $depth        = 0;

        my $props = $self-&gt;{PROPS};

        ($ascii, $latin1, $utf8, $indent, $canonical, $space_before, $space_after, $allow_blessed,
            $convert_blessed, $escape_slash, $bignum, $as_nonblessed, $allow_tags)
         = @{$props}[P_ASCII .. P_SPACE_AFTER, P_ALLOW_BLESSED, P_CONVERT_BLESSED,
                    P_ESCAPE_SLASH, P_ALLOW_BIGNUM, P_AS_NONBLESSED, P_ALLOW_TAGS];

        ($max_depth, $indent_length) = @{$self}{qw/max_depth indent_length/};

        $keysort = $canonical ? sub { $a cmp $b } : undef;

        if ($self-&gt;{sort_by}) {
            $keysort = ref($self-&gt;{sort_by}) eq 'CODE' ? $self-&gt;{sort_by}
                     : $self-&gt;{sort_by} =~ /\D+/       ? $self-&gt;{sort_by}
                     : sub { $a cmp $b };
        }

        encode_error("hash- or arrayref expected (not a simple scalar, use allow_nonref to allow this)")
             if(!ref $obj and !$props-&gt;[ P_ALLOW_NONREF ]);

        my $str  = $self-&gt;object_to_json($obj);

        $str .= "\n" if ( $indent ); # JSON::XS 2.26 compatible

        return $str;
    }


    sub object_to_json {
        my ($self, $obj) = @_;
        my $type = ref($obj);

        if($type eq 'HASH'){
            return $self-&gt;hash_to_json($obj);
        }
        elsif($type eq 'ARRAY'){
            return $self-&gt;array_to_json($obj);
        }
        elsif ($type) { # blessed object?
            if (blessed($obj)) {

                return $self-&gt;value_to_json($obj) if ( $obj-&gt;isa('JSON::PP::Boolean') );

                if ( $allow_tags and $obj-&gt;can('FREEZE') ) {
                    my $obj_class = ref $obj || $obj;
                    $obj = bless $obj, $obj_class;
                    my @results = $obj-&gt;FREEZE('JSON');
                    if ( @results and ref $results[0] ) {
                        if ( refaddr( $obj ) eq refaddr( $results[0] ) ) {
                            encode_error( sprintf(
                                "%s::FREEZE method returned same object as was passed instead of a new one",
                                ref $obj
                            ) );
                        }
                    }
                    return '("'.$obj_class.'")['.join(',', @results).']';
                }

                if ( $convert_blessed and $obj-&gt;can('TO_JSON') ) {
                    my $result = $obj-&gt;TO_JSON();
                    if ( defined $result and ref( $result ) ) {
                        if ( refaddr( $obj ) eq refaddr( $result ) ) {
                            encode_error( sprintf(
                                "%s::TO_JSON method returned same object as was passed instead of a new one",
                                ref $obj
                            ) );
                        }
                    }

                    return $self-&gt;object_to_json( $result );
                }

                return "$obj" if ( $bignum and _is_bignum($obj) );

                if ($allow_blessed) {
                    return $self-&gt;blessed_to_json($obj) if ($as_nonblessed); # will be removed.
                    return 'null';
                }
                encode_error( sprintf("encountered object '%s', but neither allow_blessed, convert_blessed nor allow_tags settings are enabled (or TO_JSON/FREEZE method missing)", $obj)
                );
            }
            else {
                return $self-&gt;value_to_json($obj);
            }
        }
        else{
            return $self-&gt;value_to_json($obj);
        }
    }


    sub hash_to_json {
        my ($self, $obj) = @_;
        my @res;

        encode_error("json text or perl structure exceeds maximum nesting level (max_depth set too low?)")
                                         if (++$depth &gt; $max_depth);

        my ($pre, $post) = $indent ? $self-&gt;_up_indent() : ('', '');
        my $del = ($space_before ? ' ' : '') . ':' . ($space_after ? ' ' : '');

        for my $k ( _sort( $obj ) ) {
            if ( OLD_PERL ) { utf8::decode($k) } # key for Perl 5.6 / be optimized
            push @res, $self-&gt;string_to_json( $k )
                          .  $del
                          . ( ref $obj-&gt;{$k} ? $self-&gt;object_to_json( $obj-&gt;{$k} ) : $self-&gt;value_to_json( $obj-&gt;{$k} ) );
        }

        --$depth;
        $self-&gt;_down_indent() if ($indent);

        return '{}' unless @res;
        return '{' . $pre . join( ",$pre", @res ) . $post . '}';
    }


    sub array_to_json {
        my ($self, $obj) = @_;
        my @res;

        encode_error("json text or perl structure exceeds maximum nesting level (max_depth set too low?)")
                                         if (++$depth &gt; $max_depth);

        my ($pre, $post) = $indent ? $self-&gt;_up_indent() : ('', '');

        for my $v (@$obj){
            push @res, ref($v) ? $self-&gt;object_to_json($v) : $self-&gt;value_to_json($v);
        }

        --$depth;
        $self-&gt;_down_indent() if ($indent);

        return '[]' unless @res;
        return '[' . $pre . join( ",$pre", @res ) . $post . ']';
    }

    sub _looks_like_number {
        my $value = shift;
        if (USE_B) {
            my $b_obj = B::svref_2object(\$value);
            my $flags = $b_obj-&gt;FLAGS;
            return 1 if $flags &amp; ( B::SVp_IOK() | B::SVp_NOK() ) and !( $flags &amp; B::SVp_POK() );
            return;
        } else {
            no warnings 'numeric';
            # if the utf8 flag is on, it almost certainly started as a string
            return if utf8::is_utf8($value);
            # detect numbers
            # string &amp; "" -&gt; ""
            # number &amp; "" -&gt; 0 (with warning)
            # nan and inf can detect as numbers, so check with * 0
            return unless length((my $dummy = "") &amp; $value);
            return unless 0 + $value eq $value;
            return 1 if $value * 0 == 0;
            return -1; # inf/nan
        }
    }

    sub value_to_json {
        my ($self, $value) = @_;

        return 'null' if(!defined $value);

        my $type = ref($value);

        if (!$type) {
            BEGIN { CORE_BOOL and warnings-&gt;unimport('experimental::builtin') }
            if (CORE_BOOL &amp;&amp; builtin::is_bool($value)) {
                return $value ? 'true' : 'false';
            }
            elsif (_looks_like_number($value)) {
                return $value;
            }
            return $self-&gt;string_to_json($value);
        }
        elsif( blessed($value) and  $value-&gt;isa('JSON::PP::Boolean') ){
            return $$value == 1 ? 'true' : 'false';
        }
        else {
            if ((overload::StrVal($value) =~ /=(\w+)/)[0]) {
                return $self-&gt;value_to_json("$value");
            }

            if ($type eq 'SCALAR' and defined $$value) {
                return   $$value eq '1' ? 'true'
                       : $$value eq '0' ? 'false'
                       : $self-&gt;{PROPS}-&gt;[ P_ALLOW_UNKNOWN ] ? 'null'
                       : encode_error("cannot encode reference to scalar");
            }

            if ( $self-&gt;{PROPS}-&gt;[ P_ALLOW_UNKNOWN ] ) {
                return 'null';
            }
            else {
                if ( $type eq 'SCALAR' or $type eq 'REF' ) {
                    encode_error("cannot encode reference to scalar");
                }
                else {
                    encode_error("encountered $value, but JSON can only represent references to arrays or hashes");
                }
            }

        }
    }


    my %esc = (
        "\n" =&gt; '\n',
        "\r" =&gt; '\r',
        "\t" =&gt; '\t',
        "\f" =&gt; '\f',
        "\b" =&gt; '\b',
        "\"" =&gt; '\"',
        "\\" =&gt; '\\\\',
        "\'" =&gt; '\\\'',
    );


    sub string_to_json {
        my ($self, $arg) = @_;

        $arg =~ s/(["\\\n\r\t\f\b])/$esc{$1}/g;
        $arg =~ s/\//\\\//g if ($escape_slash);

        # On ASCII platforms, matches [\x00-\x08\x0b\x0e-\x1f]
        $arg =~ s/([^\n\t\c?[:^cntrl:][:^ascii:]])/'\\u00' . unpack('H2', $1)/eg;

        if ($ascii) {
            $arg = JSON_PP_encode_ascii($arg);
        }

        if ($latin1) {
            $arg = JSON_PP_encode_latin1($arg);
        }

        if ($utf8) {
            utf8::encode($arg);
        }

        return '"' . $arg . '"';
    }


    sub blessed_to_json {
        my $reftype = reftype($_[1]) || '';
        if ($reftype eq 'HASH') {
            return $_[0]-&gt;hash_to_json($_[1]);
        }
        elsif ($reftype eq 'ARRAY') {
            return $_[0]-&gt;array_to_json($_[1]);
        }
        else {
            return 'null';
        }
    }


    sub encode_error {
        my $error  = shift;
        Carp::croak "$error";
    }


    sub _sort {
        defined $keysort ? (sort $keysort (keys %{$_[0]})) : keys %{$_[0]};
    }


    sub _up_indent {
        my $self  = shift;
        my $space = ' ' x $indent_length;

        my ($pre,$post) = ('','');

        $post = "\n" . $space x $indent_count;

        $indent_count++;

        $pre = "\n" . $space x $indent_count;

        return ($pre,$post);
    }


    sub _down_indent { $indent_count--; }


    sub PP_encode_box {
        {
            depth        =&gt; $depth,
            indent_count =&gt; $indent_count,
        };
    }

} # Convert


sub _encode_ascii {
    join('',
        map {
            chr($_) =~ /[[:ascii:]]/ ?
                chr($_) :
            $_ &lt;= 65535 ?
                sprintf('\u%04x', $_) : sprintf('\u%x\u%x', _encode_surrogates($_));
        } unpack('U*', $_[0])
    );
}


sub _encode_latin1 {
    join('',
        map {
            $_ &lt;= 255 ?
                chr($_) :
            $_ &lt;= 65535 ?
                sprintf('\u%04x', $_) : sprintf('\u%x\u%x', _encode_surrogates($_));
        } unpack('U*', $_[0])
    );
}


sub _encode_surrogates { # from perlunicode
    my $uni = $_[0] - 0x10000;
    return ($uni / 0x400 + 0xD800, $uni % 0x400 + 0xDC00);
}


sub _is_bignum {
    $_[0]-&gt;isa('Math::BigInt') or $_[0]-&gt;isa('Math::BigFloat');
}



#
# JSON =&gt; Perl
#

my $max_intsize;

BEGIN {
    my $checkint = 1111;
    for my $d (5..64) {
        $checkint .= 1;
        my $int   = eval qq| $checkint |;
        if ($int =~ /[eE]/) {
            $max_intsize = $d - 1;
            last;
        }
    }
}

{ # PARSE 

    my %escapes = ( #  by Jeremy Muhlich &lt;jmuhlich [at] bitflood.org&gt;
        b    =&gt; "\b",
        t    =&gt; "\t",
        n    =&gt; "\n",
        f    =&gt; "\f",
        r    =&gt; "\r",
        '\\' =&gt; '\\',
        '"'  =&gt; '"',
        '/'  =&gt; '/',
    );

    my $text; # json data
    my $at;   # offset
    my $ch;   # first character
    my $len;  # text length (changed according to UTF8 or NON UTF8)
    # INTERNAL
    my $depth;          # nest counter
    my $encoding;       # json text encoding
    my $is_valid_utf8;  # temp variable
    my $utf8_len;       # utf8 byte length
    # FLAGS
    my $utf8;           # must be utf8
    my $max_depth;      # max nest number of objects and arrays
    my $max_size;
    my $relaxed;
    my $cb_object;
    my $cb_sk_object;

    my $F_HOOK;

    my $allow_bignum;   # using Math::BigInt/BigFloat
    my $singlequote;    # loosely quoting
    my $loose;          # 
    my $allow_barekey;  # bareKey
    my $allow_tags;

    my $alt_true;
    my $alt_false;

    sub _detect_utf_encoding {
        my $text = shift;
        my @octets = unpack('C4', $text);
        return 'unknown' unless defined $octets[3];
        return ( $octets[0] and  $octets[1]) ? 'UTF-8'
             : (!$octets[0] and  $octets[1]) ? 'UTF-16BE'
             : (!$octets[0] and !$octets[1]) ? 'UTF-32BE'
             : ( $octets[2]                ) ? 'UTF-16LE'
             : (!$octets[2]                ) ? 'UTF-32LE'
             : 'unknown';
    }

    sub PP_decode_json {
        my ($self, $want_offset);

        ($self, $text, $want_offset) = @_;

        ($at, $ch, $depth) = (0, '', 0);

        if ( !defined $text or ref $text ) {
            decode_error("malformed JSON string, neither array, object, number, string or atom");
        }

        my $props = $self-&gt;{PROPS};

        ($utf8, $relaxed, $loose, $allow_bignum, $allow_barekey, $singlequote, $allow_tags)
            = @{$props}[P_UTF8, P_RELAXED, P_LOOSE .. P_ALLOW_SINGLEQUOTE, P_ALLOW_TAGS];

        ($alt_true, $alt_false) = @$self{qw/true false/};

        if ( $utf8 ) {
            $encoding = _detect_utf_encoding($text);
            if ($encoding ne 'UTF-8' and $encoding ne 'unknown') {
                require Encode;
                Encode::from_to($text, $encoding, 'utf-8');
            } else {
                utf8::downgrade( $text, 1 ) or Carp::croak("Wide character in subroutine entry");
            }
        }
        else {
            utf8::encode( $text );
        }

        $len = length $text;

        ($max_depth, $max_size, $cb_object, $cb_sk_object, $F_HOOK)
             = @{$self}{qw/max_depth  max_size cb_object cb_sk_object F_HOOK/};

        if ($max_size &gt; 1) {
            use bytes;
            my $bytes = length $text;
            decode_error(
                sprintf("attempted decode of JSON text of %s bytes size, but max_size is set to %s"
                    , $bytes, $max_size), 1
            ) if ($bytes &gt; $max_size);
        }

        white(); # remove head white space

        decode_error("malformed JSON string, neither array, object, number, string or atom") unless defined $ch; # Is there a first character for JSON structure?

        my $result = value();

        if ( !$props-&gt;[ P_ALLOW_NONREF ] and !ref $result ) {
                decode_error(
                'JSON text must be an object or array (but found number, string, true, false or null,'
                       . ' use allow_nonref to allow this)', 1);
        }

        Carp::croak('something wrong.') if $len &lt; $at; # we won't arrive here.

        my $consumed = defined $ch ? $at - 1 : $at; # consumed JSON text length

        white(); # remove tail white space

        return ( $result, $consumed ) if $want_offset; # all right if decode_prefix

        decode_error("garbage after JSON object") if defined $ch;

        $result;
    }


    sub next_chr {
        return $ch = undef if($at &gt;= $len);
        $ch = substr($text, $at++, 1);
    }


    sub value {
        white();
        return          if(!defined $ch);
        return object() if($ch eq '{');
        return array()  if($ch eq '[');
        return tag()    if($ch eq '(');
        return string() if($ch eq '"' or ($singlequote and $ch eq "'"));
        return number() if($ch =~ /[0-9]/ or $ch eq '-');
        return word();
    }

    sub string {
        my $utf16;
        my $is_utf8;

        ($is_valid_utf8, $utf8_len) = ('', 0);

        my $s = ''; # basically UTF8 flag on

        if($ch eq '"' or ($singlequote and $ch eq "'")){
            my $boundChar = $ch;

            OUTER: while( defined(next_chr()) ){

                if($ch eq $boundChar){
                    next_chr();

                    if ($utf16) {
                        decode_error("missing low surrogate character in surrogate pair");
                    }

                    utf8::decode($s) if($is_utf8);

                    return $s;
                }
                elsif($ch eq '\\'){
                    next_chr();
                    if(exists $escapes{$ch}){
                        $s .= $escapes{$ch};
                    }
                    elsif($ch eq 'u'){ # UNICODE handling
                        my $u = '';

                        for(1..4){
                            $ch = next_chr();
                            last OUTER if($ch !~ /[0-9a-fA-F]/);
                            $u .= $ch;
                        }

                        # U+D800 - U+DBFF
                        if ($u =~ /^[dD][89abAB][0-9a-fA-F]{2}/) { # UTF-16 high surrogate?
                            $utf16 = $u;
                        }
                        # U+DC00 - U+DFFF
                        elsif ($u =~ /^[dD][c-fC-F][0-9a-fA-F]{2}/) { # UTF-16 low surrogate?
                            unless (defined $utf16) {
                                decode_error("missing high surrogate character in surrogate pair");
                            }
                            $is_utf8 = 1;
                            $s .= JSON_PP_decode_surrogates($utf16, $u) || next;
                            $utf16 = undef;
                        }
                        else {
                            if (defined $utf16) {
                                decode_error("surrogate pair expected");
                            }

                            my $hex = hex( $u );
                            if ( chr $u =~ /[[:^ascii:]]/ ) {
                                $is_utf8 = 1;
                                $s .= JSON_PP_decode_unicode($u) || next;
                            }
                            else {
                                $s .= chr $hex;
                            }
                        }

                    }
                    else{
                        unless ($loose) {
                            $at -= 2;
                            decode_error('illegal backslash escape sequence in string');
                        }
                        $s .= $ch;
                    }
                }
                else{

                    if ( $ch =~ /[[:^ascii:]]/ ) {
                        unless( $ch = is_valid_utf8($ch) ) {
                            $at -= 1;
                            decode_error("malformed UTF-8 character in JSON string");
                        }
                        else {
                            $at += $utf8_len - 1;
                        }

                        $is_utf8 = 1;
                    }

                    if (!$loose) {
                        if ($ch =~ $invalid_char_re)  { # '/' ok
                            if (!$relaxed or $ch ne "\t") {
                                $at--;
                                decode_error(sprintf "invalid character 0x%X"
                                   . " encountered while parsing JSON string",
                                   ord $ch);
                            }
                        }
                    }

                    $s .= $ch;
                }
            }
        }

        decode_error("unexpected end of string while parsing JSON string");
    }


    sub white {
        while( defined $ch  ){
            if($ch eq '' or $ch =~ /\A[ \t\r\n]\z/){
                next_chr();
            }
            elsif($relaxed and $ch eq '/'){
                next_chr();
                if(defined $ch and $ch eq '/'){
                    1 while(defined(next_chr()) and $ch ne "\n" and $ch ne "\r");
                }
                elsif(defined $ch and $ch eq '*'){
                    next_chr();
                    while(1){
                        if(defined $ch){
                            if($ch eq '*'){
                                if(defined(next_chr()) and $ch eq '/'){
                                    next_chr();
                                    last;
                                }
                            }
                            else{
                                next_chr();
                            }
                        }
                        else{
                            decode_error("Unterminated comment");
                        }
                    }
                    next;
                }
                else{
                    $at--;
                    decode_error("malformed JSON string, neither array, object, number, string or atom");
                }
            }
            else{
                if ($relaxed and $ch eq '#') { # correctly?
                    pos($text) = $at;
                    $text =~ /\G([^\n]*(?:\r\n|\r|\n|$))/g;
                    $at = pos($text);
                    next_chr;
                    next;
                }

                last;
            }
        }
    }


    sub array {
        my $a  = $_[0] || []; # you can use this code to use another array ref object.

        decode_error('json text or perl structure exceeds maximum nesting level (max_depth set too low?)')
                                                    if (++$depth &gt; $max_depth);

        next_chr();
        white();

        if(defined $ch and $ch eq ']'){
            --$depth;
            next_chr();
            return $a;
        }
        else {
            while(defined($ch)){
                push @$a, value();

                white();

                if (!defined $ch) {
                    last;
                }

                if($ch eq ']'){
                    --$depth;
                    next_chr();
                    return $a;
                }

                if($ch ne ','){
                    last;
                }

                next_chr();
                white();

                if ($relaxed and $ch eq ']') {
                    --$depth;
                    next_chr();
                    return $a;
                }

            }
        }

        $at-- if defined $ch and $ch ne '';
        decode_error(", or ] expected while parsing array");
    }

    sub tag {
        decode_error('malformed JSON string, neither array, object, number, string or atom') unless $allow_tags;

        next_chr();
        white();

        my $tag = value();
        return unless defined $tag;
        decode_error('malformed JSON string, (tag) must be a string') if ref $tag;

        white();

        if (!defined $ch or $ch ne ')') {
            decode_error(') expected after tag');
        }

        next_chr();
        white();

        my $val = value();
        return unless defined $val;
        decode_error('malformed JSON string, tag value must be an array') unless ref $val eq 'ARRAY';

        if (!eval { $tag-&gt;can('THAW') }) {
             decode_error('cannot decode perl-object (package does not exist)') if $@;
             decode_error('cannot decode perl-object (package does not have a THAW method)');
        }
        $tag-&gt;THAW('JSON', @$val);
    }

    sub object {
        my $o = $_[0] || {}; # you can use this code to use another hash ref object.
        my $k;

        decode_error('json text or perl structure exceeds maximum nesting level (max_depth set too low?)')
                                                if (++$depth &gt; $max_depth);
        next_chr();
        white();

        if(defined $ch and $ch eq '}'){
            --$depth;
            next_chr();
            if ($F_HOOK) {
                return _json_object_hook($o);
            }
            return $o;
        }
        else {
            while (defined $ch) {
                $k = ($allow_barekey and $ch ne '"' and $ch ne "'") ? bareKey() : string();
                white();

                if(!defined $ch or $ch ne ':'){
                    $at--;
                    decode_error("':' expected");
                }

                next_chr();
                $o-&gt;{$k} = value();
                white();

                last if (!defined $ch);

                if($ch eq '}'){
                    --$depth;
                    next_chr();
                    if ($F_HOOK) {
                        return _json_object_hook($o);
                    }
                    return $o;
                }

                if($ch ne ','){
                    last;
                }

                next_chr();
                white();

                if ($relaxed and $ch eq '}') {
                    --$depth;
                    next_chr();
                    if ($F_HOOK) {
                        return _json_object_hook($o);
                    }
                    return $o;
                }

            }

        }

        $at-- if defined $ch and $ch ne '';
        decode_error(", or } expected while parsing object/hash");
    }


    sub bareKey { # doesn't strictly follow Standard ECMA-262 3rd Edition
        my $key;
        while($ch =~ /[\$\w[:^ascii:]]/){
            $key .= $ch;
            next_chr();
        }
        return $key;
    }


    sub word {
        my $word =  substr($text,$at-1,4);

        if($word eq 'true'){
            $at += 3;
            next_chr;
            return defined $alt_true ? $alt_true : $JSON::PP::true;
        }
        elsif($word eq 'null'){
            $at += 3;
            next_chr;
            return undef;
        }
        elsif($word eq 'fals'){
            $at += 3;
            if(substr($text,$at,1) eq 'e'){
                $at++;
                next_chr;
                return defined $alt_false ? $alt_false : $JSON::PP::false;
            }
        }

        $at--; # for decode_error report

        decode_error("'null' expected")  if ($word =~ /^n/);
        decode_error("'true' expected")  if ($word =~ /^t/);
        decode_error("'false' expected") if ($word =~ /^f/);
        decode_error("malformed JSON string, neither array, object, number, string or atom");
    }


    sub number {
        my $n    = '';
        my $v;
        my $is_dec;
        my $is_exp;

        if($ch eq '-'){
            $n = '-';
            next_chr;
            if (!defined $ch or $ch !~ /\d/) {
                decode_error("malformed number (no digits after initial minus)");
            }
        }

        # According to RFC4627, hex or oct digits are invalid.
        if($ch eq '0'){
            my $peek = substr($text,$at,1);
            if($peek =~ /^[0-9a-dfA-DF]/){ # e may be valid (exponential)
                decode_error("malformed number (leading zero must not be followed by another digit)");
            }
            $n .= $ch;
            next_chr;
        }

        while(defined $ch and $ch =~ /\d/){
            $n .= $ch;
            next_chr;
        }

        if(defined $ch and $ch eq '.'){
            $n .= '.';
            $is_dec = 1;

            next_chr;
            if (!defined $ch or $ch !~ /\d/) {
                decode_error("malformed number (no digits after decimal point)");
            }
            else {
                $n .= $ch;
            }

            while(defined(next_chr) and $ch =~ /\d/){
                $n .= $ch;
            }
        }

        if(defined $ch and ($ch eq 'e' or $ch eq 'E')){
            $n .= $ch;
            $is_exp = 1;
            next_chr;

            if(defined($ch) and ($ch eq '+' or $ch eq '-')){
                $n .= $ch;
                next_chr;
                if (!defined $ch or $ch =~ /\D/) {
                    decode_error("malformed number (no digits after exp sign)");
                }
                $n .= $ch;
            }
            elsif(defined($ch) and $ch =~ /\d/){
                $n .= $ch;
            }
            else {
                decode_error("malformed number (no digits after exp sign)");
            }

            while(defined(next_chr) and $ch =~ /\d/){
                $n .= $ch;
            }

        }

        $v .= $n;

        if ($is_dec or $is_exp) {
            if ($allow_bignum) {
                require Math::BigFloat;
                return Math::BigFloat-&gt;new($v);
            }
        } else {
            if (length $v &gt; $max_intsize) {
                if ($allow_bignum) { # from Adam Sussman
                    require Math::BigInt;
                    return Math::BigInt-&gt;new($v);
                }
                else {
                    return "$v";
                }
            }
        }

        return $is_dec ? $v/1.0 : 0+$v;
    }

    # Compute how many bytes are in the longest legal official Unicode
    # character
    my $max_unicode_length = do {
      BEGIN { $] &gt;= 5.006 and require warnings and warnings-&gt;unimport('utf8') }
      chr 0x10FFFF;
    };
    utf8::encode($max_unicode_length);
    $max_unicode_length = length $max_unicode_length;

    sub is_valid_utf8 {

        # Returns undef (setting $utf8_len to 0) unless the next bytes in $text
        # comprise a well-formed UTF-8 encoded character, in which case,
        # return those bytes, setting $utf8_len to their count.

        my $start_point = substr($text, $at - 1);

        # Look no further than the maximum number of bytes in a single
        # character
        my $limit = $max_unicode_length;
        $limit = length($start_point) if $limit &gt; length($start_point);

        # Find the number of bytes comprising the first character in $text
        # (without having to know the details of its internal representation).
        # This loop will iterate just once on well-formed input.
        while ($limit &gt; 0) {    # Until we succeed or exhaust the input
            my $copy = substr($start_point, 0, $limit);

            # decode() will return true if all bytes are valid; false
            # if any aren't.
            if (utf8::decode($copy)) {

                # Is valid: get the first character, convert back to bytes,
                # and return those bytes.
                $copy = substr($copy, 0, 1);
                utf8::encode($copy);
                $utf8_len = length $copy;
                return substr($start_point, 0, $utf8_len);
            }

            # If it didn't work, it could be that there is a full legal character
            # followed by a partial or malformed one.  Narrow the window and
            # try again.
            $limit--;
        }

        # Failed to find a legal UTF-8 character.
        $utf8_len = 0;
        return;
    }


    sub decode_error {
        my $error  = shift;
        my $no_rep = shift;
        my $str    = defined $text ? substr($text, $at) : '';
        my $mess   = '';
        my $type   = 'U*';

        if ( OLD_PERL ) {
            my $type   =  $] &lt;  5.006           ? 'C*'
                        : utf8::is_utf8( $str ) ? 'U*' # 5.6
                        : 'C*'
                        ;
        }

        for my $c ( unpack( $type, $str ) ) { # emulate pv_uni_display() ?
            my $chr_c = chr($c);
            $mess .=  $chr_c eq '\\' ? '\\\\'
                    : $chr_c =~ /[[:print:]]/ ? $chr_c
                    : $chr_c eq '\a' ? '\a'
                    : $chr_c eq '\t' ? '\t'
                    : $chr_c eq '\n' ? '\n'
                    : $chr_c eq '\r' ? '\r'
                    : $chr_c eq '\f' ? '\f'
                    : sprintf('\x{%x}', $c)
                    ;
            if ( length $mess &gt;= 20 ) {
                $mess .= '...';
                last;
            }
        }

        unless ( length $mess ) {
            $mess = '(end of string)';
        }

        Carp::croak (
            $no_rep ? "$error" : "$error, at character offset $at (before \"$mess\")"
        );

    }


    sub _json_object_hook {
        my $o    = $_[0];
        my @ks = keys %{$o};

        if ( $cb_sk_object and @ks == 1 and exists $cb_sk_object-&gt;{ $ks[0] } and ref $cb_sk_object-&gt;{ $ks[0] } ) {
            my @val = $cb_sk_object-&gt;{ $ks[0] }-&gt;( $o-&gt;{$ks[0]} );
            if (@val == 0) {
                return $o;
            }
            elsif (@val == 1) {
                return $val[0];
            }
            else {
                Carp::croak("filter_json_single_key_object callbacks must not return more than one scalar");
            }
        }

        my @val = $cb_object-&gt;($o) if ($cb_object);
        if (@val == 0) {
            return $o;
        }
        elsif (@val == 1) {
            return $val[0];
        }
        else {
            Carp::croak("filter_json_object callbacks must not return more than one scalar");
        }
    }


    sub PP_decode_box {
        {
            text    =&gt; $text,
            at      =&gt; $at,
            ch      =&gt; $ch,
            len     =&gt; $len,
            depth   =&gt; $depth,
            encoding      =&gt; $encoding,
            is_valid_utf8 =&gt; $is_valid_utf8,
        };
    }

} # PARSE


sub _decode_surrogates { # from perlunicode
    my $uni = 0x10000 + (hex($_[0]) - 0xD800) * 0x400 + (hex($_[1]) - 0xDC00);
    my $un  = pack('U*', $uni);
    utf8::encode( $un );
    return $un;
}


sub _decode_unicode {
    my $un = pack('U', hex shift);
    utf8::encode( $un );
    return $un;
}

#
# Setup for various Perl versions (the code from JSON::PP58)
#

BEGIN {

    unless ( defined &amp;utf8::is_utf8 ) {
       require Encode;
       *utf8::is_utf8 = *Encode::is_utf8;
    }

    if ( !OLD_PERL ) {
        *JSON::PP::JSON_PP_encode_ascii      = \&amp;_encode_ascii;
        *JSON::PP::JSON_PP_encode_latin1     = \&amp;_encode_latin1;
        *JSON::PP::JSON_PP_decode_surrogates = \&amp;_decode_surrogates;
        *JSON::PP::JSON_PP_decode_unicode    = \&amp;_decode_unicode;

        if ($] &lt; 5.008003) { # join() in 5.8.0 - 5.8.2 is broken.
            package # hide from PAUSE
              JSON::PP;
            require subs;
            subs-&gt;import('join');
            eval q|
                sub join {
                    return '' if (@_ &lt; 2);
                    my $j   = shift;
                    my $str = shift;
                    for (@_) { $str .= $j . $_; }
                    return $str;
                }
            |;
        }
    }


    sub JSON::PP::incr_parse {
        local $Carp::CarpLevel = 1;
        ( $_[0]-&gt;{_incr_parser} ||= JSON::PP::IncrParser-&gt;new )-&gt;incr_parse( @_ );
    }


    sub JSON::PP::incr_skip {
        ( $_[0]-&gt;{_incr_parser} ||= JSON::PP::IncrParser-&gt;new )-&gt;incr_skip;
    }


    sub JSON::PP::incr_reset {
        ( $_[0]-&gt;{_incr_parser} ||= JSON::PP::IncrParser-&gt;new )-&gt;incr_reset;
    }

    eval q{
        sub JSON::PP::incr_text : lvalue {
            $_[0]-&gt;{_incr_parser} ||= JSON::PP::IncrParser-&gt;new;

            if ( $_[0]-&gt;{_incr_parser}-&gt;{incr_pos} ) {
                Carp::croak("incr_text cannot be called when the incremental parser already started parsing");
            }
            $_[0]-&gt;{_incr_parser}-&gt;{incr_text};
        }
    } if ( $] &gt;= 5.006 );

} # Setup for various Perl versions (the code from JSON::PP58)


###############################
# Utilities
#

BEGIN {
    eval 'require Scalar::Util';
    unless($@){
        *JSON::PP::blessed = \&amp;Scalar::Util::blessed;
        *JSON::PP::reftype = \&amp;Scalar::Util::reftype;
        *JSON::PP::refaddr = \&amp;Scalar::Util::refaddr;
    }
    else{ # This code is from Scalar::Util.
        # warn $@;
        eval 'sub UNIVERSAL::a_sub_not_likely_to_be_here { ref($_[0]) }';
        *JSON::PP::blessed = sub {
            local($@, $SIG{__DIE__}, $SIG{__WARN__});
            ref($_[0]) ? eval { $_[0]-&gt;a_sub_not_likely_to_be_here } : undef;
        };
        require B;
        my %tmap = qw(
            B::NULL   SCALAR
            B::HV     HASH
            B::AV     ARRAY
            B::CV     CODE
            B::IO     IO
            B::GV     GLOB
            B::REGEXP REGEXP
        );
        *JSON::PP::reftype = sub {
            my $r = shift;

            return undef unless length(ref($r));

            my $t = ref(B::svref_2object($r));

            return
                exists $tmap{$t} ? $tmap{$t}
              : length(ref($$r)) ? 'REF'
              :                    'SCALAR';
        };
        *JSON::PP::refaddr = sub {
          return undef unless length(ref($_[0]));

          my $addr;
          if(defined(my $pkg = blessed($_[0]))) {
            $addr .= bless $_[0], 'Scalar::Util::Fake';
            bless $_[0], $pkg;
          }
          else {
            $addr .= $_[0]
          }

          $addr =~ /0x(\w+)/;
          local $^W;
          #no warnings 'portable';
          hex($1);
        }
    }
}


# shamelessly copied and modified from JSON::XS code.

$JSON::PP::true  = do { bless \(my $dummy = 1), "JSON::PP::Boolean" };
$JSON::PP::false = do { bless \(my $dummy = 0), "JSON::PP::Boolean" };

sub is_bool {
  if (blessed $_[0]) {
    return (
      $_[0]-&gt;isa("JSON::PP::Boolean")
      or $_[0]-&gt;isa("Types::Serialiser::BooleanBase")
      or $_[0]-&gt;isa("JSON::XS::Boolean")
    );
  }
  elsif (CORE_BOOL) {
    BEGIN { CORE_BOOL and warnings-&gt;unimport('experimental::builtin') }
    return builtin::is_bool($_[0]);
  }
  return !!0;
}

sub true  { $JSON::PP::true  }
sub false { $JSON::PP::false }
sub null  { undef; }

###############################

package # hide from PAUSE
  JSON::PP::IncrParser;

use strict;

use constant INCR_M_WS   =&gt; 0; # initial whitespace skipping
use constant INCR_M_STR  =&gt; 1; # inside string
use constant INCR_M_BS   =&gt; 2; # inside backslash
use constant INCR_M_JSON =&gt; 3; # outside anything, count nesting
use constant INCR_M_C0   =&gt; 4;
use constant INCR_M_C1   =&gt; 5;
use constant INCR_M_TFN  =&gt; 6;
use constant INCR_M_NUM  =&gt; 7;

$JSON::backportPP::IncrParser::VERSION = '1.01';

sub new {
    my ( $class ) = @_;

    bless {
        incr_nest    =&gt; 0,
        incr_text    =&gt; undef,
        incr_pos     =&gt; 0,
        incr_mode    =&gt; 0,
    }, $class;
}


sub incr_parse {
    my ( $self, $coder, $text ) = @_;

    $self-&gt;{incr_text} = '' unless ( defined $self-&gt;{incr_text} );

    if ( defined $text ) {
        $self-&gt;{incr_text} .= $text;
    }

    if ( defined wantarray ) {
        my $max_size = $coder-&gt;get_max_size;
        my $p = $self-&gt;{incr_pos};
        my @ret;
        {
            do {
                unless ( $self-&gt;{incr_nest} &lt;= 0 and $self-&gt;{incr_mode} == INCR_M_JSON ) {
                    $self-&gt;_incr_parse( $coder );

                    if ( $max_size and $self-&gt;{incr_pos} &gt; $max_size ) {
                        Carp::croak("attempted decode of JSON text of $self-&gt;{incr_pos} bytes size, but max_size is set to $max_size");
                    }
                    unless ( $self-&gt;{incr_nest} &lt;= 0 and $self-&gt;{incr_mode} == INCR_M_JSON ) {
                        # as an optimisation, do not accumulate white space in the incr buffer
                        if ( $self-&gt;{incr_mode} == INCR_M_WS and $self-&gt;{incr_pos} ) {
                            $self-&gt;{incr_pos} = 0;
                            $self-&gt;{incr_text} = '';
                        }
                        last;
                    }
                }

                unless ( $coder-&gt;get_utf8 ) {
                    utf8::decode( $self-&gt;{incr_text} );
                }

                my ($obj, $offset) = $coder-&gt;PP_decode_json( $self-&gt;{incr_text}, 0x00000001 );
                push @ret, $obj;
                use bytes;
                $self-&gt;{incr_text} = substr( $self-&gt;{incr_text}, $offset || 0 );
                $self-&gt;{incr_pos} = 0;
                $self-&gt;{incr_nest} = 0;
                $self-&gt;{incr_mode} = 0;
                last unless wantarray;
            } while ( wantarray );
        }

        if ( wantarray ) {
            return @ret;
        }
        else { # in scalar context
            return defined $ret[0] ? $ret[0] : undef;
        }
    }
}


sub _incr_parse {
    my ($self, $coder) = @_;
    my $text = $self-&gt;{incr_text};
    my $len = length $text;
    my $p = $self-&gt;{incr_pos};

INCR_PARSE:
    while ( $len &gt; $p ) {
        my $s = substr( $text, $p, 1 );
        last INCR_PARSE unless defined $s;
        my $mode = $self-&gt;{incr_mode};

        if ( $mode == INCR_M_WS ) {
            while ( $len &gt; $p ) {
                $s = substr( $text, $p, 1 );
                last INCR_PARSE unless defined $s;
                if ( ord($s) &gt; ord " " ) {
                    if ( $s eq '#' ) {
                        $self-&gt;{incr_mode} = INCR_M_C0;
                        redo INCR_PARSE;
                    } else {
                        $self-&gt;{incr_mode} = INCR_M_JSON;
                        redo INCR_PARSE;
                    }
                }
                $p++;
            }
        } elsif ( $mode == INCR_M_BS ) {
            $p++;
            $self-&gt;{incr_mode} = INCR_M_STR;
            redo INCR_PARSE;
        } elsif ( $mode == INCR_M_C0 or $mode == INCR_M_C1 ) {
            while ( $len &gt; $p ) {
                $s = substr( $text, $p, 1 );
                last INCR_PARSE unless defined $s;
                if ( $s eq "\n" ) {
                    $self-&gt;{incr_mode} = $self-&gt;{incr_mode} == INCR_M_C0 ? INCR_M_WS : INCR_M_JSON;
                    last;
                }
                $p++;
            }
            next;
        } elsif ( $mode == INCR_M_TFN ) {
            last INCR_PARSE if $p &gt;= $len &amp;&amp; $self-&gt;{incr_nest};
            while ( $len &gt; $p ) {
                $s = substr( $text, $p++, 1 );
                next if defined $s and $s =~ /[rueals]/;
                last;
            }
            $p--;
            $self-&gt;{incr_mode} = INCR_M_JSON;

            last INCR_PARSE unless $self-&gt;{incr_nest};
            redo INCR_PARSE;
        } elsif ( $mode == INCR_M_NUM ) {
            last INCR_PARSE if $p &gt;= $len &amp;&amp; $self-&gt;{incr_nest};
            while ( $len &gt; $p ) {
                $s = substr( $text, $p++, 1 );
                next if defined $s and $s =~ /[0-9eE.+\-]/;
                last;
            }
            $p--;
            $self-&gt;{incr_mode} = INCR_M_JSON;

            last INCR_PARSE unless $self-&gt;{incr_nest};
            redo INCR_PARSE;
        } elsif ( $mode == INCR_M_STR ) {
            while ( $len &gt; $p ) {
                $s = substr( $text, $p, 1 );
                last INCR_PARSE unless defined $s;
                if ( $s eq '"' ) {
                    $p++;
                    $self-&gt;{incr_mode} = INCR_M_JSON;

                    last INCR_PARSE unless $self-&gt;{incr_nest};
                    redo INCR_PARSE;
                }
                elsif ( $s eq '\\' ) {
                    $p++;
                    if ( !defined substr($text, $p, 1) ) {
                        $self-&gt;{incr_mode} = INCR_M_BS;
                        last INCR_PARSE;
                    }
                }
                $p++;
            }
        } elsif ( $mode == INCR_M_JSON ) {
            while ( $len &gt; $p ) {
                $s = substr( $text, $p++, 1 );
                if ( $s eq "\x00" ) {
                    $p--;
                    last INCR_PARSE;
                } elsif ( $s =~ /^[\t\n\r ]$/) {
                    if ( !$self-&gt;{incr_nest} ) {
                        $p--; # do not eat the whitespace, let the next round do it
                        last INCR_PARSE;
                    }
                    next;
                } elsif ( $s eq 't' or $s eq 'f' or $s eq 'n' ) {
                    $self-&gt;{incr_mode} = INCR_M_TFN;
                    redo INCR_PARSE;
                } elsif ( $s =~ /^[0-9\-]$/ ) {
                    $self-&gt;{incr_mode} = INCR_M_NUM;
                    redo INCR_PARSE;
                } elsif ( $s eq '"' ) {
                    $self-&gt;{incr_mode} = INCR_M_STR;
                    redo INCR_PARSE;
                } elsif ( $s eq '[' or $s eq '{' ) {
                    if ( ++$self-&gt;{incr_nest} &gt; $coder-&gt;get_max_depth ) {
                        Carp::croak('json text or perl structure exceeds maximum nesting level (max_depth set too low?)');
                    }
                    next;
                } elsif ( $s eq ']' or $s eq '}' ) {
                    if ( --$self-&gt;{incr_nest} &lt;= 0 ) {
                        last INCR_PARSE;
                    }
                } elsif ( $s eq '#' ) {
                    $self-&gt;{incr_mode} = INCR_M_C1;
                    redo INCR_PARSE;
                }
            }
        }
    }

    $self-&gt;{incr_pos} = $p;
    $self-&gt;{incr_parsing} = $p ? 1 : 0; # for backward compatibility
}


sub incr_text {
    if ( $_[0]-&gt;{incr_pos} ) {
        Carp::croak("incr_text cannot be called when the incremental parser already started parsing");
    }
    $_[0]-&gt;{incr_text};
}


sub incr_skip {
    my $self  = shift;
    $self-&gt;{incr_text} = substr( $self-&gt;{incr_text}, $self-&gt;{incr_pos} );
    $self-&gt;{incr_pos}     = 0;
    $self-&gt;{incr_mode}    = 0;
    $self-&gt;{incr_nest}    = 0;
}


sub incr_reset {
    my $self = shift;
    $self-&gt;{incr_text}    = undef;
    $self-&gt;{incr_pos}     = 0;
    $self-&gt;{incr_mode}    = 0;
    $self-&gt;{incr_nest}    = 0;
}

###############################


1;
__END__
=pod

=head1 NAME

JSON::PP - JSON::XS compatible pure-Perl module.

=head1 SYNOPSIS

 use JSON::PP;

 # exported functions, they croak on error
 # and expect/generate UTF-8

 $utf8_encoded_json_text = encode_json $perl_hash_or_arrayref;
 $perl_hash_or_arrayref  = decode_json $utf8_encoded_json_text;

 # OO-interface

 $json = JSON::PP-&gt;new-&gt;ascii-&gt;pretty-&gt;allow_nonref;
 
 $pretty_printed_json_text = $json-&gt;encode( $perl_scalar );
 $perl_scalar = $json-&gt;decode( $json_text );
 
 # Note that JSON version 2.0 and above will automatically use
 # JSON::XS or JSON::PP, so you should be able to just:
 
 use JSON;


=head1 DESCRIPTION

JSON::PP is a pure perl JSON decoder/encoder, and (almost) compatible to much
faster L&lt;JSON::XS&gt; written by Marc Lehmann in C. JSON::PP works as
a fallback module when you use L&lt;JSON&gt; module without having
installed JSON::XS.

Because of this fallback feature of JSON.pm, JSON::PP tries not to
be more JavaScript-friendly than JSON::XS (i.e. not to escape extra
characters such as U+2028 and U+2029, etc),
in order for you not to lose such JavaScript-friendliness silently
when you use JSON.pm and install JSON::XS for speed or by accident.
If you need JavaScript-friendly RFC7159-compliant pure perl module,
try L&lt;JSON::Tiny&gt;, which is derived from L&lt;Mojolicious&gt; web
framework and is also smaller and faster than JSON::PP.

JSON::PP has been in the Perl core since Perl 5.14, mainly for
CPAN toolchain modules to parse META.json.

=head1 FUNCTIONAL INTERFACE

This section is taken from JSON::XS almost verbatim. C&lt;encode_json&gt;
and C&lt;decode_json&gt; are exported by default.

=head2 encode_json

    $json_text = encode_json $perl_scalar

Converts the given Perl data structure to a UTF-8 encoded, binary string
(that is, the string contains octets only). Croaks on error.

This function call is functionally identical to:

    $json_text = JSON::PP-&gt;new-&gt;utf8-&gt;encode($perl_scalar)

Except being faster.

=head2 decode_json

    $perl_scalar = decode_json $json_text

The opposite of C&lt;encode_json&gt;: expects an UTF-8 (binary) string and tries
to parse that as an UTF-8 encoded JSON text, returning the resulting
reference. Croaks on error.

This function call is functionally identical to:

    $perl_scalar = JSON::PP-&gt;new-&gt;utf8-&gt;decode($json_text)

Except being faster.

=head2 JSON::PP::is_bool

    $is_boolean = JSON::PP::is_bool($scalar)

Returns true if the passed scalar represents either JSON::PP::true or
JSON::PP::false, two constants that act like C&lt;1&gt; and C&lt;0&gt; respectively
and are also used to represent JSON C&lt;true&gt; and C&lt;false&gt; in Perl strings.

On perl 5.36 and above, will also return true when given one of perl's
standard boolean values, such as the result of a comparison.

See L&lt;MAPPING&gt;, below, for more information on how JSON values are mapped to
Perl.

=head1 OBJECT-ORIENTED INTERFACE

This section is also taken from JSON::XS.

The object oriented interface lets you configure your own encoding or
decoding style, within the limits of supported formats.

=head2 new

    $json = JSON::PP-&gt;new

Creates a new JSON::PP object that can be used to de/encode JSON
strings. All boolean flags described below are by default I&lt;disabled&gt;
(with the exception of C&lt;allow_nonref&gt;, which defaults to I&lt;enabled&gt; since
version C&lt;4.0&gt;).

The mutators for flags all return the JSON::PP object again and thus calls can
be chained:

   my $json = JSON::PP-&gt;new-&gt;utf8-&gt;space_after-&gt;encode({a =&gt; [1,2]})
   =&gt; {"a": [1, 2]}

=head2 ascii

    $json = $json-&gt;ascii([$enable])
    
    $enabled = $json-&gt;get_ascii

If C&lt;$enable&gt; is true (or missing), then the C&lt;encode&gt; method will not
generate characters outside the code range C&lt;0..127&gt; (which is ASCII). Any
Unicode characters outside that range will be escaped using either a
single \uXXXX (BMP characters) or a double \uHHHH\uLLLLL escape sequence,
as per RFC4627. The resulting encoded JSON text can be treated as a native
Unicode string, an ascii-encoded, latin1-encoded or UTF-8 encoded string,
or any other superset of ASCII.

If C&lt;$enable&gt; is false, then the C&lt;encode&gt; method will not escape Unicode
characters unless required by the JSON syntax or other flags. This results
in a faster and more compact format.

See also the section I&lt;ENCODING/CODESET FLAG NOTES&gt; later in this document.

The main use for this flag is to produce JSON texts that can be
transmitted over a 7-bit channel, as the encoded JSON texts will not
contain any 8 bit characters.

  JSON::PP-&gt;new-&gt;ascii(1)-&gt;encode([chr 0x10401])
  =&gt; ["\ud801\udc01"]

=head2 latin1

    $json = $json-&gt;latin1([$enable])
    
    $enabled = $json-&gt;get_latin1

If C&lt;$enable&gt; is true (or missing), then the C&lt;encode&gt; method will encode
the resulting JSON text as latin1 (or iso-8859-1), escaping any characters
outside the code range C&lt;0..255&gt;. The resulting string can be treated as a
latin1-encoded JSON text or a native Unicode string. The C&lt;decode&gt; method
will not be affected in any way by this flag, as C&lt;decode&gt; by default
expects Unicode, which is a strict superset of latin1.

If C&lt;$enable&gt; is false, then the C&lt;encode&gt; method will not escape Unicode
characters unless required by the JSON syntax or other flags.

See also the section I&lt;ENCODING/CODESET FLAG NOTES&gt; later in this document.

The main use for this flag is efficiently encoding binary data as JSON
text, as most octets will not be escaped, resulting in a smaller encoded
size. The disadvantage is that the resulting JSON text is encoded
in latin1 (and must correctly be treated as such when storing and
transferring), a rare encoding for JSON. It is therefore most useful when
you want to store data structures known to contain binary data efficiently
in files or databases, not when talking to other JSON encoders/decoders.

  JSON::PP-&gt;new-&gt;latin1-&gt;encode (["\x{89}\x{abc}"]
  =&gt; ["\x{89}\\u0abc"]    # (perl syntax, U+abc escaped, U+89 not)

=head2 utf8

    $json = $json-&gt;utf8([$enable])
    
    $enabled = $json-&gt;get_utf8

If C&lt;$enable&gt; is true (or missing), then the C&lt;encode&gt; method will encode
the JSON result into UTF-8, as required by many protocols, while the
C&lt;decode&gt; method expects to be handled an UTF-8-encoded string.  Please
note that UTF-8-encoded strings do not contain any characters outside the
range C&lt;0..255&gt;, they are thus useful for bytewise/binary I/O. In future
versions, enabling this option might enable autodetection of the UTF-16
and UTF-32 encoding families, as described in RFC4627.

If C&lt;$enable&gt; is false, then the C&lt;encode&gt; method will return the JSON
string as a (non-encoded) Unicode string, while C&lt;decode&gt; expects thus a
Unicode string.  Any decoding or encoding (e.g. to UTF-8 or UTF-16) needs
to be done yourself, e.g. using the Encode module.

See also the section I&lt;ENCODING/CODESET FLAG NOTES&gt; later in this document.

Example, output UTF-16BE-encoded JSON:

  use Encode;
  $jsontext = encode "UTF-16BE", JSON::PP-&gt;new-&gt;encode ($object);

Example, decode UTF-32LE-encoded JSON:

  use Encode;
  $object = JSON::PP-&gt;new-&gt;decode (decode "UTF-32LE", $jsontext);

=head2 pretty

    $json = $json-&gt;pretty([$enable])

This enables (or disables) all of the C&lt;indent&gt;, C&lt;space_before&gt; and
C&lt;space_after&gt; (and in the future possibly more) flags in one call to
generate the most readable (or most compact) form possible.

=head2 indent

    $json = $json-&gt;indent([$enable])
    
    $enabled = $json-&gt;get_indent

If C&lt;$enable&gt; is true (or missing), then the C&lt;encode&gt; method will use a multiline
format as output, putting every array member or object/hash key-value pair
into its own line, indenting them properly.

If C&lt;$enable&gt; is false, no newlines or indenting will be produced, and the
resulting JSON text is guaranteed not to contain any C&lt;newlines&gt;.

This setting has no effect when decoding JSON texts.

The default indent space length is three.
You can use C&lt;indent_length&gt; to change the length.

=head2 space_before

    $json = $json-&gt;space_before([$enable])
    
    $enabled = $json-&gt;get_space_before

If C&lt;$enable&gt; is true (or missing), then the C&lt;encode&gt; method will add an extra
optional space before the C&lt;:&gt; separating keys from values in JSON objects.

If C&lt;$enable&gt; is false, then the C&lt;encode&gt; method will not add any extra
space at those places.

This setting has no effect when decoding JSON texts. You will also
most likely combine this setting with C&lt;space_after&gt;.

Example, space_before enabled, space_after and indent disabled:

   {"key" :"value"}

=head2 space_after

    $json = $json-&gt;space_after([$enable])
    
    $enabled = $json-&gt;get_space_after

If C&lt;$enable&gt; is true (or missing), then the C&lt;encode&gt; method will add an extra
optional space after the C&lt;:&gt; separating keys from values in JSON objects
and extra whitespace after the C&lt;,&gt; separating key-value pairs and array
members.

If C&lt;$enable&gt; is false, then the C&lt;encode&gt; method will not add any extra
space at those places.

This setting has no effect when decoding JSON texts.

Example, space_before and indent disabled, space_after enabled:

   {"key": "value"}

=head2 relaxed

    $json = $json-&gt;relaxed([$enable])
    
    $enabled = $json-&gt;get_relaxed

If C&lt;$enable&gt; is true (or missing), then C&lt;decode&gt; will accept some
extensions to normal JSON syntax (see below). C&lt;encode&gt; will not be
affected in anyway. I&lt;Be aware that this option makes you accept invalid
JSON texts as if they were valid!&gt;. I suggest only to use this option to
parse application-specific files written by humans (configuration files,
resource files etc.)

If C&lt;$enable&gt; is false (the default), then C&lt;decode&gt; will only accept
valid JSON texts.

Currently accepted extensions are:

=over 4

=item * list items can have an end-comma

JSON I&lt;separates&gt; array elements and key-value pairs with commas. This
can be annoying if you write JSON texts manually and want to be able to
quickly append elements, so this extension accepts comma at the end of
such items not just between them:

   [
      1,
      2, &lt;- this comma not normally allowed
   ]
   {
      "k1": "v1",
      "k2": "v2", &lt;- this comma not normally allowed
   }

=item * shell-style '#'-comments

Whenever JSON allows whitespace, shell-style comments are additionally
allowed. They are terminated by the first carriage-return or line-feed
character, after which more white-space and comments are allowed.

  [
     1, # this comment not allowed in JSON
        # neither this one...
  ]

=item * C-style multiple-line '/* */'-comments (JSON::PP only)

Whenever JSON allows whitespace, C-style multiple-line comments are additionally
allowed. Everything between C&lt;/*&gt; and C&lt;*/&gt; is a comment, after which
more white-space and comments are allowed.

  [
     1, /* this comment not allowed in JSON */
        /* neither this one... */
  ]

=item * C++-style one-line '//'-comments (JSON::PP only)

Whenever JSON allows whitespace, C++-style one-line comments are additionally
allowed. They are terminated by the first carriage-return or line-feed
character, after which more white-space and comments are allowed.

  [
     1, // this comment not allowed in JSON
        // neither this one...
  ]

=item * literal ASCII TAB characters in strings

Literal ASCII TAB characters are now allowed in strings (and treated as
C&lt;\t&gt;).

  [
     "Hello\tWorld",
     "Hello&lt;TAB&gt;World", # literal &lt;TAB&gt; would not normally be allowed
  ]

=back

=head2 canonical

    $json = $json-&gt;canonical([$enable])
    
    $enabled = $json-&gt;get_canonical

If C&lt;$enable&gt; is true (or missing), then the C&lt;encode&gt; method will output JSON objects
by sorting their keys. This is adding a comparatively high overhead.

If C&lt;$enable&gt; is false, then the C&lt;encode&gt; method will output key-value
pairs in the order Perl stores them (which will likely change between runs
of the same script, and can change even within the same run from 5.18
onwards).

This option is useful if you want the same data structure to be encoded as
the same JSON text (given the same overall settings). If it is disabled,
the same hash might be encoded differently even if contains the same data,
as key-value pairs have no inherent ordering in Perl.

This setting has no effect when decoding JSON texts.

This setting has currently no effect on tied hashes.

=head2 allow_nonref

    $json = $json-&gt;allow_nonref([$enable])
    
    $enabled = $json-&gt;get_allow_nonref

Unlike other boolean options, this opotion is enabled by default beginning
with version C&lt;4.0&gt;.

If C&lt;$enable&gt; is true (or missing), then the C&lt;encode&gt; method can convert a
non-reference into its corresponding string, number or null JSON value,
which is an extension to RFC4627. Likewise, C&lt;decode&gt; will accept those JSON
values instead of croaking.

If C&lt;$enable&gt; is false, then the C&lt;encode&gt; method will croak if it isn't
passed an arrayref or hashref, as JSON texts must either be an object
or array. Likewise, C&lt;decode&gt; will croak if given something that is not a
JSON object or array.

Example, encode a Perl scalar as JSON value without enabled C&lt;allow_nonref&gt;,
resulting in an error:

   JSON::PP-&gt;new-&gt;allow_nonref(0)-&gt;encode ("Hello, World!")
   =&gt; hash- or arrayref expected...

=head2 allow_unknown

    $json = $json-&gt;allow_unknown([$enable])
    
    $enabled = $json-&gt;get_allow_unknown

If C&lt;$enable&gt; is true (or missing), then C&lt;encode&gt; will I&lt;not&gt; throw an
exception when it encounters values it cannot represent in JSON (for
example, filehandles) but instead will encode a JSON C&lt;null&gt; value. Note
that blessed objects are not included here and are handled separately by
c&lt;allow_blessed&gt;.

If C&lt;$enable&gt; is false (the default), then C&lt;encode&gt; will throw an
exception when it encounters anything it cannot encode as JSON.

This option does not affect C&lt;decode&gt; in any way, and it is recommended to
leave it off unless you know your communications partner.

=head2 allow_blessed

    $json = $json-&gt;allow_blessed([$enable])
    
    $enabled = $json-&gt;get_allow_blessed

See L&lt;OBJECT SERIALISATION&gt; for details.

If C&lt;$enable&gt; is true (or missing), then the C&lt;encode&gt; method will not
barf when it encounters a blessed reference that it cannot convert
otherwise. Instead, a JSON C&lt;null&gt; value is encoded instead of the object.

If C&lt;$enable&gt; is false (the default), then C&lt;encode&gt; will throw an
exception when it encounters a blessed object that it cannot convert
otherwise.

This setting has no effect on C&lt;decode&gt;.

=head2 convert_blessed

    $json = $json-&gt;convert_blessed([$enable])
    
    $enabled = $json-&gt;get_convert_blessed

See L&lt;OBJECT SERIALISATION&gt; for details.

If C&lt;$enable&gt; is true (or missing), then C&lt;encode&gt;, upon encountering a
blessed object, will check for the availability of the C&lt;TO_JSON&gt; method
on the object's class. If found, it will be called in scalar context and
the resulting scalar will be encoded instead of the object.

The C&lt;TO_JSON&gt; method may safely call die if it wants. If C&lt;TO_JSON&gt;
returns other blessed objects, those will be handled in the same
way. C&lt;TO_JSON&gt; must take care of not causing an endless recursion cycle
(== crash) in this case. The name of C&lt;TO_JSON&gt; was chosen because other
methods called by the Perl core (== not by the user of the object) are
usually in upper case letters and to avoid collisions with any C&lt;to_json&gt;
function or method.

If C&lt;$enable&gt; is false (the default), then C&lt;encode&gt; will not consider
this type of conversion.

This setting has no effect on C&lt;decode&gt;.

=head2 allow_tags

    $json = $json-&gt;allow_tags([$enable])

    $enabled = $json-&gt;get_allow_tags

See L&lt;OBJECT SERIALISATION&gt; for details.

If C&lt;$enable&gt; is true (or missing), then C&lt;encode&gt;, upon encountering a
blessed object, will check for the availability of the C&lt;FREEZE&gt; method on
the object's class. If found, it will be used to serialise the object into
a nonstandard tagged JSON value (that JSON decoders cannot decode).

It also causes C&lt;decode&gt; to parse such tagged JSON values and deserialise
them via a call to the C&lt;THAW&gt; method.

If C&lt;$enable&gt; is false (the default), then C&lt;encode&gt; will not consider
this type of conversion, and tagged JSON values will cause a parse error
in C&lt;decode&gt;, as if tags were not part of the grammar.

=head2 boolean_values

    $json-&gt;boolean_values([$false, $true])

    ($false,  $true) = $json-&gt;get_boolean_values

By default, JSON booleans will be decoded as overloaded
C&lt;$JSON::PP::false&gt; and C&lt;$JSON::PP::true&gt; objects.

With this method you can specify your own boolean values for decoding -
on decode, JSON C&lt;false&gt; will be decoded as a copy of C&lt;$false&gt;, and JSON
C&lt;true&gt; will be decoded as C&lt;$true&gt; ("copy" here is the same thing as
assigning a value to another variable, i.e. C&lt;$copy = $false&gt;).

This is useful when you want to pass a decoded data structure directly
to other serialisers like YAML, Data::MessagePack and so on.

Note that this works only when you C&lt;decode&gt;. You can set incompatible
boolean objects (like L&lt;boolean&gt;), but when you C&lt;encode&gt; a data structure
with such boolean objects, you still need to enable C&lt;convert_blessed&gt;
(and add a C&lt;TO_JSON&gt; method if necessary).

Calling this method without any arguments will reset the booleans
to their default values.

C&lt;get_boolean_values&gt; will return both C&lt;$false&gt; and C&lt;$true&gt; values, or
the empty list when they are set to the default.

=head2 core_bools

    $json-&gt;core_bools([$enable]);

If C&lt;$enable&gt; is true (or missing), then C&lt;decode&gt;, will produce standard
perl boolean values. Equivalent to calling:

    $json-&gt;boolean_values(!!1, !!0)

C&lt;get_core_bools&gt; will return true if this has been set. On perl 5.36, it will
also return true if the boolean values have been set to perl's core booleans
using the C&lt;boolean_values&gt; method.

The methods C&lt;unblessed_bool&gt; and C&lt;get_unblessed_bool&gt; are provided as aliases
for compatibility with L&lt;Cpanel::JSON::XS&gt;.

=head2 filter_json_object

    $json = $json-&gt;filter_json_object([$coderef])

When C&lt;$coderef&gt; is specified, it will be called from C&lt;decode&gt; each
time it decodes a JSON object. The only argument is a reference to
the newly-created hash. If the code references returns a single scalar
(which need not be a reference), this value (or rather a copy of it) is
inserted into the deserialised data structure. If it returns an empty
list (NOTE: I&lt;not&gt; C&lt;undef&gt;, which is a valid scalar), the original
deserialised hash will be inserted. This setting can slow down decoding
considerably.

When C&lt;$coderef&gt; is omitted or undefined, any existing callback will
be removed and C&lt;decode&gt; will not change the deserialised hash in any
way.

Example, convert all JSON objects into the integer 5:

   my $js = JSON::PP-&gt;new-&gt;filter_json_object(sub { 5 });
   # returns [5]
   $js-&gt;decode('[{}]');
   # returns 5
   $js-&gt;decode('{"a":1, "b":2}');

=head2 filter_json_single_key_object

    $json = $json-&gt;filter_json_single_key_object($key [=&gt; $coderef])

Works remotely similar to C&lt;filter_json_object&gt;, but is only called for
JSON objects having a single key named C&lt;$key&gt;.

This C&lt;$coderef&gt; is called before the one specified via
C&lt;filter_json_object&gt;, if any. It gets passed the single value in the JSON
object. If it returns a single value, it will be inserted into the data
structure. If it returns nothing (not even C&lt;undef&gt; but the empty list),
the callback from C&lt;filter_json_object&gt; will be called next, as if no
single-key callback were specified.

If C&lt;$coderef&gt; is omitted or undefined, the corresponding callback will be
disabled. There can only ever be one callback for a given key.

As this callback gets called less often then the C&lt;filter_json_object&gt;
one, decoding speed will not usually suffer as much. Therefore, single-key
objects make excellent targets to serialise Perl objects into, especially
as single-key JSON objects are as close to the type-tagged value concept
as JSON gets (it's basically an ID/VALUE tuple). Of course, JSON does not
support this in any way, so you need to make sure your data never looks
like a serialised Perl hash.

Typical names for the single object key are C&lt;__class_whatever__&gt;, or
C&lt;$__dollars_are_rarely_used__$&gt; or C&lt;}ugly_brace_placement&gt;, or even
things like C&lt;__class_md5sum(classname)__&gt;, to reduce the risk of clashing
with real hashes.

Example, decode JSON objects of the form C&lt;&lt; { "__widget__" =&gt; &lt;id&gt; } &gt;&gt;
into the corresponding C&lt;&lt; $WIDGET{&lt;id&gt;} &gt;&gt; object:

   # return whatever is in $WIDGET{5}:
   JSON::PP
      -&gt;new
      -&gt;filter_json_single_key_object (__widget__ =&gt; sub {
            $WIDGET{ $_[0] }
         })
      -&gt;decode ('{"__widget__": 5')

   # this can be used with a TO_JSON method in some "widget" class
   # for serialisation to json:
   sub WidgetBase::TO_JSON {
      my ($self) = @_;

      unless ($self-&gt;{id}) {
         $self-&gt;{id} = ..get..some..id..;
         $WIDGET{$self-&gt;{id}} = $self;
      }

      { __widget__ =&gt; $self-&gt;{id} }
   }

=head2 shrink

    $json = $json-&gt;shrink([$enable])
    
    $enabled = $json-&gt;get_shrink

If C&lt;$enable&gt; is true (or missing), the string returned by C&lt;encode&gt; will
be shrunk (i.e. downgraded if possible).

The actual definition of what shrink does might change in future versions,
but it will always try to save space at the expense of time.

If C&lt;$enable&gt; is false, then JSON::PP does nothing.

=head2 max_depth

    $json = $json-&gt;max_depth([$maximum_nesting_depth])
    
    $max_depth = $json-&gt;get_max_depth

Sets the maximum nesting level (default C&lt;512&gt;) accepted while encoding
or decoding. If a higher nesting level is detected in JSON text or a Perl
data structure, then the encoder and decoder will stop and croak at that
point.

Nesting level is defined by number of hash- or arrayrefs that the encoder
needs to traverse to reach a given point or the number of C&lt;{&gt; or C&lt;[&gt;
characters without their matching closing parenthesis crossed to reach a
given character in a string.

Setting the maximum depth to one disallows any nesting, so that ensures
that the object is only a single hash/object or array.

If no argument is given, the highest possible setting will be used, which
is rarely useful.

See L&lt;JSON::XS/SECURITY CONSIDERATIONS&gt; for more info on why this is useful.

=head2 max_size

    $json = $json-&gt;max_size([$maximum_string_size])
    
    $max_size = $json-&gt;get_max_size

Set the maximum length a JSON text may have (in bytes) where decoding is
being attempted. The default is C&lt;0&gt;, meaning no limit. When C&lt;decode&gt;
is called on a string that is longer then this many bytes, it will not
attempt to decode the string but throw an exception. This setting has no
effect on C&lt;encode&gt; (yet).

If no argument is given, the limit check will be deactivated (same as when
C&lt;0&gt; is specified).

See L&lt;JSON::XS/SECURITY CONSIDERATIONS&gt; for more info on why this is useful.

=head2 encode

    $json_text = $json-&gt;encode($perl_scalar)

Converts the given Perl value or data structure to its JSON
representation. Croaks on error.

=head2 decode

    $perl_scalar = $json-&gt;decode($json_text)

The opposite of C&lt;encode&gt;: expects a JSON text and tries to parse it,
returning the resulting simple scalar or reference. Croaks on error.

=head2 decode_prefix

    ($perl_scalar, $characters) = $json-&gt;decode_prefix($json_text)

This works like the C&lt;decode&gt; method, but instead of raising an exception
when there is trailing garbage after the first JSON object, it will
silently stop parsing there and return the number of characters consumed
so far.

This is useful if your JSON texts are not delimited by an outer protocol
and you need to know where the JSON text ends.

   JSON::PP-&gt;new-&gt;decode_prefix ("[1] the tail")
   =&gt; ([1], 3)

=head1 FLAGS FOR JSON::PP ONLY

The following flags and properties are for JSON::PP only. If you use
any of these, you can't make your application run faster by replacing
JSON::PP with JSON::XS. If you need these and also speed boost,
you might want to try L&lt;Cpanel::JSON::XS&gt;, a fork of JSON::XS by
Reini Urban, which supports some of these (with a different set of
incompatibilities). Most of these historical flags are only kept
for backward compatibility, and should not be used in a new application.

=head2 allow_singlequote

    $json = $json-&gt;allow_singlequote([$enable])
    $enabled = $json-&gt;get_allow_singlequote

If C&lt;$enable&gt; is true (or missing), then C&lt;decode&gt; will accept
invalid JSON texts that contain strings that begin and end with
single quotation marks. C&lt;encode&gt; will not be affected in any way.
I&lt;Be aware that this option makes you accept invalid JSON texts
as if they were valid!&gt;. I suggest only to use this option to
parse application-specific files written by humans (configuration
files, resource files etc.)

If C&lt;$enable&gt; is false (the default), then C&lt;decode&gt; will only accept
valid JSON texts.

    $json-&gt;allow_singlequote-&gt;decode(qq|{"foo":'bar'}|);
    $json-&gt;allow_singlequote-&gt;decode(qq|{'foo':"bar"}|);
    $json-&gt;allow_singlequote-&gt;decode(qq|{'foo':'bar'}|);

=head2 allow_barekey

    $json = $json-&gt;allow_barekey([$enable])
    $enabled = $json-&gt;get_allow_barekey

If C&lt;$enable&gt; is true (or missing), then C&lt;decode&gt; will accept
invalid JSON texts that contain JSON objects whose names don't
begin and end with quotation marks. C&lt;encode&gt; will not be affected
in any way. I&lt;Be aware that this option makes you accept invalid JSON
texts as if they were valid!&gt;. I suggest only to use this option to
parse application-specific files written by humans (configuration
files, resource files etc.)

If C&lt;$enable&gt; is false (the default), then C&lt;decode&gt; will only accept
valid JSON texts.

    $json-&gt;allow_barekey-&gt;decode(qq|{foo:"bar"}|);

=head2 allow_bignum

    $json = $json-&gt;allow_bignum([$enable])
    $enabled = $json-&gt;get_allow_bignum

If C&lt;$enable&gt; is true (or missing), then C&lt;decode&gt; will convert
big integers Perl cannot handle as integer into L&lt;Math::BigInt&gt;
objects and convert floating numbers into L&lt;Math::BigFloat&gt;
objects. C&lt;encode&gt; will convert C&lt;Math::BigInt&gt; and C&lt;Math::BigFloat&gt;
objects into JSON numbers.

   $json-&gt;allow_nonref-&gt;allow_bignum;
   $bigfloat = $json-&gt;decode('2.000000000000000000000000001');
   print $json-&gt;encode($bigfloat);
   # =&gt; 2.000000000000000000000000001

See also L&lt;MAPPING&gt;.

=head2 loose

    $json = $json-&gt;loose([$enable])
    $enabled = $json-&gt;get_loose

If C&lt;$enable&gt; is true (or missing), then C&lt;decode&gt; will accept
invalid JSON texts that contain unescaped [\x00-\x1f\x22\x5c]
characters. C&lt;encode&gt; will not be affected in any way.
I&lt;Be aware that this option makes you accept invalid JSON texts
as if they were valid!&gt;. I suggest only to use this option to
parse application-specific files written by humans (configuration
files, resource files etc.)

If C&lt;$enable&gt; is false (the default), then C&lt;decode&gt; will only accept
valid JSON texts.

    $json-&gt;loose-&gt;decode(qq|["abc
                                   def"]|);

=head2 escape_slash

    $json = $json-&gt;escape_slash([$enable])
    $enabled = $json-&gt;get_escape_slash

If C&lt;$enable&gt; is true (or missing), then C&lt;encode&gt; will explicitly
escape I&lt;slash&gt; (solidus; C&lt;U+002F&gt;) characters to reduce the risk of
XSS (cross site scripting) that may be caused by C&lt;&lt; &lt;/script&gt; &gt;&gt;
in a JSON text, with the cost of bloating the size of JSON texts.

This option may be useful when you embed JSON in HTML, but embedding
arbitrary JSON in HTML (by some HTML template toolkit or by string
interpolation) is risky in general. You must escape necessary
characters in correct order, depending on the context.

C&lt;decode&gt; will not be affected in any way.

=head2 indent_length

    $json = $json-&gt;indent_length($number_of_spaces)
    $length = $json-&gt;get_indent_length

This option is only useful when you also enable C&lt;indent&gt; or C&lt;pretty&gt;.

JSON::XS indents with three spaces when you C&lt;encode&gt; (if requested
by C&lt;indent&gt; or C&lt;pretty&gt;), and the number cannot be changed.
JSON::PP allows you to change/get the number of indent spaces with these
mutator/accessor. The default number of spaces is three (the same as
JSON::XS), and the acceptable range is from C&lt;0&gt; (no indentation;
it'd be better to disable indentation by C&lt;indent(0)&gt;) to C&lt;15&gt;.

=head2 sort_by

    $json = $json-&gt;sort_by($code_ref)
    $json = $json-&gt;sort_by($subroutine_name)

If you just want to sort keys (names) in JSON objects when you
C&lt;encode&gt;, enable C&lt;canonical&gt; option (see above) that allows you to
sort object keys alphabetically.

If you do need to sort non-alphabetically for whatever reasons,
you can give a code reference (or a subroutine name) to C&lt;sort_by&gt;,
then the argument will be passed to Perl's C&lt;sort&gt; built-in function.

As the sorting is done in the JSON::PP scope, you usually need to
prepend C&lt;JSON::PP::&gt; to the subroutine name, and the special variables
C&lt;$a&gt; and C&lt;$b&gt; used in the subrontine used by C&lt;sort&gt; function.

Example:

   my %ORDER = (id =&gt; 1, class =&gt; 2, name =&gt; 3);
   $json-&gt;sort_by(sub {
       ($ORDER{$JSON::PP::a} // 999) &lt;=&gt; ($ORDER{$JSON::PP::b} // 999)
       or $JSON::PP::a cmp $JSON::PP::b
   });
   print $json-&gt;encode([
       {name =&gt; 'CPAN', id =&gt; 1, href =&gt; 'http://cpan.org'}
   ]);
   # [{"id":1,"name":"CPAN","href":"http://cpan.org"}]

Note that C&lt;sort_by&gt; affects all the plain hashes in the data structure.
If you need finer control, C&lt;tie&gt; necessary hashes with a module that
implements ordered hash (such as L&lt;Hash::Ordered&gt; and L&lt;Tie::IxHash&gt;).
C&lt;canonical&gt; and C&lt;sort_by&gt; don't affect the key order in C&lt;tie&gt;d
hashes.

   use Hash::Ordered;
   tie my %hash, 'Hash::Ordered',
       (name =&gt; 'CPAN', id =&gt; 1, href =&gt; 'http://cpan.org');
   print $json-&gt;encode([\%hash]);
   # [{"name":"CPAN","id":1,"href":"http://cpan.org"}] # order is kept

=head1 INCREMENTAL PARSING

This section is also taken from JSON::XS.

In some cases, there is the need for incremental parsing of JSON
texts. While this module always has to keep both JSON text and resulting
Perl data structure in memory at one time, it does allow you to parse a
JSON stream incrementally. It does so by accumulating text until it has
a full JSON object, which it then can decode. This process is similar to
using C&lt;decode_prefix&gt; to see if a full JSON object is available, but
is much more efficient (and can be implemented with a minimum of method
calls).

JSON::PP will only attempt to parse the JSON text once it is sure it
has enough text to get a decisive result, using a very simple but
truly incremental parser. This means that it sometimes won't stop as
early as the full parser, for example, it doesn't detect mismatched
parentheses. The only thing it guarantees is that it starts decoding as
soon as a syntactically valid JSON text has been seen. This means you need
to set resource limits (e.g. C&lt;max_size&gt;) to ensure the parser will stop
parsing in the presence if syntax errors.

The following methods implement this incremental parser.

=head2 incr_parse

    $json-&gt;incr_parse( [$string] ) # void context
    
    $obj_or_undef = $json-&gt;incr_parse( [$string] ) # scalar context
    
    @obj_or_empty = $json-&gt;incr_parse( [$string] ) # list context

This is the central parsing function. It can both append new text and
extract objects from the stream accumulated so far (both of these
functions are optional).

If C&lt;$string&gt; is given, then this string is appended to the already
existing JSON fragment stored in the C&lt;$json&gt; object.

After that, if the function is called in void context, it will simply
return without doing anything further. This can be used to add more text
in as many chunks as you want.

If the method is called in scalar context, then it will try to extract
exactly I&lt;one&gt; JSON object. If that is successful, it will return this
object, otherwise it will return C&lt;undef&gt;. If there is a parse error,
this method will croak just as C&lt;decode&gt; would do (one can then use
C&lt;incr_skip&gt; to skip the erroneous part). This is the most common way of
using the method.

And finally, in list context, it will try to extract as many objects
from the stream as it can find and return them, or the empty list
otherwise. For this to work, there must be no separators (other than
whitespace) between the JSON objects or arrays, instead they must be
concatenated back-to-back. If an error occurs, an exception will be
raised as in the scalar context case. Note that in this case, any
previously-parsed JSON texts will be lost.

Example: Parse some JSON arrays/objects in a given string and return
them.

    my @objs = JSON::PP-&gt;new-&gt;incr_parse ("[5][7][1,2]");

=head2 incr_text

    $lvalue_string = $json-&gt;incr_text

This method returns the currently stored JSON fragment as an lvalue, that
is, you can manipulate it. This I&lt;only&gt; works when a preceding call to
C&lt;incr_parse&gt; in I&lt;scalar context&gt; successfully returned an object. Under
all other circumstances you must not call this function (I mean it.
although in simple tests it might actually work, it I&lt;will&gt; fail under
real world conditions). As a special exception, you can also call this
method before having parsed anything.

That means you can only use this function to look at or manipulate text
before or after complete JSON objects, not while the parser is in the
middle of parsing a JSON object.

This function is useful in two cases: a) finding the trailing text after a
JSON object or b) parsing multiple JSON objects separated by non-JSON text
(such as commas).

=head2 incr_skip

    $json-&gt;incr_skip

This will reset the state of the incremental parser and will remove
the parsed text from the input buffer so far. This is useful after
C&lt;incr_parse&gt; died, in which case the input buffer and incremental parser
state is left unchanged, to skip the text parsed so far and to reset the
parse state.

The difference to C&lt;incr_reset&gt; is that only text until the parse error
occurred is removed.

=head2 incr_reset

    $json-&gt;incr_reset

This completely resets the incremental parser, that is, after this call,
it will be as if the parser had never parsed anything.

This is useful if you want to repeatedly parse JSON objects and want to
ignore any trailing data, which means you have to reset the parser after
each successful decode.

=head1 MAPPING

Most of this section is also taken from JSON::XS.

This section describes how JSON::PP maps Perl values to JSON values and
vice versa. These mappings are designed to "do the right thing" in most
circumstances automatically, preserving round-tripping characteristics
(what you put in comes out as something equivalent).

For the more enlightened: note that in the following descriptions,
lowercase I&lt;perl&gt; refers to the Perl interpreter, while uppercase I&lt;Perl&gt;
refers to the abstract Perl language itself.

=head2 JSON -&gt; PERL

=over 4

=item object

A JSON object becomes a reference to a hash in Perl. No ordering of object
keys is preserved (JSON does not preserve object key ordering itself).

=item array

A JSON array becomes a reference to an array in Perl.

=item string

A JSON string becomes a string scalar in Perl - Unicode codepoints in JSON
are represented by the same codepoints in the Perl string, so no manual
decoding is necessary.

=item number

A JSON number becomes either an integer, numeric (floating point) or
string scalar in perl, depending on its range and any fractional parts. On
the Perl level, there is no difference between those as Perl handles all
the conversion details, but an integer may take slightly less memory and
might represent more values exactly than floating point numbers.

If the number consists of digits only, JSON::PP will try to represent
it as an integer value. If that fails, it will try to represent it as
a numeric (floating point) value if that is possible without loss of
precision. Otherwise it will preserve the number as a string value (in
which case you lose roundtripping ability, as the JSON number will be
re-encoded to a JSON string).

Numbers containing a fractional or exponential part will always be
represented as numeric (floating point) values, possibly at a loss of
precision (in which case you might lose perfect roundtripping ability, but
the JSON number will still be re-encoded as a JSON number).

Note that precision is not accuracy - binary floating point values cannot
represent most decimal fractions exactly, and when converting from and to
floating point, JSON::PP only guarantees precision up to but not including
the least significant bit.

When C&lt;allow_bignum&gt; is enabled, big integer values and any numeric
values will be converted into L&lt;Math::BigInt&gt; and L&lt;Math::BigFloat&gt;
objects respectively, without becoming string scalars or losing
precision.

=item true, false

These JSON atoms become C&lt;JSON::PP::true&gt; and C&lt;JSON::PP::false&gt;,
respectively. They are overloaded to act almost exactly like the numbers
C&lt;1&gt; and C&lt;0&gt;. You can check whether a scalar is a JSON boolean by using
the C&lt;JSON::PP::is_bool&gt; function.

=item null

A JSON null atom becomes C&lt;undef&gt; in Perl.

=item shell-style comments (C&lt;&lt; # I&lt;text&gt; &gt;&gt;)

As a nonstandard extension to the JSON syntax that is enabled by the
C&lt;relaxed&gt; setting, shell-style comments are allowed. They can start
anywhere outside strings and go till the end of the line.

=item tagged values (C&lt;&lt; (I&lt;tag&gt;)I&lt;value&gt; &gt;&gt;).

Another nonstandard extension to the JSON syntax, enabled with the
C&lt;allow_tags&gt; setting, are tagged values. In this implementation, the
I&lt;tag&gt; must be a perl package/class name encoded as a JSON string, and the
I&lt;value&gt; must be a JSON array encoding optional constructor arguments.

See L&lt;OBJECT SERIALISATION&gt;, below, for details.

=back


=head2 PERL -&gt; JSON

The mapping from Perl to JSON is slightly more difficult, as Perl is a
truly typeless language, so we can only guess which JSON type is meant by
a Perl value.

=over 4

=item hash references

Perl hash references become JSON objects. As there is no inherent
ordering in hash keys (or JSON objects), they will usually be encoded
in a pseudo-random order. JSON::PP can optionally sort the hash keys
(determined by the I&lt;canonical&gt; flag and/or I&lt;sort_by&gt; property), so
the same data structure will serialise to the same JSON text (given
same settings and version of JSON::PP), but this incurs a runtime
overhead and is only rarely useful, e.g. when you want to compare some
JSON text against another for equality.

=item array references

Perl array references become JSON arrays.

=item other references

Other unblessed references are generally not allowed and will cause an
exception to be thrown, except for references to the integers C&lt;0&gt; and
C&lt;1&gt;, which get turned into C&lt;false&gt; and C&lt;true&gt; atoms in JSON. You can
also use C&lt;JSON::PP::false&gt; and C&lt;JSON::PP::true&gt; to improve
readability.

   to_json [\0, JSON::PP::true]      # yields [false,true]

=item JSON::PP::true, JSON::PP::false

These special values become JSON true and JSON false values,
respectively. You can also use C&lt;\1&gt; and C&lt;\0&gt; directly if you want.

=item JSON::PP::null

This special value becomes JSON null.

=item blessed objects

Blessed objects are not directly representable in JSON, but C&lt;JSON::PP&gt;
allows various ways of handling objects. See L&lt;OBJECT SERIALISATION&gt;,
below, for details.

=item simple scalars

Simple Perl scalars (any scalar that is not a reference) are the most
difficult objects to encode: JSON::PP will encode undefined scalars as
JSON C&lt;null&gt; values, scalars that have last been used in a string context
before encoding as JSON strings, and anything else as number value:

   # dump as number
   encode_json [2]                      # yields [2]
   encode_json [-3.0e17]                # yields [-3e+17]
   my $value = 5; encode_json [$value]  # yields [5]

   # used as string, so dump as string
   print $value;
   encode_json [$value]                 # yields ["5"]

   # undef becomes null
   encode_json [undef]                  # yields [null]

You can force the type to be a JSON string by stringifying it:

   my $x = 3.1; # some variable containing a number
   "$x";        # stringified
   $x .= "";    # another, more awkward way to stringify
   print $x;    # perl does it for you, too, quite often
                # (but for older perls)

You can force the type to be a JSON number by numifying it:

   my $x = "3"; # some variable containing a string
   $x += 0;     # numify it, ensuring it will be dumped as a number
   $x *= 1;     # same thing, the choice is yours.

You can not currently force the type in other, less obscure, ways.

Since version 2.91_01, JSON::PP uses a different number detection logic
that converts a scalar that is possible to turn into a number safely.
The new logic is slightly faster, and tends to help people who use older
perl or who want to encode complicated data structure. However, this may
results in a different JSON text from the one JSON::XS encodes (and
thus may break tests that compare entire JSON texts). If you do
need the previous behavior for compatibility or for finer control,
set PERL_JSON_PP_USE_B environmental variable to true before you
C&lt;use&gt; JSON::PP (or JSON.pm).

Note that numerical precision has the same meaning as under Perl (so
binary to decimal conversion follows the same rules as in Perl, which
can differ to other languages). Also, your perl interpreter might expose
extensions to the floating point numbers of your platform, such as
infinities or NaN's - these cannot be represented in JSON, and it is an
error to pass those in.

JSON::PP (and JSON::XS) trusts what you pass to C&lt;encode&gt; method
(or C&lt;encode_json&gt; function) is a clean, validated data structure with
values that can be represented as valid JSON values only, because it's
not from an external data source (as opposed to JSON texts you pass to
C&lt;decode&gt; or C&lt;decode_json&gt;, which JSON::PP considers tainted and
doesn't trust). As JSON::PP doesn't know exactly what you and consumers
of your JSON texts want the unexpected values to be (you may want to
convert them into null, or to stringify them with or without
normalisation (string representation of infinities/NaN may vary
depending on platforms), or to croak without conversion), you're advised
to do what you and your consumers need before you encode, and also not
to numify values that may start with values that look like a number
(including infinities/NaN), without validating.

=back

=head2 OBJECT SERIALISATION

As JSON cannot directly represent Perl objects, you have to choose between
a pure JSON representation (without the ability to deserialise the object
automatically again), and a nonstandard extension to the JSON syntax,
tagged values.

=head3 SERIALISATION

What happens when C&lt;JSON::PP&gt; encounters a Perl object depends on the
C&lt;allow_blessed&gt;, C&lt;convert_blessed&gt;, C&lt;allow_tags&gt; and C&lt;allow_bignum&gt;
settings, which are used in this order:

=over 4

=item 1. C&lt;allow_tags&gt; is enabled and the object has a C&lt;FREEZE&gt; method.

In this case, C&lt;JSON::PP&gt; creates a tagged JSON value, using a nonstandard
extension to the JSON syntax.

This works by invoking the C&lt;FREEZE&gt; method on the object, with the first
argument being the object to serialise, and the second argument being the
constant string C&lt;JSON&gt; to distinguish it from other serialisers.

The C&lt;FREEZE&gt; method can return any number of values (i.e. zero or
more). These values and the paclkage/classname of the object will then be
encoded as a tagged JSON value in the following format:

   ("classname")[FREEZE return values...]

e.g.:

   ("URI")["http://www.google.com/"]
   ("MyDate")[2013,10,29]
   ("ImageData::JPEG")["Z3...VlCg=="]

For example, the hypothetical C&lt;My::Object&gt; C&lt;FREEZE&gt; method might use the
objects C&lt;type&gt; and C&lt;id&gt; members to encode the object:

   sub My::Object::FREEZE {
      my ($self, $serialiser) = @_;

      ($self-&gt;{type}, $self-&gt;{id})
   }

=item 2. C&lt;convert_blessed&gt; is enabled and the object has a C&lt;TO_JSON&gt; method.

In this case, the C&lt;TO_JSON&gt; method of the object is invoked in scalar
context. It must return a single scalar that can be directly encoded into
JSON. This scalar replaces the object in the JSON text.

For example, the following C&lt;TO_JSON&gt; method will convert all L&lt;URI&gt;
objects to JSON strings when serialised. The fact that these values
originally were L&lt;URI&gt; objects is lost.

   sub URI::TO_JSON {
      my ($uri) = @_;
      $uri-&gt;as_string
   }

=item 3. C&lt;allow_bignum&gt; is enabled and the object is a C&lt;Math::BigInt&gt; or C&lt;Math::BigFloat&gt;.

The object will be serialised as a JSON number value.

=item 4. C&lt;allow_blessed&gt; is enabled.

The object will be serialised as a JSON null value.

=item 5. none of the above

If none of the settings are enabled or the respective methods are missing,
C&lt;JSON::PP&gt; throws an exception.

=back

=head3 DESERIALISATION

For deserialisation there are only two cases to consider: either
nonstandard tagging was used, in which case C&lt;allow_tags&gt; decides,
or objects cannot be automatically be deserialised, in which
case you can use postprocessing or the C&lt;filter_json_object&gt; or
C&lt;filter_json_single_key_object&gt; callbacks to get some real objects our of
your JSON.

This section only considers the tagged value case: a tagged JSON object
is encountered during decoding and C&lt;allow_tags&gt; is disabled, a parse
error will result (as if tagged values were not part of the grammar).

If C&lt;allow_tags&gt; is enabled, C&lt;JSON::PP&gt; will look up the C&lt;THAW&gt; method
of the package/classname used during serialisation (it will not attempt
to load the package as a Perl module). If there is no such method, the
decoding will fail with an error.

Otherwise, the C&lt;THAW&gt; method is invoked with the classname as first
argument, the constant string C&lt;JSON&gt; as second argument, and all the
values from the JSON array (the values originally returned by the
C&lt;FREEZE&gt; method) as remaining arguments.

The method must then return the object. While technically you can return
any Perl scalar, you might have to enable the C&lt;allow_nonref&gt; setting to
make that work in all cases, so better return an actual blessed reference.

As an example, let's implement a C&lt;THAW&gt; function that regenerates the
C&lt;My::Object&gt; from the C&lt;FREEZE&gt; example earlier:

   sub My::Object::THAW {
      my ($class, $serialiser, $type, $id) = @_;

      $class-&gt;new (type =&gt; $type, id =&gt; $id)
   }


=head1 ENCODING/CODESET FLAG NOTES

This section is taken from JSON::XS.

The interested reader might have seen a number of flags that signify
encodings or codesets - C&lt;utf8&gt;, C&lt;latin1&gt; and C&lt;ascii&gt;. There seems to be
some confusion on what these do, so here is a short comparison:

C&lt;utf8&gt; controls whether the JSON text created by C&lt;encode&gt; (and expected
by C&lt;decode&gt;) is UTF-8 encoded or not, while C&lt;latin1&gt; and C&lt;ascii&gt; only
control whether C&lt;encode&gt; escapes character values outside their respective
codeset range. Neither of these flags conflict with each other, although
some combinations make less sense than others.

Care has been taken to make all flags symmetrical with respect to
C&lt;encode&gt; and C&lt;decode&gt;, that is, texts encoded with any combination of
these flag values will be correctly decoded when the same flags are used
- in general, if you use different flag settings while encoding vs. when
decoding you likely have a bug somewhere.

Below comes a verbose discussion of these flags. Note that a "codeset" is
simply an abstract set of character-codepoint pairs, while an encoding
takes those codepoint numbers and I&lt;encodes&gt; them, in our case into
octets. Unicode is (among other things) a codeset, UTF-8 is an encoding,
and ISO-8859-1 (= latin 1) and ASCII are both codesets I&lt;and&gt; encodings at
the same time, which can be confusing.

=over 4

=item C&lt;utf8&gt; flag disabled

When C&lt;utf8&gt; is disabled (the default), then C&lt;encode&gt;/C&lt;decode&gt; generate
and expect Unicode strings, that is, characters with high ordinal Unicode
values (&gt; 255) will be encoded as such characters, and likewise such
characters are decoded as-is, no changes to them will be done, except
"(re-)interpreting" them as Unicode codepoints or Unicode characters,
respectively (to Perl, these are the same thing in strings unless you do
funny/weird/dumb stuff).

This is useful when you want to do the encoding yourself (e.g. when you
want to have UTF-16 encoded JSON texts) or when some other layer does
the encoding for you (for example, when printing to a terminal using a
filehandle that transparently encodes to UTF-8 you certainly do NOT want
to UTF-8 encode your data first and have Perl encode it another time).

=item C&lt;utf8&gt; flag enabled

If the C&lt;utf8&gt;-flag is enabled, C&lt;encode&gt;/C&lt;decode&gt; will encode all
characters using the corresponding UTF-8 multi-byte sequence, and will
expect your input strings to be encoded as UTF-8, that is, no "character"
of the input string must have any value &gt; 255, as UTF-8 does not allow
that.

The C&lt;utf8&gt; flag therefore switches between two modes: disabled means you
will get a Unicode string in Perl, enabled means you get an UTF-8 encoded
octet/binary string in Perl.

=item C&lt;latin1&gt; or C&lt;ascii&gt; flags enabled

With C&lt;latin1&gt; (or C&lt;ascii&gt;) enabled, C&lt;encode&gt; will escape characters
with ordinal values &gt; 255 (&gt; 127 with C&lt;ascii&gt;) and encode the remaining
characters as specified by the C&lt;utf8&gt; flag.

If C&lt;utf8&gt; is disabled, then the result is also correctly encoded in those
character sets (as both are proper subsets of Unicode, meaning that a
Unicode string with all character values &lt; 256 is the same thing as a
ISO-8859-1 string, and a Unicode string with all character values &lt; 128 is
the same thing as an ASCII string in Perl).

If C&lt;utf8&gt; is enabled, you still get a correct UTF-8-encoded string,
regardless of these flags, just some more characters will be escaped using
C&lt;\uXXXX&gt; then before.

Note that ISO-8859-1-I&lt;encoded&gt; strings are not compatible with UTF-8
encoding, while ASCII-encoded strings are. That is because the ISO-8859-1
encoding is NOT a subset of UTF-8 (despite the ISO-8859-1 I&lt;codeset&gt; being
a subset of Unicode), while ASCII is.

Surprisingly, C&lt;decode&gt; will ignore these flags and so treat all input
values as governed by the C&lt;utf8&gt; flag. If it is disabled, this allows you
to decode ISO-8859-1- and ASCII-encoded strings, as both strict subsets of
Unicode. If it is enabled, you can correctly decode UTF-8 encoded strings.

So neither C&lt;latin1&gt; nor C&lt;ascii&gt; are incompatible with the C&lt;utf8&gt; flag -
they only govern when the JSON output engine escapes a character or not.

The main use for C&lt;latin1&gt; is to relatively efficiently store binary data
as JSON, at the expense of breaking compatibility with most JSON decoders.

The main use for C&lt;ascii&gt; is to force the output to not contain characters
with values &gt; 127, which means you can interpret the resulting string
as UTF-8, ISO-8859-1, ASCII, KOI8-R or most about any character set and
8-bit-encoding, and still get the same data structure back. This is useful
when your channel for JSON transfer is not 8-bit clean or the encoding
might be mangled in between (e.g. in mail), and works because ASCII is a
proper subset of most 8-bit and multibyte encodings in use in the world.

=back

=head1 BUGS

Please report bugs on a specific behavior of this module to RT or GitHub
issues (preferred):

L&lt;https://github.com/makamaka/JSON-PP/issues&gt;

L&lt;https://rt.cpan.org/Public/Dist/Display.html?Queue=JSON-PP&gt;

As for new features and requests to change common behaviors, please
ask the author of JSON::XS (Marc Lehmann, E&lt;lt&gt;schmorp[at]schmorp.deE&lt;gt&gt;)
first, by email (important!), to keep compatibility among JSON.pm backends.

Generally speaking, if you need something special for you, you are advised
to create a new module, maybe based on L&lt;JSON::Tiny&gt;, which is smaller and
written in a much cleaner way than this module.

=head1 SEE ALSO

The F&lt;json_pp&gt; command line utility for quick experiments.

L&lt;JSON::XS&gt;, L&lt;Cpanel::JSON::XS&gt;, and L&lt;JSON::Tiny&gt; for faster alternatives.
L&lt;JSON&gt; and L&lt;JSON::MaybeXS&gt; for easy migration.

L&lt;JSON::backportPP::Compat5005&gt; and L&lt;JSON::backportPP::Compat5006&gt; for older perl users.

RFC4627 (L&lt;http://www.ietf.org/rfc/rfc4627.txt&gt;)

RFC7159 (L&lt;http://www.ietf.org/rfc/rfc7159.txt&gt;)

RFC8259 (L&lt;http://www.ietf.org/rfc/rfc8259.txt&gt;)

=head1 AUTHOR

Makamaka Hannyaharamitu, E&lt;lt&gt;makamaka[at]cpan.orgE&lt;gt&gt;

=head1 CURRENT MAINTAINER

Kenichi Ishigaki, E&lt;lt&gt;ishigaki[at]cpan.orgE&lt;gt&gt;

=head1 COPYRIGHT AND LICENSE

Copyright 2007-2016 by Makamaka Hannyaharamitu

Most of the documentation is taken from JSON::XS by Marc Lehmann

This library is free software; you can redistribute it and/or modify
it under the same terms as Perl itself. 

=cut
</pre></body></html>