<html><head><meta name="color-scheme" content="light dark"></head><body><pre style="word-wrap: break-word; white-space: pre-wrap;">#
# Complex numbers and associated mathematical functions
# -- Raphael Manfredi	Since Sep 1996
# -- Jarkko Hietaniemi	Since Mar 1997
# -- Daniel S. Lewart	Since Sep 1997
#

package Math::Complex;

{ use 5.006; }
use strict;

our $VERSION = 1.62;

use Config;

our ($Inf, $ExpInf);
our ($vax_float, $has_inf, $has_nan);

BEGIN {
    $vax_float = (pack("d",1) =~ /^[\x80\x10]\x40/);
    $has_inf   = !$vax_float;
    $has_nan   = !$vax_float;

    unless ($has_inf) {
      # For example in vax, there is no Inf,
      # and just mentioning the DBL_MAX (1.70141183460469229e+38)
      # causes SIGFPE.

      # These are pretty useless without a real infinity,
      # but setting them makes for less warnings about their
      # undefined values.
      $Inf = "Inf";
      $ExpInf = "Inf";
      return;
    }

    my %DBL_MAX =  # These are IEEE 754 maxima.
	(
	  4  =&gt; '1.70141183460469229e+38',
	  8  =&gt; '1.7976931348623157e+308',
	 # AFAICT the 10, 12, and 16-byte long doubles
	 # all have the same maximum.
	 10 =&gt; '1.1897314953572317650857593266280070162E+4932',
	 12 =&gt; '1.1897314953572317650857593266280070162E+4932',
	 16 =&gt; '1.1897314953572317650857593266280070162E+4932',
	);

    my $nvsize = $Config{nvsize} ||
	        ($Config{uselongdouble} &amp;&amp; $Config{longdblsize}) ||
                 $Config{doublesize};
    die "Math::Complex: Could not figure out nvsize\n"
	unless defined $nvsize;
    die "Math::Complex: Cannot not figure out max nv (nvsize = $nvsize)\n"
	unless defined $DBL_MAX{$nvsize};
    my $DBL_MAX = eval $DBL_MAX{$nvsize};
    die "Math::Complex: Could not figure out max nv (nvsize = $nvsize)\n"
	unless defined $DBL_MAX;
    my $BIGGER_THAN_THIS = 1e30;  # Must find something bigger than this.
    if ($^O eq 'unicosmk') {
	$Inf = $DBL_MAX;
    } else {
	local $SIG{FPE} = sub { };
        local $!;
	# We do want an arithmetic overflow, Inf INF inf Infinity.
	for my $t (
	    'exp(99999)',  # Enough even with 128-bit long doubles.
	    'inf',
	    'Inf',
	    'INF',
	    'infinity',
	    'Infinity',
	    'INFINITY',
	    '1e99999',
	    ) {
	    local $^W = 0;
	    my $i = eval "$t+1.0";
	    if (defined $i &amp;&amp; $i &gt; $BIGGER_THAN_THIS) {
		$Inf = $i;
		last;
	    }
          }
	$Inf = $DBL_MAX unless defined $Inf;  # Oh well, close enough.
	die "Math::Complex: Could not get Infinity"
	    unless $Inf &gt; $BIGGER_THAN_THIS;
	$ExpInf = eval 'exp(99999)';
      }
    # print "# On this machine, Inf = '$Inf'\n";
}

use Scalar::Util qw(set_prototype);

use warnings;
no warnings 'syntax';  # To avoid the (_) warnings.

BEGIN {
    # For certain functions that we override, in 5.10 or better
    # we can set a smarter prototype that will handle the lexical $_
    # (also a 5.10+ feature).
    if ($] &gt;= 5.010000) {
        set_prototype \&amp;abs, '_';
        set_prototype \&amp;cos, '_';
        set_prototype \&amp;exp, '_';
        set_prototype \&amp;log, '_';
        set_prototype \&amp;sin, '_';
        set_prototype \&amp;sqrt, '_';
    }
}

my $i;
my %LOGN;

# Regular expression for floating point numbers.
# These days we could use Scalar::Util::lln(), I guess.
my $gre = qr'\s*([\+\-]?(?:(?:(?:\d+(?:_\d+)*(?:\.\d*(?:_\d+)*)?|\.\d+(?:_\d+)*)(?:[eE][\+\-]?\d+(?:_\d+)*)?))|inf)'i;

require Exporter;

our @ISA = qw(Exporter);

my @trig = qw(
	      pi
	      tan
	      csc cosec sec cot cotan
	      asin acos atan
	      acsc acosec asec acot acotan
	      sinh cosh tanh
	      csch cosech sech coth cotanh
	      asinh acosh atanh
	      acsch acosech asech acoth acotanh
	     );

our @EXPORT = (qw(
	     i Re Im rho theta arg
	     sqrt log ln
	     log10 logn cbrt root
	     cplx cplxe
	     atan2
	     ),
	   @trig);

my @pi = qw(pi pi2 pi4 pip2 pip4 Inf);

our @EXPORT_OK = @pi;

our %EXPORT_TAGS = (
    'trig' =&gt; [@trig],
    'pi' =&gt; [@pi],
);

use overload
	'='	=&gt; \&amp;_copy,
	'+='	=&gt; \&amp;_plus,
	'+'	=&gt; \&amp;_plus,
	'-='	=&gt; \&amp;_minus,
	'-'	=&gt; \&amp;_minus,
	'*='	=&gt; \&amp;_multiply,
	'*'	=&gt; \&amp;_multiply,
	'/='	=&gt; \&amp;_divide,
	'/'	=&gt; \&amp;_divide,
	'**='	=&gt; \&amp;_power,
	'**'	=&gt; \&amp;_power,
	'=='	=&gt; \&amp;_numeq,
	'&lt;=&gt;'	=&gt; \&amp;_spaceship,
	'neg'	=&gt; \&amp;_negate,
	'~'	=&gt; \&amp;_conjugate,
	'abs'	=&gt; \&amp;abs,
	'sqrt'	=&gt; \&amp;sqrt,
	'exp'	=&gt; \&amp;exp,
	'log'	=&gt; \&amp;log,
	'sin'	=&gt; \&amp;sin,
	'cos'	=&gt; \&amp;cos,
	'atan2'	=&gt; \&amp;atan2,
        '""'    =&gt; \&amp;_stringify;

#
# Package "privates"
#

my %DISPLAY_FORMAT = ('style' =&gt; 'cartesian',
		      'polar_pretty_print' =&gt; 1);
my $eps            = 1e-14;		# Epsilon

#
# Object attributes (internal):
#	cartesian	[real, imaginary] -- cartesian form
#	polar		[rho, theta] -- polar form
#	c_dirty		cartesian form not up-to-date
#	p_dirty		polar form not up-to-date
#	display		display format (package's global when not set)
#

# Die on bad *make() arguments.

sub _cannot_make {
    die "@{[(caller(1))[3]]}: Cannot take $_[0] of '$_[1]'.\n";
}

sub _make {
    my $arg = shift;
    my ($p, $q);

    if ($arg =~ /^$gre$/) {
	($p, $q) = ($1, 0);
    } elsif ($arg =~ /^(?:$gre)?$gre\s*i\s*$/) {
	($p, $q) = ($1 || 0, $2);
    } elsif ($arg =~ /^\s*\(\s*$gre\s*(?:,\s*$gre\s*)?\)\s*$/) {
	($p, $q) = ($1, $2 || 0);
    }

    if (defined $p) {
	$p =~ s/^\+//;
	$p =~ s/^(-?)inf$/"${1}9**9**9"/e if $has_inf;
	$q =~ s/^\+//;
	$q =~ s/^(-?)inf$/"${1}9**9**9"/e if $has_inf;
    }

    return ($p, $q);
}

sub _emake {
    my $arg = shift;
    my ($p, $q);

    if ($arg =~ /^\s*\[\s*$gre\s*(?:,\s*$gre\s*)?\]\s*$/) {
	($p, $q) = ($1, $2 || 0);
    } elsif ($arg =~ m!^\s*\[\s*$gre\s*(?:,\s*([-+]?\d*\s*)?pi(?:/\s*(\d+))?\s*)?\]\s*$!) {
	($p, $q) = ($1, ($2 eq '-' ? -1 : ($2 || 1)) * pi() / ($3 || 1));
    } elsif ($arg =~ /^\s*\[\s*$gre\s*\]\s*$/) {
	($p, $q) = ($1, 0);
    } elsif ($arg =~ /^\s*$gre\s*$/) {
	($p, $q) = ($1, 0);
    }

    if (defined $p) {
	$p =~ s/^\+//;
	$q =~ s/^\+//;
	$p =~ s/^(-?)inf$/"${1}9**9**9"/e if $has_inf;
	$q =~ s/^(-?)inf$/"${1}9**9**9"/e if $has_inf;
    }

    return ($p, $q);
}

sub _copy {
    my $self = shift;
    my $clone = {%$self};
    if ($self-&gt;{'cartesian'}) {
	$clone-&gt;{'cartesian'} = [@{$self-&gt;{'cartesian'}}];
    }
    if ($self-&gt;{'polar'}) {
	$clone-&gt;{'polar'} = [@{$self-&gt;{'polar'}}];
    }
    bless $clone,__PACKAGE__;
    return $clone;
}

#
# -&gt;make
#
# Create a new complex number (cartesian form)
#
sub make {
    my $self = bless {}, shift;
    my ($re, $im);
    if (@_ == 0) {
	($re, $im) = (0, 0);
    } elsif (@_ == 1) {
	return (ref $self)-&gt;emake($_[0])
	    if ($_[0] =~ /^\s*\[/);
	($re, $im) = _make($_[0]);
    } elsif (@_ == 2) {
	($re, $im) = @_;
    }
    if (defined $re) {
	_cannot_make("real part",      $re) unless $re =~ /^$gre$/;
    }
    $im ||= 0;
    _cannot_make("imaginary part", $im) unless $im =~ /^$gre$/;
    $self-&gt;_set_cartesian([$re, $im ]);
    $self-&gt;display_format('cartesian');

    return $self;
}

#
# -&gt;emake
#
# Create a new complex number (exponential form)
#
sub emake {
    my $self = bless {}, shift;
    my ($rho, $theta);
    if (@_ == 0) {
	($rho, $theta) = (0, 0);
    } elsif (@_ == 1) {
	return (ref $self)-&gt;make($_[0])
	    if ($_[0] =~ /^\s*\(/ || $_[0] =~ /i\s*$/);
	($rho, $theta) = _emake($_[0]);
    } elsif (@_ == 2) {
	($rho, $theta) = @_;
    }
    if (defined $rho &amp;&amp; defined $theta) {
	if ($rho &lt; 0) {
	    $rho   = -$rho;
	    $theta = ($theta &lt;= 0) ? $theta + pi() : $theta - pi();
	}
    }
    if (defined $rho) {
	_cannot_make("rho",   $rho)   unless $rho   =~ /^$gre$/;
    }
    $theta ||= 0;
    _cannot_make("theta", $theta) unless $theta =~ /^$gre$/;
    $self-&gt;_set_polar([$rho, $theta]);
    $self-&gt;display_format('polar');

    return $self;
}

sub new { &amp;make }		# For backward compatibility only.

#
# cplx
#
# Creates a complex number from a (re, im) tuple.
# This avoids the burden of writing Math::Complex-&gt;make(re, im).
#
sub cplx {
	return __PACKAGE__-&gt;make(@_);
}

#
# cplxe
#
# Creates a complex number from a (rho, theta) tuple.
# This avoids the burden of writing Math::Complex-&gt;emake(rho, theta).
#
sub cplxe {
	return __PACKAGE__-&gt;emake(@_);
}

#
# pi
#
# The number defined as pi = 180 degrees
#
sub pi () { 4 * CORE::atan2(1, 1) }

#
# pi2
#
# The full circle
#
sub pi2 () { 2 * pi }

#
# pi4
#
# The full circle twice.
#
sub pi4 () { 4 * pi }

#
# pip2
#
# The quarter circle
#
sub pip2 () { pi / 2 }

#
# pip4
#
# The eighth circle.
#
sub pip4 () { pi / 4 }

#
# _uplog10
#
# Used in log10().
#
sub _uplog10 () { 1 / CORE::log(10) }

#
# i
#
# The number defined as i*i = -1;
#
sub i () {
        return $i if ($i);
	$i = bless {};
	$i-&gt;{'cartesian'} = [0, 1];
	$i-&gt;{'polar'}     = [1, pip2];
	$i-&gt;{c_dirty} = 0;
	$i-&gt;{p_dirty} = 0;
	return $i;
}

#
# _ip2
#
# Half of i.
#
sub _ip2 () { i / 2 }

#
# Attribute access/set routines
#

sub _cartesian {$_[0]-&gt;{c_dirty} ?
		   $_[0]-&gt;_update_cartesian : $_[0]-&gt;{'cartesian'}}
sub _polar     {$_[0]-&gt;{p_dirty} ?
		   $_[0]-&gt;_update_polar : $_[0]-&gt;{'polar'}}

sub _set_cartesian { $_[0]-&gt;{p_dirty}++; $_[0]-&gt;{c_dirty} = 0;
		     $_[0]-&gt;{'cartesian'} = $_[1] }
sub _set_polar     { $_[0]-&gt;{c_dirty}++; $_[0]-&gt;{p_dirty} = 0;
		     $_[0]-&gt;{'polar'} = $_[1] }

#
# -&gt;_update_cartesian
#
# Recompute and return the cartesian form, given accurate polar form.
#
sub _update_cartesian {
	my $self = shift;
	my ($r, $t) = @{$self-&gt;{'polar'}};
	$self-&gt;{c_dirty} = 0;
	return $self-&gt;{'cartesian'} = [$r * CORE::cos($t), $r * CORE::sin($t)];
}

#
#
# -&gt;_update_polar
#
# Recompute and return the polar form, given accurate cartesian form.
#
sub _update_polar {
	my $self = shift;
	my ($x, $y) = @{$self-&gt;{'cartesian'}};
	$self-&gt;{p_dirty} = 0;
	return $self-&gt;{'polar'} = [0, 0] if $x == 0 &amp;&amp; $y == 0;
	return $self-&gt;{'polar'} = [CORE::sqrt($x*$x + $y*$y),
				   CORE::atan2($y, $x)];
}

#
# (_plus)
#
# Computes z1+z2.
#
sub _plus {
	my ($z1, $z2, $regular) = @_;
	my ($re1, $im1) = @{$z1-&gt;_cartesian};
	$z2 = cplx($z2) unless ref $z2;
	my ($re2, $im2) = ref $z2 ? @{$z2-&gt;_cartesian} : ($z2, 0);
	unless (defined $regular) {
		$z1-&gt;_set_cartesian([$re1 + $re2, $im1 + $im2]);
		return $z1;
	}
	return (ref $z1)-&gt;make($re1 + $re2, $im1 + $im2);
}

#
# (_minus)
#
# Computes z1-z2.
#
sub _minus {
	my ($z1, $z2, $inverted) = @_;
	my ($re1, $im1) = @{$z1-&gt;_cartesian};
	$z2 = cplx($z2) unless ref $z2;
	my ($re2, $im2) = @{$z2-&gt;_cartesian};
	unless (defined $inverted) {
		$z1-&gt;_set_cartesian([$re1 - $re2, $im1 - $im2]);
		return $z1;
	}
	return $inverted ?
		(ref $z1)-&gt;make($re2 - $re1, $im2 - $im1) :
		(ref $z1)-&gt;make($re1 - $re2, $im1 - $im2);

}

#
# (_multiply)
#
# Computes z1*z2.
#
sub _multiply {
        my ($z1, $z2, $regular) = @_;
	if ($z1-&gt;{p_dirty} == 0 and ref $z2 and $z2-&gt;{p_dirty} == 0) {
	    # if both polar better use polar to avoid rounding errors
	    my ($r1, $t1) = @{$z1-&gt;_polar};
	    my ($r2, $t2) = @{$z2-&gt;_polar};
	    my $t = $t1 + $t2;
	    if    ($t &gt;   pi()) { $t -= pi2 }
	    elsif ($t &lt;= -pi()) { $t += pi2 }
	    unless (defined $regular) {
		$z1-&gt;_set_polar([$r1 * $r2, $t]);
		return $z1;
	    }
	    return (ref $z1)-&gt;emake($r1 * $r2, $t);
	} else {
	    my ($x1, $y1) = @{$z1-&gt;_cartesian};
	    if (ref $z2) {
		my ($x2, $y2) = @{$z2-&gt;_cartesian};
		return (ref $z1)-&gt;make($x1*$x2-$y1*$y2, $x1*$y2+$y1*$x2);
	    } else {
		return (ref $z1)-&gt;make($x1*$z2, $y1*$z2);
	    }
	}
}

#
# _divbyzero
#
# Die on division by zero.
#
sub _divbyzero {
    my $mess = "$_[0]: Division by zero.\n";

    if (defined $_[1]) {
	$mess .= "(Because in the definition of $_[0], the divisor ";
	$mess .= "$_[1] " unless ("$_[1]" eq '0');
	$mess .= "is 0)\n";
    }

    my @up = caller(1);

    $mess .= "Died at $up[1] line $up[2].\n";

    die $mess;
}

#
# (_divide)
#
# Computes z1/z2.
#
sub _divide {
	my ($z1, $z2, $inverted) = @_;
	if ($z1-&gt;{p_dirty} == 0 and ref $z2 and $z2-&gt;{p_dirty} == 0) {
	    # if both polar better use polar to avoid rounding errors
	    my ($r1, $t1) = @{$z1-&gt;_polar};
	    my ($r2, $t2) = @{$z2-&gt;_polar};
	    my $t;
	    if ($inverted) {
		_divbyzero "$z2/0" if ($r1 == 0);
		$t = $t2 - $t1;
		if    ($t &gt;   pi()) { $t -= pi2 }
		elsif ($t &lt;= -pi()) { $t += pi2 }
		return (ref $z1)-&gt;emake($r2 / $r1, $t);
	    } else {
		_divbyzero "$z1/0" if ($r2 == 0);
		$t = $t1 - $t2;
		if    ($t &gt;   pi()) { $t -= pi2 }
		elsif ($t &lt;= -pi()) { $t += pi2 }
		return (ref $z1)-&gt;emake($r1 / $r2, $t);
	    }
	} else {
	    my ($d, $x2, $y2);
	    if ($inverted) {
		($x2, $y2) = @{$z1-&gt;_cartesian};
		$d = $x2*$x2 + $y2*$y2;
		_divbyzero "$z2/0" if $d == 0;
		return (ref $z1)-&gt;make(($x2*$z2)/$d, -($y2*$z2)/$d);
	    } else {
		my ($x1, $y1) = @{$z1-&gt;_cartesian};
		if (ref $z2) {
		    ($x2, $y2) = @{$z2-&gt;_cartesian};
		    $d = $x2*$x2 + $y2*$y2;
		    _divbyzero "$z1/0" if $d == 0;
		    my $u = ($x1*$x2 + $y1*$y2)/$d;
		    my $v = ($y1*$x2 - $x1*$y2)/$d;
		    return (ref $z1)-&gt;make($u, $v);
		} else {
		    _divbyzero "$z1/0" if $z2 == 0;
		    return (ref $z1)-&gt;make($x1/$z2, $y1/$z2);
		}
	    }
	}
}

#
# (_power)
#
# Computes z1**z2 = exp(z2 * log z1)).
#
sub _power {
	my ($z1, $z2, $inverted) = @_;
	if ($inverted) {
	    return 1 if $z1 == 0 || $z2 == 1;
	    return 0 if $z2 == 0 &amp;&amp; Re($z1) &gt; 0;
	} else {
	    return 1 if $z2 == 0 || $z1 == 1;
	    return 0 if $z1 == 0 &amp;&amp; Re($z2) &gt; 0;
	}
	my $w = $inverted ? &amp;exp($z1 * &amp;log($z2))
	                  : &amp;exp($z2 * &amp;log($z1));
	# If both arguments cartesian, return cartesian, else polar.
	return $z1-&gt;{c_dirty} == 0 &amp;&amp;
	       (not ref $z2 or $z2-&gt;{c_dirty} == 0) ?
	       cplx(@{$w-&gt;_cartesian}) : $w;
}

#
# (_spaceship)
#
# Computes z1 &lt;=&gt; z2.
# Sorts on the real part first, then on the imaginary part. Thus 2-4i &lt; 3+8i.
#
sub _spaceship {
	my ($z1, $z2, $inverted) = @_;
	my ($re1, $im1) = ref $z1 ? @{$z1-&gt;_cartesian} : ($z1, 0);
	my ($re2, $im2) = ref $z2 ? @{$z2-&gt;_cartesian} : ($z2, 0);
	my $sgn = $inverted ? -1 : 1;
	return $sgn * ($re1 &lt;=&gt; $re2) if $re1 != $re2;
	return $sgn * ($im1 &lt;=&gt; $im2);
}

#
# (_numeq)
#
# Computes z1 == z2.
#
# (Required in addition to _spaceship() because of NaNs.)
sub _numeq {
	my ($z1, $z2, $inverted) = @_;
	my ($re1, $im1) = ref $z1 ? @{$z1-&gt;_cartesian} : ($z1, 0);
	my ($re2, $im2) = ref $z2 ? @{$z2-&gt;_cartesian} : ($z2, 0);
	return $re1 == $re2 &amp;&amp; $im1 == $im2 ? 1 : 0;
}

#
# (_negate)
#
# Computes -z.
#
sub _negate {
	my ($z) = @_;
	if ($z-&gt;{c_dirty}) {
		my ($r, $t) = @{$z-&gt;_polar};
		$t = ($t &lt;= 0) ? $t + pi : $t - pi;
		return (ref $z)-&gt;emake($r, $t);
	}
	my ($re, $im) = @{$z-&gt;_cartesian};
	return (ref $z)-&gt;make(-$re, -$im);
}

#
# (_conjugate)
#
# Compute complex's _conjugate.
#
sub _conjugate {
	my ($z) = @_;
	if ($z-&gt;{c_dirty}) {
		my ($r, $t) = @{$z-&gt;_polar};
		return (ref $z)-&gt;emake($r, -$t);
	}
	my ($re, $im) = @{$z-&gt;_cartesian};
	return (ref $z)-&gt;make($re, -$im);
}

#
# (abs)
#
# Compute or set complex's norm (rho).
#
sub abs {
	my ($z, $rho) = @_ ? @_ : $_;
	unless (ref $z) {
	    if (@_ == 2) {
		$_[0] = $_[1];
	    } else {
		return CORE::abs($z);
	    }
	}
	if (defined $rho) {
	    $z-&gt;{'polar'} = [ $rho, ${$z-&gt;_polar}[1] ];
	    $z-&gt;{p_dirty} = 0;
	    $z-&gt;{c_dirty} = 1;
	    return $rho;
	} else {
	    return ${$z-&gt;_polar}[0];
	}
}

sub _theta {
    my $theta = $_[0];

    if    ($$theta &gt;   pi()) { $$theta -= pi2 }
    elsif ($$theta &lt;= -pi()) { $$theta += pi2 }
}

#
# arg
#
# Compute or set complex's argument (theta).
#
sub arg {
	my ($z, $theta) = @_;
	return $z unless ref $z;
	if (defined $theta) {
	    _theta(\$theta);
	    $z-&gt;{'polar'} = [ ${$z-&gt;_polar}[0], $theta ];
	    $z-&gt;{p_dirty} = 0;
	    $z-&gt;{c_dirty} = 1;
	} else {
	    $theta = ${$z-&gt;_polar}[1];
	    _theta(\$theta);
	}
	return $theta;
}

#
# (sqrt)
#
# Compute sqrt(z).
#
# It is quite tempting to use wantarray here so that in list context
# sqrt() would return the two solutions.  This, however, would
# break things like
#
#	print "sqrt(z) = ", sqrt($z), "\n";
#
# The two values would be printed side by side without no intervening
# whitespace, quite confusing.
# Therefore if you want the two solutions use the root().
#
sub sqrt {
	my ($z) = @_ ? $_[0] : $_;
	my ($re, $im) = ref $z ? @{$z-&gt;_cartesian} : ($z, 0);
	return $re &lt; 0 ? cplx(0, CORE::sqrt(-$re)) : CORE::sqrt($re)
	    if $im == 0;
	my ($r, $t) = @{$z-&gt;_polar};
	return (ref $z)-&gt;emake(CORE::sqrt($r), $t/2);
}

#
# cbrt
#
# Compute cbrt(z) (cubic root).
#
# Why are we not returning three values?  The same answer as for sqrt().
#
sub cbrt {
	my ($z) = @_;
	return $z &lt; 0 ?
	    -CORE::exp(CORE::log(-$z)/3) :
		($z &gt; 0 ? CORE::exp(CORE::log($z)/3): 0)
	    unless ref $z;
	my ($r, $t) = @{$z-&gt;_polar};
	return 0 if $r == 0;
	return (ref $z)-&gt;emake(CORE::exp(CORE::log($r)/3), $t/3);
}

#
# _rootbad
#
# Die on bad root.
#
sub _rootbad {
    my $mess = "Root '$_[0]' illegal, root rank must be positive integer.\n";

    my @up = caller(1);

    $mess .= "Died at $up[1] line $up[2].\n";

    die $mess;
}

#
# root
#
# Computes all nth root for z, returning an array whose size is n.
# `n' must be a positive integer.
#
# The roots are given by (for k = 0..n-1):
#
# z^(1/n) = r^(1/n) (cos ((t+2 k pi)/n) + i sin ((t+2 k pi)/n))
#
sub root {
	my ($z, $n, $k) = @_;
	_rootbad($n) if ($n &lt; 1 or int($n) != $n);
	my ($r, $t) = ref $z ?
	    @{$z-&gt;_polar} : (CORE::abs($z), $z &gt;= 0 ? 0 : pi);
	my $theta_inc = pi2 / $n;
	my $rho = $r ** (1/$n);
	my $cartesian = ref $z &amp;&amp; $z-&gt;{c_dirty} == 0;
	if (@_ == 2) {
	    my @root;
	    for (my $i = 0, my $theta = $t / $n;
		 $i &lt; $n;
		 $i++, $theta += $theta_inc) {
		my $w = cplxe($rho, $theta);
		# Yes, $cartesian is loop invariant.
		push @root, $cartesian ? cplx(@{$w-&gt;_cartesian}) : $w;
	    }
	    return @root;
	} elsif (@_ == 3) {
	    my $w = cplxe($rho, $t / $n + $k * $theta_inc);
	    return $cartesian ? cplx(@{$w-&gt;_cartesian}) : $w;
	}
}

#
# Re
#
# Return or set Re(z).
#
sub Re {
	my ($z, $Re) = @_;
	return $z unless ref $z;
	if (defined $Re) {
	    $z-&gt;{'cartesian'} = [ $Re, ${$z-&gt;_cartesian}[1] ];
	    $z-&gt;{c_dirty} = 0;
	    $z-&gt;{p_dirty} = 1;
	} else {
	    return ${$z-&gt;_cartesian}[0];
	}
}

#
# Im
#
# Return or set Im(z).
#
sub Im {
	my ($z, $Im) = @_;
	return 0 unless ref $z;
	if (defined $Im) {
	    $z-&gt;{'cartesian'} = [ ${$z-&gt;_cartesian}[0], $Im ];
	    $z-&gt;{c_dirty} = 0;
	    $z-&gt;{p_dirty} = 1;
	} else {
	    return ${$z-&gt;_cartesian}[1];
	}
}

#
# rho
#
# Return or set rho(w).
#
sub rho {
    Math::Complex::abs(@_);
}

#
# theta
#
# Return or set theta(w).
#
sub theta {
    Math::Complex::arg(@_);
}

#
# (exp)
#
# Computes exp(z).
#
sub exp {
    my ($z) = @_ ? @_ : $_;
    return CORE::exp($z) unless ref $z;
    my ($x, $y) = @{$z-&gt;_cartesian};
    return (ref $z)-&gt;emake(CORE::exp($x), $y);
}

#
# _logofzero
#
# Die on logarithm of zero.
#
sub _logofzero {
    my $mess = "$_[0]: Logarithm of zero.\n";

    if (defined $_[1]) {
	$mess .= "(Because in the definition of $_[0], the argument ";
	$mess .= "$_[1] " unless ($_[1] eq '0');
	$mess .= "is 0)\n";
    }

    my @up = caller(1);

    $mess .= "Died at $up[1] line $up[2].\n";

    die $mess;
}

#
# (log)
#
# Compute log(z).
#
sub log {
	my ($z) = @_ ? @_ : $_;
	unless (ref $z) {
	    _logofzero("log") if $z == 0;
	    return $z &gt; 0 ? CORE::log($z) : cplx(CORE::log(-$z), pi);
	}
	my ($r, $t) = @{$z-&gt;_polar};
	_logofzero("log") if $r == 0;
	if    ($t &gt;   pi()) { $t -= pi2 }
	elsif ($t &lt;= -pi()) { $t += pi2 }
	return (ref $z)-&gt;make(CORE::log($r), $t);
}

#
# ln
#
# Alias for log().
#
sub ln { Math::Complex::log(@_) }

#
# log10
#
# Compute log10(z).
#

sub log10 {
	return Math::Complex::log($_[0]) * _uplog10;
}

#
# logn
#
# Compute logn(z,n) = log(z) / log(n)
#
sub logn {
	my ($z, $n) = @_;
	$z = cplx($z, 0) unless ref $z;
	my $logn = $LOGN{$n};
	$logn = $LOGN{$n} = CORE::log($n) unless defined $logn;	# Cache log(n)
	return &amp;log($z) / $logn;
}

#
# (cos)
#
# Compute cos(z) = (exp(iz) + exp(-iz))/2.
#
sub cos {
	my ($z) = @_ ? @_ : $_;
	return CORE::cos($z) unless ref $z;
	my ($x, $y) = @{$z-&gt;_cartesian};
	my $ey = CORE::exp($y);
	my $sx = CORE::sin($x);
	my $cx = CORE::cos($x);
	my $ey_1 = $ey ? 1 / $ey : Inf();
	return (ref $z)-&gt;make($cx * ($ey + $ey_1)/2,
			      $sx * ($ey_1 - $ey)/2);
}

#
# (sin)
#
# Compute sin(z) = (exp(iz) - exp(-iz))/2.
#
sub sin {
	my ($z) = @_ ? @_ : $_;
	return CORE::sin($z) unless ref $z;
	my ($x, $y) = @{$z-&gt;_cartesian};
	my $ey = CORE::exp($y);
	my $sx = CORE::sin($x);
	my $cx = CORE::cos($x);
	my $ey_1 = $ey ? 1 / $ey : Inf();
	return (ref $z)-&gt;make($sx * ($ey + $ey_1)/2,
			      $cx * ($ey - $ey_1)/2);
}

#
# tan
#
# Compute tan(z) = sin(z) / cos(z).
#
sub tan {
	my ($z) = @_;
	my $cz = &amp;cos($z);
	_divbyzero "tan($z)", "cos($z)" if $cz == 0;
	return &amp;sin($z) / $cz;
}

#
# sec
#
# Computes the secant sec(z) = 1 / cos(z).
#
sub sec {
	my ($z) = @_;
	my $cz = &amp;cos($z);
	_divbyzero "sec($z)", "cos($z)" if ($cz == 0);
	return 1 / $cz;
}

#
# csc
#
# Computes the cosecant csc(z) = 1 / sin(z).
#
sub csc {
	my ($z) = @_;
	my $sz = &amp;sin($z);
	_divbyzero "csc($z)", "sin($z)" if ($sz == 0);
	return 1 / $sz;
}

#
# cosec
#
# Alias for csc().
#
sub cosec { Math::Complex::csc(@_) }

#
# cot
#
# Computes cot(z) = cos(z) / sin(z).
#
sub cot {
	my ($z) = @_;
	my $sz = &amp;sin($z);
	_divbyzero "cot($z)", "sin($z)" if ($sz == 0);
	return &amp;cos($z) / $sz;
}

#
# cotan
#
# Alias for cot().
#
sub cotan { Math::Complex::cot(@_) }

#
# acos
#
# Computes the arc cosine acos(z) = -i log(z + sqrt(z*z-1)).
#
sub acos {
	my $z = $_[0];
	return CORE::atan2(CORE::sqrt(1-$z*$z), $z)
	    if (! ref $z) &amp;&amp; CORE::abs($z) &lt;= 1;
	$z = cplx($z, 0) unless ref $z;
	my ($x, $y) = @{$z-&gt;_cartesian};
	return 0 if $x == 1 &amp;&amp; $y == 0;
	my $t1 = CORE::sqrt(($x+1)*($x+1) + $y*$y);
	my $t2 = CORE::sqrt(($x-1)*($x-1) + $y*$y);
	my $alpha = ($t1 + $t2)/2;
	my $beta  = ($t1 - $t2)/2;
	$alpha = 1 if $alpha &lt; 1;
	if    ($beta &gt;  1) { $beta =  1 }
	elsif ($beta &lt; -1) { $beta = -1 }
	my $u = CORE::atan2(CORE::sqrt(1-$beta*$beta), $beta);
	my $v = CORE::log($alpha + CORE::sqrt($alpha*$alpha-1));
	$v = -$v if $y &gt; 0 || ($y == 0 &amp;&amp; $x &lt; -1);
	return (ref $z)-&gt;make($u, $v);
}

#
# asin
#
# Computes the arc sine asin(z) = -i log(iz + sqrt(1-z*z)).
#
sub asin {
	my $z = $_[0];
	return CORE::atan2($z, CORE::sqrt(1-$z*$z))
	    if (! ref $z) &amp;&amp; CORE::abs($z) &lt;= 1;
	$z = cplx($z, 0) unless ref $z;
	my ($x, $y) = @{$z-&gt;_cartesian};
	return 0 if $x == 0 &amp;&amp; $y == 0;
	my $t1 = CORE::sqrt(($x+1)*($x+1) + $y*$y);
	my $t2 = CORE::sqrt(($x-1)*($x-1) + $y*$y);
	my $alpha = ($t1 + $t2)/2;
	my $beta  = ($t1 - $t2)/2;
	$alpha = 1 if $alpha &lt; 1;
	if    ($beta &gt;  1) { $beta =  1 }
	elsif ($beta &lt; -1) { $beta = -1 }
	my $u =  CORE::atan2($beta, CORE::sqrt(1-$beta*$beta));
	my $v = -CORE::log($alpha + CORE::sqrt($alpha*$alpha-1));
	$v = -$v if $y &gt; 0 || ($y == 0 &amp;&amp; $x &lt; -1);
	return (ref $z)-&gt;make($u, $v);
}

#
# atan
#
# Computes the arc tangent atan(z) = i/2 log((i+z) / (i-z)).
#
sub atan {
	my ($z) = @_;
	return CORE::atan2($z, 1) unless ref $z;
	my ($x, $y) = ref $z ? @{$z-&gt;_cartesian} : ($z, 0);
	return 0 if $x == 0 &amp;&amp; $y == 0;
	_divbyzero "atan(i)"  if ( $z == i);
	_logofzero "atan(-i)" if (-$z == i); # -i is a bad file test...
	my $log = &amp;log((i + $z) / (i - $z));
	return _ip2 * $log;
}

#
# asec
#
# Computes the arc secant asec(z) = acos(1 / z).
#
sub asec {
	my ($z) = @_;
	_divbyzero "asec($z)", $z if ($z == 0);
	return acos(1 / $z);
}

#
# acsc
#
# Computes the arc cosecant acsc(z) = asin(1 / z).
#
sub acsc {
	my ($z) = @_;
	_divbyzero "acsc($z)", $z if ($z == 0);
	return asin(1 / $z);
}

#
# acosec
#
# Alias for acsc().
#
sub acosec { Math::Complex::acsc(@_) }

#
# acot
#
# Computes the arc cotangent acot(z) = atan(1 / z)
#
sub acot {
	my ($z) = @_;
	_divbyzero "acot(0)"  if $z == 0;
	return ($z &gt;= 0) ? CORE::atan2(1, $z) : CORE::atan2(-1, -$z)
	    unless ref $z;
	_divbyzero "acot(i)"  if ($z - i == 0);
	_logofzero "acot(-i)" if ($z + i == 0);
	return atan(1 / $z);
}

#
# acotan
#
# Alias for acot().
#
sub acotan { Math::Complex::acot(@_) }

#
# cosh
#
# Computes the hyperbolic cosine cosh(z) = (exp(z) + exp(-z))/2.
#
sub cosh {
	my ($z) = @_;
	my $ex;
	unless (ref $z) {
	    $ex = CORE::exp($z);
            return $ex ? ($ex == $ExpInf ? Inf() : ($ex + 1/$ex)/2) : Inf();
	}
	my ($x, $y) = @{$z-&gt;_cartesian};
	$ex = CORE::exp($x);
	my $ex_1 = $ex ? 1 / $ex : Inf();
	return (ref $z)-&gt;make(CORE::cos($y) * ($ex + $ex_1)/2,
			      CORE::sin($y) * ($ex - $ex_1)/2);
}

#
# sinh
#
# Computes the hyperbolic sine sinh(z) = (exp(z) - exp(-z))/2.
#
sub sinh {
	my ($z) = @_;
	my $ex;
	unless (ref $z) {
	    return 0 if $z == 0;
	    $ex = CORE::exp($z);
            return $ex ? ($ex == $ExpInf ? Inf() : ($ex - 1/$ex)/2) : -Inf();
	}
	my ($x, $y) = @{$z-&gt;_cartesian};
	my $cy = CORE::cos($y);
	my $sy = CORE::sin($y);
	$ex = CORE::exp($x);
	my $ex_1 = $ex ? 1 / $ex : Inf();
	return (ref $z)-&gt;make(CORE::cos($y) * ($ex - $ex_1)/2,
			      CORE::sin($y) * ($ex + $ex_1)/2);
}

#
# tanh
#
# Computes the hyperbolic tangent tanh(z) = sinh(z) / cosh(z).
#
sub tanh {
	my ($z) = @_;
	my $cz = cosh($z);
	_divbyzero "tanh($z)", "cosh($z)" if ($cz == 0);
	my $sz = sinh($z);
	return  1 if $cz ==  $sz;
	return -1 if $cz == -$sz;
	return $sz / $cz;
}

#
# sech
#
# Computes the hyperbolic secant sech(z) = 1 / cosh(z).
#
sub sech {
	my ($z) = @_;
	my $cz = cosh($z);
	_divbyzero "sech($z)", "cosh($z)" if ($cz == 0);
	return 1 / $cz;
}

#
# csch
#
# Computes the hyperbolic cosecant csch(z) = 1 / sinh(z).
#
sub csch {
	my ($z) = @_;
	my $sz = sinh($z);
	_divbyzero "csch($z)", "sinh($z)" if ($sz == 0);
	return 1 / $sz;
}

#
# cosech
#
# Alias for csch().
#
sub cosech { Math::Complex::csch(@_) }

#
# coth
#
# Computes the hyperbolic cotangent coth(z) = cosh(z) / sinh(z).
#
sub coth {
	my ($z) = @_;
	my $sz = sinh($z);
	_divbyzero "coth($z)", "sinh($z)" if $sz == 0;
	my $cz = cosh($z);
	return  1 if $cz ==  $sz;
	return -1 if $cz == -$sz;
	return $cz / $sz;
}

#
# cotanh
#
# Alias for coth().
#
sub cotanh { Math::Complex::coth(@_) }

#
# acosh
#
# Computes the area/inverse hyperbolic cosine acosh(z) = log(z + sqrt(z*z-1)).
#
sub acosh {
	my ($z) = @_;
	unless (ref $z) {
	    $z = cplx($z, 0);
	}
	my ($re, $im) = @{$z-&gt;_cartesian};
	if ($im == 0) {
	    return CORE::log($re + CORE::sqrt($re*$re - 1))
		if $re &gt;= 1;
	    return cplx(0, CORE::atan2(CORE::sqrt(1 - $re*$re), $re))
		if CORE::abs($re) &lt; 1;
	}
	my $t = &amp;sqrt($z * $z - 1) + $z;
	# Try Taylor if looking bad (this usually means that
	# $z was large negative, therefore the sqrt is really
	# close to abs(z), summing that with z...)
	$t = 1/(2 * $z) - 1/(8 * $z**3) + 1/(16 * $z**5) - 5/(128 * $z**7)
	    if $t == 0;
	my $u = &amp;log($t);
	$u-&gt;Im(-$u-&gt;Im) if $re &lt; 0 &amp;&amp; $im == 0;
	return $re &lt; 0 ? -$u : $u;
}

#
# asinh
#
# Computes the area/inverse hyperbolic sine asinh(z) = log(z + sqrt(z*z+1))
#
sub asinh {
	my ($z) = @_;
	unless (ref $z) {
	    my $t = $z + CORE::sqrt($z*$z + 1);
	    return CORE::log($t) if $t;
	}
	my $t = &amp;sqrt($z * $z + 1) + $z;
	# Try Taylor if looking bad (this usually means that
	# $z was large negative, therefore the sqrt is really
	# close to abs(z), summing that with z...)
	$t = 1/(2 * $z) - 1/(8 * $z**3) + 1/(16 * $z**5) - 5/(128 * $z**7)
	    if $t == 0;
	return &amp;log($t);
}

#
# atanh
#
# Computes the area/inverse hyperbolic tangent atanh(z) = 1/2 log((1+z) / (1-z)).
#
sub atanh {
	my ($z) = @_;
	unless (ref $z) {
	    return CORE::log((1 + $z)/(1 - $z))/2 if CORE::abs($z) &lt; 1;
	    $z = cplx($z, 0);
	}
	_divbyzero 'atanh(1)',  "1 - $z" if (1 - $z == 0);
	_logofzero 'atanh(-1)'           if (1 + $z == 0);
	return 0.5 * &amp;log((1 + $z) / (1 - $z));
}

#
# asech
#
# Computes the area/inverse hyperbolic secant asech(z) = acosh(1 / z).
#
sub asech {
	my ($z) = @_;
	_divbyzero 'asech(0)', "$z" if ($z == 0);
	return acosh(1 / $z);
}

#
# acsch
#
# Computes the area/inverse hyperbolic cosecant acsch(z) = asinh(1 / z).
#
sub acsch {
	my ($z) = @_;
	_divbyzero 'acsch(0)', $z if ($z == 0);
	return asinh(1 / $z);
}

#
# acosech
#
# Alias for acosh().
#
sub acosech { Math::Complex::acsch(@_) }

#
# acoth
#
# Computes the area/inverse hyperbolic cotangent acoth(z) = 1/2 log((1+z) / (z-1)).
#
sub acoth {
	my ($z) = @_;
	_divbyzero 'acoth(0)'            if ($z == 0);
	unless (ref $z) {
	    return CORE::log(($z + 1)/($z - 1))/2 if CORE::abs($z) &gt; 1;
	    $z = cplx($z, 0);
	}
	_divbyzero 'acoth(1)',  "$z - 1" if ($z - 1 == 0);
	_logofzero 'acoth(-1)', "1 + $z" if (1 + $z == 0);
	return &amp;log((1 + $z) / ($z - 1)) / 2;
}

#
# acotanh
#
# Alias for acot().
#
sub acotanh { Math::Complex::acoth(@_) }

#
# (atan2)
#
# Compute atan(z1/z2), minding the right quadrant.
#
sub atan2 {
	my ($z1, $z2, $inverted) = @_;
	my ($re1, $im1, $re2, $im2);
	if ($inverted) {
	    ($re1, $im1) = ref $z2 ? @{$z2-&gt;_cartesian} : ($z2, 0);
	    ($re2, $im2) = ref $z1 ? @{$z1-&gt;_cartesian} : ($z1, 0);
	} else {
	    ($re1, $im1) = ref $z1 ? @{$z1-&gt;_cartesian} : ($z1, 0);
	    ($re2, $im2) = ref $z2 ? @{$z2-&gt;_cartesian} : ($z2, 0);
	}
	if ($im1 || $im2) {
	    # In MATLAB the imaginary parts are ignored.
	    # warn "atan2: Imaginary parts ignored";
	    # http://documents.wolfram.com/mathematica/functions/ArcTan
	    # NOTE: Mathematica ArcTan[x,y] while atan2(y,x)
	    my $s = $z1 * $z1 + $z2 * $z2;
	    _divbyzero("atan2") if $s == 0;
	    my $i = &amp;i;
	    my $r = $z2 + $z1 * $i;
	    return -$i * &amp;log($r / &amp;sqrt( $s ));
	}
	return CORE::atan2($re1, $re2);
}

#
# display_format
# -&gt;display_format
#
# Set (get if no argument) the display format for all complex numbers that
# don't happen to have overridden it via -&gt;display_format
#
# When called as an object method, this actually sets the display format for
# the current object.
#
# Valid object formats are 'c' and 'p' for cartesian and polar. The first
# letter is used actually, so the type can be fully spelled out for clarity.
#
sub display_format {
	my $self  = shift;
	my %display_format = %DISPLAY_FORMAT;

	if (ref $self) {			# Called as an object method
	    if (exists $self-&gt;{display_format}) {
		my %obj = %{$self-&gt;{display_format}};
		@display_format{keys %obj} = values %obj;
	    }
	}
	if (@_ == 1) {
	    $display_format{style} = shift;
	} else {
	    my %new = @_;
	    @display_format{keys %new} = values %new;
	}

	if (ref $self) { # Called as an object method
	    $self-&gt;{display_format} = { %display_format };
	    return
		wantarray ?
		    %{$self-&gt;{display_format}} :
		    $self-&gt;{display_format}-&gt;{style};
	}

        # Called as a class method
	%DISPLAY_FORMAT = %display_format;
	return
	    wantarray ?
		%DISPLAY_FORMAT :
		    $DISPLAY_FORMAT{style};
}

#
# (_stringify)
#
# Show nicely formatted complex number under its cartesian or polar form,
# depending on the current display format:
#
# . If a specific display format has been recorded for this object, use it.
# . Otherwise, use the generic current default for all complex numbers,
#   which is a package global variable.
#
sub _stringify {
	my ($z) = shift;

	my $style = $z-&gt;display_format;

	$style = $DISPLAY_FORMAT{style} unless defined $style;

	return $z-&gt;_stringify_polar if $style =~ /^p/i;
	return $z-&gt;_stringify_cartesian;
}

#
# -&gt;_stringify_cartesian
#
# Stringify as a cartesian representation 'a+bi'.
#
sub _stringify_cartesian {
	my $z  = shift;
	my ($x, $y) = @{$z-&gt;_cartesian};
	my ($re, $im);

	my %format = $z-&gt;display_format;
	my $format = $format{format};

	if ($x) {
	    if ($x =~ /^NaN[QS]?$/i) {
		$re = $x;
	    } else {
		if ($x =~ /^-?\Q$Inf\E$/oi) {
		    $re = $x;
		} else {
		    $re = defined $format ? sprintf($format, $x) : $x;
		}
	    }
	} else {
	    undef $re;
	}

	if ($y) {
	    if ($y =~ /^(NaN[QS]?)$/i) {
		$im = $y;
	    } else {
		if ($y =~ /^-?\Q$Inf\E$/oi) {
		    $im = $y;
		} else {
		    $im =
			defined $format ?
			    sprintf($format, $y) :
			    ($y == 1 ? "" : ($y == -1 ? "-" : $y));
		}
	    }
	    $im .= "i";
	} else {
	    undef $im;
	}

	my $str = $re;

	if (defined $im) {
	    if ($y &lt; 0) {
		$str .= $im;
	    } elsif ($y &gt; 0 || $im =~ /^NaN[QS]?i$/i)  {
		$str .= "+" if defined $re;
		$str .= $im;
	    }
	} elsif (!defined $re) {
	    $str = "0";
	}

	return $str;
}


#
# -&gt;_stringify_polar
#
# Stringify as a polar representation '[r,t]'.
#
sub _stringify_polar {
	my $z  = shift;
	my ($r, $t) = @{$z-&gt;_polar};
	my $theta;

	my %format = $z-&gt;display_format;
	my $format = $format{format};

	if ($t =~ /^NaN[QS]?$/i || $t =~ /^-?\Q$Inf\E$/oi) {
	    $theta = $t; 
	} elsif ($t == pi) {
	    $theta = "pi";
	} elsif ($r == 0 || $t == 0) {
	    $theta = defined $format ? sprintf($format, $t) : $t;
	}

	return "[$r,$theta]" if defined $theta;

	#
	# Try to identify pi/n and friends.
	#

	$t -= int(CORE::abs($t) / pi2) * pi2;

	if ($format{polar_pretty_print} &amp;&amp; $t) {
	    my ($a, $b);
	    for $a (2..9) {
		$b = $t * $a / pi;
		if ($b =~ /^-?\d+$/) {
		    $b = $b &lt; 0 ? "-" : "" if CORE::abs($b) == 1;
		    $theta = "${b}pi/$a";
		    last;
		}
	    }
	}

        if (defined $format) {
	    $r     = sprintf($format, $r);
	    $theta = sprintf($format, $t) unless defined $theta;
	} else {
	    $theta = $t unless defined $theta;
	}

	return "[$r,$theta]";
}

sub Inf {
    return $Inf;
}

1;
__END__

=pod

=head1 NAME

Math::Complex - complex numbers and associated mathematical functions

=head1 SYNOPSIS

	use Math::Complex;

	$z = Math::Complex-&gt;make(5, 6);
	$t = 4 - 3*i + $z;
	$j = cplxe(1, 2*pi/3);

=head1 DESCRIPTION

This package lets you create and manipulate complex numbers. By default,
I&lt;Perl&gt; limits itself to real numbers, but an extra C&lt;use&gt; statement brings
full complex support, along with a full set of mathematical functions
typically associated with and/or extended to complex numbers.

If you wonder what complex numbers are, they were invented to be able to solve
the following equation:

	x*x = -1

and by definition, the solution is noted I&lt;i&gt; (engineers use I&lt;j&gt; instead since
I&lt;i&gt; usually denotes an intensity, but the name does not matter). The number
I&lt;i&gt; is a pure I&lt;imaginary&gt; number.

The arithmetics with pure imaginary numbers works just like you would expect
it with real numbers... you just have to remember that

	i*i = -1

so you have:

	5i + 7i = i * (5 + 7) = 12i
	4i - 3i = i * (4 - 3) = i
	4i * 2i = -8
	6i / 2i = 3
	1 / i = -i

Complex numbers are numbers that have both a real part and an imaginary
part, and are usually noted:

	a + bi

where C&lt;a&gt; is the I&lt;real&gt; part and C&lt;b&gt; is the I&lt;imaginary&gt; part. The
arithmetic with complex numbers is straightforward. You have to
keep track of the real and the imaginary parts, but otherwise the
rules used for real numbers just apply:

	(4 + 3i) + (5 - 2i) = (4 + 5) + i(3 - 2) = 9 + i
	(2 + i) * (4 - i) = 2*4 + 4i -2i -i*i = 8 + 2i + 1 = 9 + 2i

A graphical representation of complex numbers is possible in a plane
(also called the I&lt;complex plane&gt;, but it's really a 2D plane).
The number

	z = a + bi

is the point whose coordinates are (a, b). Actually, it would
be the vector originating from (0, 0) to (a, b). It follows that the addition
of two complex numbers is a vectorial addition.

Since there is a bijection between a point in the 2D plane and a complex
number (i.e. the mapping is unique and reciprocal), a complex number
can also be uniquely identified with polar coordinates:

	[rho, theta]

where C&lt;rho&gt; is the distance to the origin, and C&lt;theta&gt; the angle between
the vector and the I&lt;x&gt; axis. There is a notation for this using the
exponential form, which is:

	rho * exp(i * theta)

where I&lt;i&gt; is the famous imaginary number introduced above. Conversion
between this form and the cartesian form C&lt;a + bi&gt; is immediate:

	a = rho * cos(theta)
	b = rho * sin(theta)

which is also expressed by this formula:

	z = rho * exp(i * theta) = rho * (cos theta + i * sin theta)

In other words, it's the projection of the vector onto the I&lt;x&gt; and I&lt;y&gt;
axes. Mathematicians call I&lt;rho&gt; the I&lt;norm&gt; or I&lt;modulus&gt; and I&lt;theta&gt;
the I&lt;argument&gt; of the complex number. The I&lt;norm&gt; of C&lt;z&gt; is
marked here as C&lt;abs(z)&gt;.

The polar notation (also known as the trigonometric representation) is
much more handy for performing multiplications and divisions of
complex numbers, whilst the cartesian notation is better suited for
additions and subtractions. Real numbers are on the I&lt;x&gt; axis, and
therefore I&lt;y&gt; or I&lt;theta&gt; is zero or I&lt;pi&gt;.

All the common operations that can be performed on a real number have
been defined to work on complex numbers as well, and are merely
I&lt;extensions&gt; of the operations defined on real numbers. This means
they keep their natural meaning when there is no imaginary part, provided
the number is within their definition set.

For instance, the C&lt;sqrt&gt; routine which computes the square root of
its argument is only defined for non-negative real numbers and yields a
non-negative real number (it is an application from B&lt;R+&gt; to B&lt;R+&gt;).
If we allow it to return a complex number, then it can be extended to
negative real numbers to become an application from B&lt;R&gt; to B&lt;C&gt; (the
set of complex numbers):

	sqrt(x) = x &gt;= 0 ? sqrt(x) : sqrt(-x)*i

It can also be extended to be an application from B&lt;C&gt; to B&lt;C&gt;,
whilst its restriction to B&lt;R&gt; behaves as defined above by using
the following definition:

	sqrt(z = [r,t]) = sqrt(r) * exp(i * t/2)

Indeed, a negative real number can be noted C&lt;[x,pi]&gt; (the modulus
I&lt;x&gt; is always non-negative, so C&lt;[x,pi]&gt; is really C&lt;-x&gt;, a negative
number) and the above definition states that

	sqrt([x,pi]) = sqrt(x) * exp(i*pi/2) = [sqrt(x),pi/2] = sqrt(x)*i

which is exactly what we had defined for negative real numbers above.
The C&lt;sqrt&gt; returns only one of the solutions: if you want the both,
use the C&lt;root&gt; function.

All the common mathematical functions defined on real numbers that
are extended to complex numbers share that same property of working
I&lt;as usual&gt; when the imaginary part is zero (otherwise, it would not
be called an extension, would it?).

A I&lt;new&gt; operation possible on a complex number that is
the identity for real numbers is called the I&lt;conjugate&gt;, and is noted
with a horizontal bar above the number, or C&lt;~z&gt; here.

	 z = a + bi
	~z = a - bi

Simple... Now look:

	z * ~z = (a + bi) * (a - bi) = a*a + b*b

We saw that the norm of C&lt;z&gt; was noted C&lt;abs(z)&gt; and was defined as the
distance to the origin, also known as:

	rho = abs(z) = sqrt(a*a + b*b)

so

	z * ~z = abs(z) ** 2

If z is a pure real number (i.e. C&lt;b == 0&gt;), then the above yields:

	a * a = abs(a) ** 2

which is true (C&lt;abs&gt; has the regular meaning for real number, i.e. stands
for the absolute value). This example explains why the norm of C&lt;z&gt; is
noted C&lt;abs(z)&gt;: it extends the C&lt;abs&gt; function to complex numbers, yet
is the regular C&lt;abs&gt; we know when the complex number actually has no
imaginary part... This justifies I&lt;a posteriori&gt; our use of the C&lt;abs&gt;
notation for the norm.

=head1 OPERATIONS

Given the following notations:

	z1 = a + bi = r1 * exp(i * t1)
	z2 = c + di = r2 * exp(i * t2)
	z = &lt;any complex or real number&gt;

the following (overloaded) operations are supported on complex numbers:

	z1 + z2 = (a + c) + i(b + d)
	z1 - z2 = (a - c) + i(b - d)
	z1 * z2 = (r1 * r2) * exp(i * (t1 + t2))
	z1 / z2 = (r1 / r2) * exp(i * (t1 - t2))
	z1 ** z2 = exp(z2 * log z1)
	~z = a - bi
	abs(z) = r1 = sqrt(a*a + b*b)
	sqrt(z) = sqrt(r1) * exp(i * t/2)
	exp(z) = exp(a) * exp(i * b)
	log(z) = log(r1) + i*t
	sin(z) = 1/2i (exp(i * z1) - exp(-i * z))
	cos(z) = 1/2 (exp(i * z1) + exp(-i * z))
	atan2(y, x) = atan(y / x) # Minding the right quadrant, note the order.

The definition used for complex arguments of atan2() is

       -i log((x + iy)/sqrt(x*x+y*y))

Note that atan2(0, 0) is not well-defined.

The following extra operations are supported on both real and complex
numbers:

	Re(z) = a
	Im(z) = b
	arg(z) = t
	abs(z) = r

	cbrt(z) = z ** (1/3)
	log10(z) = log(z) / log(10)
	logn(z, n) = log(z) / log(n)

	tan(z) = sin(z) / cos(z)

	csc(z) = 1 / sin(z)
	sec(z) = 1 / cos(z)
	cot(z) = 1 / tan(z)

	asin(z) = -i * log(i*z + sqrt(1-z*z))
	acos(z) = -i * log(z + i*sqrt(1-z*z))
	atan(z) = i/2 * log((i+z) / (i-z))

	acsc(z) = asin(1 / z)
	asec(z) = acos(1 / z)
	acot(z) = atan(1 / z) = -i/2 * log((i+z) / (z-i))

	sinh(z) = 1/2 (exp(z) - exp(-z))
	cosh(z) = 1/2 (exp(z) + exp(-z))
	tanh(z) = sinh(z) / cosh(z) = (exp(z) - exp(-z)) / (exp(z) + exp(-z))

	csch(z) = 1 / sinh(z)
	sech(z) = 1 / cosh(z)
	coth(z) = 1 / tanh(z)

	asinh(z) = log(z + sqrt(z*z+1))
	acosh(z) = log(z + sqrt(z*z-1))
	atanh(z) = 1/2 * log((1+z) / (1-z))

	acsch(z) = asinh(1 / z)
	asech(z) = acosh(1 / z)
	acoth(z) = atanh(1 / z) = 1/2 * log((1+z) / (z-1))

I&lt;arg&gt;, I&lt;abs&gt;, I&lt;log&gt;, I&lt;csc&gt;, I&lt;cot&gt;, I&lt;acsc&gt;, I&lt;acot&gt;, I&lt;csch&gt;,
I&lt;coth&gt;, I&lt;acosech&gt;, I&lt;acotanh&gt;, have aliases I&lt;rho&gt;, I&lt;theta&gt;, I&lt;ln&gt;,
I&lt;cosec&gt;, I&lt;cotan&gt;, I&lt;acosec&gt;, I&lt;acotan&gt;, I&lt;cosech&gt;, I&lt;cotanh&gt;,
I&lt;acosech&gt;, I&lt;acotanh&gt;, respectively.  C&lt;Re&gt;, C&lt;Im&gt;, C&lt;arg&gt;, C&lt;abs&gt;,
C&lt;rho&gt;, and C&lt;theta&gt; can be used also as mutators.  The C&lt;cbrt&gt;
returns only one of the solutions: if you want all three, use the
C&lt;root&gt; function.

The I&lt;root&gt; function is available to compute all the I&lt;n&gt;
roots of some complex, where I&lt;n&gt; is a strictly positive integer.
There are exactly I&lt;n&gt; such roots, returned as a list. Getting the
number mathematicians call C&lt;j&gt; such that:

	1 + j + j*j = 0;

is a simple matter of writing:

	$j = (root(1, 3))[1];

The I&lt;k&gt;th root for C&lt;z = [r,t]&gt; is given by:

	(root(z, n))[k] = r**(1/n) * exp(i * (t + 2*k*pi)/n)

You can return the I&lt;k&gt;th root directly by C&lt;root(z, n, k)&gt;,
indexing starting from I&lt;zero&gt; and ending at I&lt;n - 1&gt;.

The I&lt;spaceship&gt; numeric comparison operator, E&lt;lt&gt;=E&lt;gt&gt;, is also
defined. In order to ensure its restriction to real numbers is conform
to what you would expect, the comparison is run on the real part of
the complex number first, and imaginary parts are compared only when
the real parts match.

=head1 CREATION

To create a complex number, use either:

	$z = Math::Complex-&gt;make(3, 4);
	$z = cplx(3, 4);

if you know the cartesian form of the number, or

	$z = 3 + 4*i;

if you like. To create a number using the polar form, use either:

	$z = Math::Complex-&gt;emake(5, pi/3);
	$x = cplxe(5, pi/3);

instead. The first argument is the modulus, the second is the angle
(in radians, the full circle is 2*pi).  (Mnemonic: C&lt;e&gt; is used as a
notation for complex numbers in the polar form).

It is possible to write:

	$x = cplxe(-3, pi/4);

but that will be silently converted into C&lt;[3,-3pi/4]&gt;, since the
modulus must be non-negative (it represents the distance to the origin
in the complex plane).

It is also possible to have a complex number as either argument of the
C&lt;make&gt;, C&lt;emake&gt;, C&lt;cplx&gt;, and C&lt;cplxe&gt;: the appropriate component of
the argument will be used.

	$z1 = cplx(-2,  1);
	$z2 = cplx($z1, 4);

The C&lt;new&gt;, C&lt;make&gt;, C&lt;emake&gt;, C&lt;cplx&gt;, and C&lt;cplxe&gt; will also
understand a single (string) argument of the forms

    	2-3i
    	-3i
	[2,3]
	[2,-3pi/4]
	[2]

in which case the appropriate cartesian and exponential components
will be parsed from the string and used to create new complex numbers.
The imaginary component and the theta, respectively, will default to zero.

The C&lt;new&gt;, C&lt;make&gt;, C&lt;emake&gt;, C&lt;cplx&gt;, and C&lt;cplxe&gt; will also
understand the case of no arguments: this means plain zero or (0, 0).

=head1 DISPLAYING

When printed, a complex number is usually shown under its cartesian
style I&lt;a+bi&gt;, but there are legitimate cases where the polar style
I&lt;[r,t]&gt; is more appropriate.  The process of converting the complex
number into a string that can be displayed is known as I&lt;stringification&gt;.

By calling the class method C&lt;Math::Complex::display_format&gt; and
supplying either C&lt;"polar"&gt; or C&lt;"cartesian"&gt; as an argument, you
override the default display style, which is C&lt;"cartesian"&gt;. Not
supplying any argument returns the current settings.

This default can be overridden on a per-number basis by calling the
C&lt;display_format&gt; method instead. As before, not supplying any argument
returns the current display style for this number. Otherwise whatever you
specify will be the new display style for I&lt;this&gt; particular number.

For instance:

	use Math::Complex;

	Math::Complex::display_format('polar');
	$j = (root(1, 3))[1];
	print "j = $j\n";		# Prints "j = [1,2pi/3]"
	$j-&gt;display_format('cartesian');
	print "j = $j\n";		# Prints "j = -0.5+0.866025403784439i"

The polar style attempts to emphasize arguments like I&lt;k*pi/n&gt;
(where I&lt;n&gt; is a positive integer and I&lt;k&gt; an integer within [-9, +9]),
this is called I&lt;polar pretty-printing&gt;.

For the reverse of stringifying, see the C&lt;make&gt; and C&lt;emake&gt;.

=head2 CHANGED IN PERL 5.6

The C&lt;display_format&gt; class method and the corresponding
C&lt;display_format&gt; object method can now be called using
a parameter hash instead of just a one parameter.

The old display format style, which can have values C&lt;"cartesian"&gt; or
C&lt;"polar"&gt;, can be changed using the C&lt;"style"&gt; parameter.

	$j-&gt;display_format(style =&gt; "polar");

The one parameter calling convention also still works.

	$j-&gt;display_format("polar");

There are two new display parameters.

The first one is C&lt;"format"&gt;, which is a sprintf()-style format string
to be used for both numeric parts of the complex number(s).  The is
somewhat system-dependent but most often it corresponds to C&lt;"%.15g"&gt;.
You can revert to the default by setting the C&lt;format&gt; to C&lt;undef&gt;.

	# the $j from the above example

	$j-&gt;display_format('format' =&gt; '%.5f');
	print "j = $j\n";		# Prints "j = -0.50000+0.86603i"
	$j-&gt;display_format('format' =&gt; undef);
	print "j = $j\n";		# Prints "j = -0.5+0.86603i"

Notice that this affects also the return values of the
C&lt;display_format&gt; methods: in list context the whole parameter hash
will be returned, as opposed to only the style parameter value.
This is a potential incompatibility with earlier versions if you
have been calling the C&lt;display_format&gt; method in list context.

The second new display parameter is C&lt;"polar_pretty_print"&gt;, which can
be set to true or false, the default being true.  See the previous
section for what this means.

=head1 USAGE

Thanks to overloading, the handling of arithmetics with complex numbers
is simple and almost transparent.

Here are some examples:

	use Math::Complex;

	$j = cplxe(1, 2*pi/3);	# $j ** 3 == 1
	print "j = $j, j**3 = ", $j ** 3, "\n";
	print "1 + j + j**2 = ", 1 + $j + $j**2, "\n";

	$z = -16 + 0*i;			# Force it to be a complex
	print "sqrt($z) = ", sqrt($z), "\n";

	$k = exp(i * 2*pi/3);
	print "$j - $k = ", $j - $k, "\n";

	$z-&gt;Re(3);			# Re, Im, arg, abs,
	$j-&gt;arg(2);			# (the last two aka rho, theta)
					# can be used also as mutators.

=head1 CONSTANTS

=head2 PI

The constant C&lt;pi&gt; and some handy multiples of it (pi2, pi4,
and pip2 (pi/2) and pip4 (pi/4)) are also available if separately
exported:

    use Math::Complex ':pi'; 
    $third_of_circle = pi2 / 3;

=head2 Inf

The floating point infinity can be exported as a subroutine Inf():

    use Math::Complex qw(Inf sinh);
    my $AlsoInf = Inf() + 42;
    my $AnotherInf = sinh(1e42);
    print "$AlsoInf is $AnotherInf\n" if $AlsoInf == $AnotherInf;

Note that the stringified form of infinity varies between platforms:
it can be for example any of

   inf
   infinity
   INF
   1.#INF

or it can be something else. 

Also note that in some platforms trying to use the infinity in
arithmetic operations may result in Perl crashing because using
an infinity causes SIGFPE or its moral equivalent to be sent.
The way to ignore this is

  local $SIG{FPE} = sub { };

=head1 ERRORS DUE TO DIVISION BY ZERO OR LOGARITHM OF ZERO

The division (/) and the following functions

	log	ln	log10	logn
	tan	sec	csc	cot
	atan	asec	acsc	acot
	tanh	sech	csch	coth
	atanh	asech	acsch	acoth

cannot be computed for all arguments because that would mean dividing
by zero or taking logarithm of zero. These situations cause fatal
runtime errors looking like this

	cot(0): Division by zero.
	(Because in the definition of cot(0), the divisor sin(0) is 0)
	Died at ...

or

	atanh(-1): Logarithm of zero.
	Died at...

For the C&lt;csc&gt;, C&lt;cot&gt;, C&lt;asec&gt;, C&lt;acsc&gt;, C&lt;acot&gt;, C&lt;csch&gt;, C&lt;coth&gt;,
C&lt;asech&gt;, C&lt;acsch&gt;, the argument cannot be C&lt;0&gt; (zero).  For the
logarithmic functions and the C&lt;atanh&gt;, C&lt;acoth&gt;, the argument cannot
be C&lt;1&gt; (one).  For the C&lt;atanh&gt;, C&lt;acoth&gt;, the argument cannot be
C&lt;-1&gt; (minus one).  For the C&lt;atan&gt;, C&lt;acot&gt;, the argument cannot be
C&lt;i&gt; (the imaginary unit).  For the C&lt;atan&gt;, C&lt;acoth&gt;, the argument
cannot be C&lt;-i&gt; (the negative imaginary unit).  For the C&lt;tan&gt;,
C&lt;sec&gt;, C&lt;tanh&gt;, the argument cannot be I&lt;pi/2 + k * pi&gt;, where I&lt;k&gt;
is any integer.  atan2(0, 0) is undefined, and if the complex arguments
are used for atan2(), a division by zero will happen if z1**2+z2**2 == 0.

Note that because we are operating on approximations of real numbers,
these errors can happen when merely `too close' to the singularities
listed above.

=head1 ERRORS DUE TO INDIGESTIBLE ARGUMENTS

The C&lt;make&gt; and C&lt;emake&gt; accept both real and complex arguments.
When they cannot recognize the arguments they will die with error
messages like the following

    Math::Complex::make: Cannot take real part of ...
    Math::Complex::make: Cannot take real part of ...
    Math::Complex::emake: Cannot take rho of ...
    Math::Complex::emake: Cannot take theta of ...

=head1 BUGS

Saying C&lt;use Math::Complex;&gt; exports many mathematical routines in the
caller environment and even overrides some (C&lt;sqrt&gt;, C&lt;log&gt;, C&lt;atan2&gt;).
This is construed as a feature by the Authors, actually... ;-)

All routines expect to be given real or complex numbers. Don't attempt to
use BigFloat, since Perl has currently no rule to disambiguate a '+'
operation (for instance) between two overloaded entities.

In Cray UNICOS there is some strange numerical instability that results
in root(), cos(), sin(), cosh(), sinh(), losing accuracy fast.  Beware.
The bug may be in UNICOS math libs, in UNICOS C compiler, in Math::Complex.
Whatever it is, it does not manifest itself anywhere else where Perl runs.

=head1 SEE ALSO

L&lt;Math::Trig&gt;

=head1 AUTHORS

Daniel S. Lewart &lt;F&lt;lewart!at!uiuc.edu&gt;&gt;,
Jarkko Hietaniemi &lt;F&lt;jhi!at!iki.fi&gt;&gt;,
Raphael Manfredi &lt;F&lt;Raphael_Manfredi!at!pobox.com&gt;&gt;,
Zefram &lt;zefram@fysh.org&gt;

=head1 LICENSE

This library is free software; you can redistribute it and/or modify
it under the same terms as Perl itself. 

=cut

1;

# eof
</pre></body></html>