<html><head><meta name="color-scheme" content="light dark"></head><body><pre style="word-wrap: break-word; white-space: pre-wrap;">#
# Tie/IxHash.pm
#
# Indexed hash implementation for Perl
#
# See below for documentation.
#

require 5.005;

package Tie::IxHash;
use strict;
use integer;
require Tie::Hash;
use vars qw/@ISA $VERSION/;
@ISA = qw(Tie::Hash);

$VERSION = $VERSION = '1.23';

#
# standard tie functions
#

sub TIEHASH {
  my($c) = shift;
  my($s) = [];
  $s-&gt;[0] = {};   # hashkey index
  $s-&gt;[1] = [];   # array of keys
  $s-&gt;[2] = [];   # array of data
  $s-&gt;[3] = 0;    # iter count

  bless $s, $c;

  $s-&gt;Push(@_) if @_;

  return $s;
}

#sub DESTROY {}           # costly if there's nothing to do

sub FETCH {
  my($s, $k) = (shift, shift);
  return exists( $s-&gt;[0]{$k} ) ? $s-&gt;[2][ $s-&gt;[0]{$k} ] : undef;
}

sub STORE {
  my($s, $k, $v) = (shift, shift, shift);
  
  if (exists $s-&gt;[0]{$k}) {
    my($i) = $s-&gt;[0]{$k};
    $s-&gt;[1][$i] = $k;
    $s-&gt;[2][$i] = $v;
    $s-&gt;[0]{$k} = $i;
  }
  else {
    push(@{$s-&gt;[1]}, $k);
    push(@{$s-&gt;[2]}, $v);
    $s-&gt;[0]{$k} = $#{$s-&gt;[1]};
  }
}

sub DELETE {
  my($s, $k) = (shift, shift);

  if (exists $s-&gt;[0]{$k}) {
    my($i) = $s-&gt;[0]{$k};
    for ($i+1..$#{$s-&gt;[1]}) {    # reset higher elt indexes
      $s-&gt;[0]{ $s-&gt;[1][$_] }--;    # timeconsuming, is there is better way?
    }
    if ( $i == $s-&gt;[3]-1 ) {
      $s-&gt;[3]--;
    }
    delete $s-&gt;[0]{$k};
    splice @{$s-&gt;[1]}, $i, 1;
    return (splice(@{$s-&gt;[2]}, $i, 1))[0];
  }
  return undef;
}

sub EXISTS {
  exists $_[0]-&gt;[0]{ $_[1] };
}

sub FIRSTKEY {
  $_[0][3] = 0;
  &amp;NEXTKEY;
}

sub NEXTKEY {
  return $_[0][1][ $_[0][3]++ ] if ($_[0][3] &lt;= $#{ $_[0][1] } );
  return undef;
}



#
#
# class functions that provide additional capabilities
#
#

sub new { TIEHASH(@_) }

sub Clear {
  my $s = shift;
  $s-&gt;[0] = {};   # hashkey index
  $s-&gt;[1] = [];   # array of keys
  $s-&gt;[2] = [];   # array of data
  $s-&gt;[3] = 0;    # iter count
  return;
}

#
# add pairs to end of indexed hash
# note that if a supplied key exists, it will not be reordered
#
sub Push {
  my($s) = shift;
  while (@_) {
    $s-&gt;STORE(shift, shift);
  }
  return scalar(@{$s-&gt;[1]});
}

sub Push2 {
  my($s) = shift;
  $s-&gt;Splice($#{$s-&gt;[1]}+1, 0, @_);
  return scalar(@{$s-&gt;[1]});
}

#
# pop last k-v pair
#
sub Pop {
  my($s) = shift;
  my($k, $v, $i);
  $k = pop(@{$s-&gt;[1]});
  $v = pop(@{$s-&gt;[2]});
  if (defined $k) {
    delete $s-&gt;[0]{$k};
    return ($k, $v);
  }
  return undef;
}

sub Pop2 {
  return $_[0]-&gt;Splice(-1);
}

#
# shift
#
sub Shift {
  my($s) = shift;
  my($k, $v, $i);
  $k = shift(@{$s-&gt;[1]});
  $v = shift(@{$s-&gt;[2]});
  if (defined $k) {
    delete $s-&gt;[0]{$k};
    for (keys %{$s-&gt;[0]}) {
      $s-&gt;[0]{$_}--;
    }
    return ($k, $v);
  }
  return undef;
}

sub Shift2 {
  return $_[0]-&gt;Splice(0, 1);
}

#
# unshift
# if a supplied key exists, it will not be reordered
#
sub Unshift {
  my($s) = shift;
  my($k, $v, @k, @v, $len, $i);

  while (@_) {
    ($k, $v) = (shift, shift);
    if (exists $s-&gt;[0]{$k}) {
      $i = $s-&gt;[0]{$k};
      $s-&gt;[1][$i] = $k;
      $s-&gt;[2][$i] = $v;
      $s-&gt;[0]{$k} = $i;
    }
    else {
      push(@k, $k);
      push(@v, $v);
      $len++;
    }
  }
  if (defined $len) {
    for (keys %{$s-&gt;[0]}) {
      $s-&gt;[0]{$_} += $len;
    }
    $i = 0;
    for (@k) {
      $s-&gt;[0]{$_} = $i++;
    }
    unshift(@{$s-&gt;[1]}, @k);
    return unshift(@{$s-&gt;[2]}, @v);
  }
  return scalar(@{$s-&gt;[1]});
}

sub Unshift2 {
  my($s) = shift;
  $s-&gt;Splice(0,0,@_);
  return scalar(@{$s-&gt;[1]});
}

#
# splice 
#
# any existing hash key order is preserved. the value is replaced for
# such keys, and the new keys are spliced in the regular fashion.
#
# supports -ve offsets but only +ve lengths
#
# always assumes a 0 start offset
#
sub Splice {
  my($s, $start, $len) = (shift, shift, shift);
  my($k, $v, @k, @v, @r, $i, $siz);
  my($end);                   # inclusive

  # XXX  inline this 
  ($start, $end, $len) = $s-&gt;_lrange($start, $len);

  if (defined $start) {
    if ($len &gt; 0) {
      my(@k) = splice(@{$s-&gt;[1]}, $start, $len);
      my(@v) = splice(@{$s-&gt;[2]}, $start, $len);
      while (@k) {
        $k = shift(@k);
        delete $s-&gt;[0]{$k};
        push(@r, $k, shift(@v));
      }
      for ($start..$#{$s-&gt;[1]}) {
        $s-&gt;[0]{$s-&gt;[1][$_]} -= $len;
      }
    }
    while (@_) {
      ($k, $v) = (shift, shift);
      if (exists $s-&gt;[0]{$k}) {
        #      $s-&gt;STORE($k, $v);
        $i = $s-&gt;[0]{$k};
        $s-&gt;[1][$i] = $k;
        $s-&gt;[2][$i] = $v;
        $s-&gt;[0]{$k} = $i;
      }
      else {
        push(@k, $k);
        push(@v, $v);
        $siz++;
      }
    }
    if (defined $siz) {
      for ($start..$#{$s-&gt;[1]}) {
        $s-&gt;[0]{$s-&gt;[1][$_]} += $siz;
      }
      $i = $start;
      for (@k) {
        $s-&gt;[0]{$_} = $i++;
      }
      splice(@{$s-&gt;[1]}, $start, 0, @k);
      splice(@{$s-&gt;[2]}, $start, 0, @v);
    }
  }
  return @r;
}

#
# delete elements specified by key
# other elements higher than the one deleted "slide" down 
#
sub Delete {
  my($s) = shift;

  for (@_) {
    #
    # XXX potential optimization: could do $s-&gt;DELETE only if $#_ &lt; 4.
    #     otherwise, should reset all the hash indices in one loop
    #
    $s-&gt;DELETE($_);
  }
}

#
# replace hash element at specified index
#
# if the optional key is not supplied the value at index will simply be 
# replaced without affecting the order.
#
# if an element with the supplied key already exists, it will be deleted first.
#
# returns the key of replaced value if it succeeds.
#
sub Replace {
  my($s) = shift;
  my($i, $v, $k) = (shift, shift, shift);
  if (defined $i and $i &lt;= $#{$s-&gt;[1]} and $i &gt;= 0) {
    if (defined $k) {
      delete $s-&gt;[0]{ $s-&gt;[1][$i] };
      $s-&gt;DELETE($k) ; #if exists $s-&gt;[0]{$k};
      $s-&gt;[1][$i] = $k;
      $s-&gt;[2][$i] = $v;
      $s-&gt;[0]{$k} = $i;
      return $k;
    }
    else {
      $s-&gt;[2][$i] = $v;
      return $s-&gt;[1][$i];
    }
  }
  return undef;
}

#
# Given an $start and $len, returns a legal start and end (where start &lt;= end)
# for the current hash. 
# Legal range is defined as 0 to $#s+1
# $len defaults to number of elts upto end of list
#
#          0   1   2   ...
#          | X | X | X ... X | X | X |
#                           -2  -1       (no -0 alas)
# X's above are the elements 
#
sub _lrange {
  my($s) = shift;
  my($offset, $len) = @_;
  my($start, $end);         # both inclusive
  my($size) = $#{$s-&gt;[1]}+1;

  return undef unless defined $offset;
  if($offset &lt; 0) {
    $start = $offset + $size;
    $start = 0 if $start &lt; 0;
  }
  else {
    ($offset &gt; $size) ? ($start = $size) : ($start = $offset);
  }

  if (defined $len) {
    $len = -$len if $len &lt; 0;
    $len = $size - $start if $len &gt; $size - $start;
  }
  else {
    $len = $size - $start;
  }
  $end = $start + $len - 1;

  return ($start, $end, $len);
}

#
# Return keys at supplied indices
# Returns all keys if no args.
#
sub Keys   { 
  my($s) = shift;
  return ( @_ == 1
	 ? $s-&gt;[1][$_[0]]
	 : ( @_
	   ? @{$s-&gt;[1]}[@_]
	   : @{$s-&gt;[1]} ) );
}

#
# Returns values at supplied indices
# Returns all values if no args.
#
sub Values {
  my($s) = shift;
  return ( @_ == 1
	 ? $s-&gt;[2][$_[0]]
	 : ( @_
	   ? @{$s-&gt;[2]}[@_]
	   : @{$s-&gt;[2]} ) );
}

#
# get indices of specified hash keys
#
sub Indices { 
  my($s) = shift;
  return ( @_ == 1 ? $s-&gt;[0]{$_[0]} : @{$s-&gt;[0]}{@_} );
}

#
# number of k-v pairs in the ixhash
# note that this does not equal the highest index
# owing to preextended arrays
#
sub Length {
 return scalar @{$_[0]-&gt;[1]};
}

#
# Reorder the hash in the supplied key order
#
# warning: any unsupplied keys will be lost from the hash
# any supplied keys that dont exist in the hash will be ignored
#
sub Reorder {
  my($s) = shift;
  my(@k, @v, %x, $i);
  return unless @_;

  $i = 0;
  for (@_) {
    if (exists $s-&gt;[0]{$_}) {
      push(@k, $_);
      push(@v, $s-&gt;[2][ $s-&gt;[0]{$_} ] );
      $x{$_} = $i++;
    }
  }
  $s-&gt;[1] = \@k;
  $s-&gt;[2] = \@v;
  $s-&gt;[0] = \%x;
  return $s;
}

sub SortByKey {
  my($s) = shift;
  $s-&gt;Reorder(sort $s-&gt;Keys);
}

sub SortByValue {
  my($s) = shift;
  $s-&gt;Reorder(sort { $s-&gt;FETCH($a) cmp $s-&gt;FETCH($b) } $s-&gt;Keys)
}

1;
__END__

=head1 NAME

Tie::IxHash - ordered associative arrays for Perl


=head1 SYNOPSIS

    # simple usage
    use Tie::IxHash;
    tie HASHVARIABLE, 'Tie::IxHash' [, LIST];

    # OO interface with more powerful features
    use Tie::IxHash;
    TIEOBJECT = Tie::IxHash-&gt;new( [LIST] );
    TIEOBJECT-&gt;Splice( OFFSET [, LENGTH [, LIST]] );
    TIEOBJECT-&gt;Push( LIST );
    TIEOBJECT-&gt;Pop;
    TIEOBJECT-&gt;Shift;
    TIEOBJECT-&gt;Unshift( LIST );
    TIEOBJECT-&gt;Keys( [LIST] );
    TIEOBJECT-&gt;Values( [LIST] );
    TIEOBJECT-&gt;Indices( LIST );
    TIEOBJECT-&gt;Delete( [LIST] );
    TIEOBJECT-&gt;Replace( OFFSET, VALUE, [KEY] );
    TIEOBJECT-&gt;Reorder( LIST );
    TIEOBJECT-&gt;SortByKey;
    TIEOBJECT-&gt;SortByValue;
    TIEOBJECT-&gt;Length;


=head1 DESCRIPTION

This Perl module implements Perl hashes that preserve the order in which the
hash elements were added.  The order is not affected when values
corresponding to existing keys in the IxHash are changed.  The elements can
also be set to any arbitrary supplied order.  The familiar perl array
operations can also be performed on the IxHash.


=head2 Standard C&lt;TIEHASH&gt; Interface

The standard C&lt;TIEHASH&gt; mechanism is available. This interface is 
recommended for simple uses, since the usage is exactly the same as
regular Perl hashes after the C&lt;tie&gt; is declared.


=head2 Object Interface

This module also provides an extended object-oriented interface that can be
used for more powerful operations with the IxHash.  The following methods
are available:

=over 8

=item FETCH, STORE, DELETE, EXISTS

These standard C&lt;TIEHASH&gt; methods mandated by Perl can be used directly.
See the C&lt;tie&gt; entry in perlfunc(1) for details.

=item Push, Pop, Shift, Unshift, Splice

These additional methods resembling Perl functions are available for
operating on key-value pairs in the IxHash. The behavior is the same as the
corresponding perl functions, except when a supplied hash key already exists
in the hash. In that case, the existing value is updated but its order is
not affected.  To unconditionally alter the order of a supplied key-value
pair, first C&lt;DELETE&gt; the IxHash element.

=item Keys

Returns an array of IxHash element keys corresponding to the list of supplied
indices.  Returns an array of all the keys if called without arguments.
Note the return value is mostly only useful when used in a list context
(since perl will convert it to the number of elements in the array when
used in a scalar context, and that may not be very useful).

If a single argument is given, returns the single key corresponding to
the index.  This is usable in either scalar or list context.

=item Values

Returns an array of IxHash element values corresponding to the list of supplied
indices.  Returns an array of all the values if called without arguments.
Note the return value is mostly only useful when used in a list context
(since perl will convert it to the number of elements in the array when
used in a scalar context, and that may not be very useful).

If a single argument is given, returns the single value corresponding to
the index.  This is usable in either scalar or list context.

=item Indices

Returns an array of indices corresponding to the supplied list of keys.
Note the return value is mostly only useful when used in a list context
(since perl will convert it to the number of elements in the array when
used in a scalar context, and that may not be very useful).

If a single argument is given, returns the single index corresponding to
the key.  This is usable in either scalar or list context.

=item Delete

Removes elements with the supplied keys from the IxHash.

=item Replace

Substitutes the IxHash element at the specified index with the supplied
value-key pair.  If a key is not supplied, simply substitutes the value at
index with the supplied value. If an element with the supplied key already
exists, it will be removed from the IxHash first.

=item Reorder

This method can be used to manipulate the internal order of the IxHash
elements by supplying a list of keys in the desired order.  Note however,
that any IxHash elements whose keys are not in the list will be removed from
the IxHash.

=item Length

Returns the number of IxHash elements.

=item SortByKey

Reorders the IxHash elements by textual comparison of the keys.

=item SortByValue

Reorders the IxHash elements by textual comparison of the values.

=item Clear

Resets the IxHash to its pristine state: with no elements at all.

=back


=head1 EXAMPLE

    use Tie::IxHash;

    # simple interface
    $t = tie(%myhash, 'Tie::IxHash', 'a' =&gt; 1, 'b' =&gt; 2);
    %myhash = (first =&gt; 1, second =&gt; 2, third =&gt; 3);
    $myhash{fourth} = 4;
    @keys = keys %myhash;
    @values = values %myhash;
    print("y") if exists $myhash{third};

    # OO interface
    $t = Tie::IxHash-&gt;new(first =&gt; 1, second =&gt; 2, third =&gt; 3);
    $t-&gt;Push(fourth =&gt; 4); # same as $myhash{'fourth'} = 4;
    ($k, $v) = $t-&gt;Pop;    # $k is 'fourth', $v is 4
    $t-&gt;Unshift(neg =&gt; -1, zeroth =&gt; 0); 
    ($k, $v) = $t-&gt;Shift;  # $k is 'neg', $v is -1
    @oneandtwo = $t-&gt;Splice(1, 2, foo =&gt; 100, bar =&gt; 101);

    @keys = $t-&gt;Keys;
    @values = $t-&gt;Values;
    @indices = $t-&gt;Indices('foo', 'zeroth');
    @itemkeys = $t-&gt;Keys(@indices);
    @itemvals = $t-&gt;Values(@indices);
    $t-&gt;Replace(2, 0.3, 'other');
    $t-&gt;Delete('second', 'zeroth');
    $len = $t-&gt;Length;     # number of key-value pairs

    $t-&gt;Reorder(reverse @keys);
    $t-&gt;SortByKey;
    $t-&gt;SortByValue;


=head1 BUGS

You cannot specify a negative length to C&lt;Splice&gt;. Negative indexes are OK,
though.


=head1 NOTE

Indexing always begins at 0 (despite the current C&lt;$[&gt; setting) for 
all the functions.


=head1 TODO

Addition of elements with keys that already exist to the end of the IxHash
must be controlled by a switch.

Provide C&lt;TIEARRAY&gt; interface when it stabilizes in Perl.

Rewrite using XSUBs for efficiency.


=head1 AUTHOR

Gurusamy Sarathy        gsar@umich.edu

Copyright (c) 1995 Gurusamy Sarathy. All rights reserved.
This program is free software; you can redistribute it and/or
modify it under the same terms as Perl itself.


=head1 VERSION

Version 1.23


=head1 SEE ALSO

perl(1)

=cut
</pre></body></html>