<html><head><meta name="color-scheme" content="light dark"></head><body><pre style="word-wrap: break-word; white-space: pre-wrap;">##
## Hungarian tables based on English
##
#
# This is a just-because-I-stumbled-across-it
# -and-my-wife-is-Hungarian release: if Graham or
# someone adds to docs to Date::Format, I'd be
# glad to correct bugs and extend as neeed.
#

package Date::Language::Hungarian;

=head1 NAME

Date::Language::Hungarian - Magyar format for Date::Format

=head1 SYNOPSIS

	my $lang = Date::Language-&gt;new('Hungarian');
	print $lang-&gt;time2str("%a %b %e %T %Y", time);

	@lt = localtime(time);
	print $lang-&gt;time2str($template, time);
	print $lang-&gt;strftime($template, @lt);

	print $lang-&gt;time2str($template, time, $zone);
	print $lang-&gt;strftime($template, @lt, $zone);

	print $lang-&gt;ctime(time);
	print $lang-&gt;asctime(@lt);

	print $lang-&gt;ctime(time, $zone);
	print $lang-&gt;asctime(@lt, $zone);

See L&lt;Date::Format&gt;.

=head1 AUTHOR

Paula Goddard (paula -at- paulacska -dot- com)

=head1 LICENCE

Made available under the same terms as Perl itself.

=cut

use strict;
use warnings;
use base "Date::Language";
use vars qw( @DoW @DoWs @MoY @MoYs @AMPM @Dsuf %MoY %DoW $VERSION);
$VERSION = "1.01";

@DoW = qw(Vasárnap Hétfő Kedd Szerda Csütörtök Péntek Szombat);
@MoY = qw(Január Február Március Április Május Június
	  Július Augusztus Szeptember Október November December);
@DoWs = map { substr($_,0,3) } @DoW;
@MoYs = map { substr($_,0,3) } @MoY;
@AMPM = qw(DE. DU.);

# There is no 'th or 'nd in Hungarian, just a dot
@Dsuf = (".") x 31;

@MoY{@MoY}  = (0 .. scalar(@MoY));
@MoY{@MoYs} = (0 .. scalar(@MoYs));
@DoW{@DoW}  = (0 .. scalar(@DoW));
@DoW{@DoWs} = (0 .. scalar(@DoWs));

# Formatting routines

sub format_a { $DoWs[$_[0]-&gt;[6]] }
sub format_A { $DoW[$_[0]-&gt;[6]] }
sub format_b { $MoYs[$_[0]-&gt;[4]] }
sub format_B { $MoY[$_[0]-&gt;[4]] }
sub format_h { $MoYs[$_[0]-&gt;[4]] }
sub format_p { $_[0]-&gt;[2] &gt;= 12 ?  $AMPM[1] : $AMPM[0] }
sub format_P { lc($_[0]-&gt;[2] &gt;= 12 ?  $AMPM[1] : $AMPM[0]) }
sub format_o { $_[0]-&gt;[3].'.' }



sub format_D { &amp;format_y . "." . &amp;format_m . "." . &amp;format_d  }

sub format_y { sprintf("%02d",$_[0]-&gt;[5] % 100) }
sub format_d { sprintf("%02d",$_[0]-&gt;[3]) }
sub format_m { sprintf("%02d",$_[0]-&gt;[4] + 1) }


1;
</pre></body></html>