<html><head><meta name="color-scheme" content="light dark"></head><body><pre style="word-wrap: break-word; white-space: pre-wrap;">package IPC::Open2;

use strict;

require 5.006;
use Exporter 'import';

our $VERSION	= 1.06;
our @EXPORT		= qw(open2);

=head1 NAME

IPC::Open2 - open a process for both reading and writing using open2()

=head1 SYNOPSIS

    use IPC::Open2;

    my $pid = open2(my $chld_out, my $chld_in,
      'some', 'cmd', 'and', 'args');
    # or passing the command through the shell
    my $pid = open2(my $chld_out, my $chld_in, 'some cmd and args');

    # read from parent STDIN and write to already open handle
    open my $outfile, '&gt;', 'outfile.txt' or die "open failed: $!";
    my $pid = open2($outfile, '&lt;&amp;STDIN', 'some', 'cmd', 'and', 'args');

    # read from already open handle and write to parent STDOUT
    open my $infile, '&lt;', 'infile.txt' or die "open failed: $!";
    my $pid = open2('&gt;&amp;STDOUT', $infile, 'some', 'cmd', 'and', 'args');

    # reap zombie and retrieve exit status
    waitpid( $pid, 0 );
    my $child_exit_status = $? &gt;&gt; 8;

=head1 DESCRIPTION

The open2() function runs the given command and connects $chld_out for
reading and $chld_in for writing.  It's what you think should work 
when you try

    my $pid = open(my $fh, "|cmd args|");

The $chld_in filehandle will have autoflush turned on.

If $chld_out is a string (that is, a bareword filehandle rather than a glob
or a reference) and it begins with C&lt;&lt; &gt;&amp; &gt;&gt;, then the child will send output
directly to that file handle.  If $chld_in is a string that begins with
C&lt;&lt; &lt;&amp; &gt;&gt;, then $chld_in will be closed in the parent, and the child will
read from it directly.  In both cases, there will be a L&lt;dup(2)&gt; instead of a
L&lt;pipe(2)&gt; made.

If either reader or writer is the empty string or undefined, this will be
replaced by an autogenerated filehandle.  If so, you must pass a valid lvalue
in the parameter slot so it can be overwritten in the caller, or
an exception will be raised.

open2() returns the process ID of the child process.  It doesn't return on
failure: it just raises an exception matching C&lt;/^open2:/&gt;.  However,
C&lt;exec&gt; failures in the child are not detected.  You'll have to
trap SIGPIPE yourself.

open2() does not wait for and reap the child process after it exits.
Except for short programs where it's acceptable to let the operating system
take care of this, you need to do this yourself.  This is normally as
simple as calling C&lt;waitpid $pid, 0&gt; when you're done with the process.
Failing to do this can result in an accumulation of defunct or "zombie"
processes.  See L&lt;perlfunc/waitpid&gt; for more information.

This whole affair is quite dangerous, as you may block forever.  It
assumes it's going to talk to something like L&lt;bc(1)&gt;, both writing
to it and reading from it.  This is presumably safe because you
"know" that commands like L&lt;bc(1)&gt; will read a line at a time and
output a line at a time.  Programs like L&lt;sort(1)&gt; that read their
entire input stream first, however, are quite apt to cause deadlock.

The big problem with this approach is that if you don't have control 
over source code being run in the child process, you can't control
what it does with pipe buffering.  Thus you can't just open a pipe to
C&lt;cat -v&gt; and continually read and write a line from it.

The L&lt;IO::Pty&gt; and L&lt;Expect&gt; modules from CPAN can help with this, as
they provide a real tty (well, a pseudo-tty, actually), which gets you
back to line buffering in the invoked command again.

=head1 WARNING 

The order of arguments differs from that of open3().

=head1 SEE ALSO

See L&lt;IPC::Open3&gt; for an alternative that handles STDERR as well.  This
function is really just a wrapper around open3().

=cut

# &amp;open2: tom christiansen, &lt;tchrist@convex.com&gt;
#
# usage: $pid = open2('rdr', 'wtr', 'some cmd and args');
#    or  $pid = open2('rdr', 'wtr', 'some', 'cmd', 'and', 'args');
#
# spawn the given $cmd and connect $rdr for
# reading and $wtr for writing.  return pid
# of child, or 0 on failure.  
# 
# WARNING: this is dangerous, as you may block forever
# unless you are very careful.  
# 
# $wtr is left unbuffered.
# 
# abort program if
#	rdr or wtr are null
# 	a system call fails

require IPC::Open3;

sub open2 {
    local $Carp::CarpLevel = $Carp::CarpLevel + 1;
    return IPC::Open3::_open3('open2', $_[1], $_[0], '&gt;&amp;STDERR', @_[2 .. $#_]);
}

1
</pre></body></html>