<html><head><meta name="color-scheme" content="light dark"></head><body><pre style="word-wrap: break-word; white-space: pre-wrap;"># Copyright Â© 2017 Guillem Jover &lt;guillem@debian.org&gt;
#
# This program is free software; you can redistribute it and/or modify
# it under the terms of the GNU General Public License as published by
# the Free Software Foundation; either version 2 of the License, or
# (at your option) any later version.
#
# This program is distributed in the hope that it will be useful,
# but WITHOUT ANY WARRANTY; without even the implied warranty of
# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
# GNU General Public License for more details.
#
# You should have received a copy of the GNU General Public License
# along with this program.  If not, see &lt;https://www.gnu.org/licenses/&gt;.

=encoding utf8

=head1 NAME

Dpkg::OpenPGP - multi-backend OpenPGP support

=head1 DESCRIPTION

This module provides a class for transparent multi-backend OpenPGP support.

B&lt;Note&gt;: This is a private module, its API can change at any time.

=cut

package Dpkg::OpenPGP 0.01;

use strict;
use warnings;

use List::Util qw(none);

use Dpkg::Gettext;
use Dpkg::ErrorHandling;
use Dpkg::IPC;
use Dpkg::Path qw(find_command);

my @BACKENDS = qw(
    sop
    sq
    gpg
);
my %BACKEND = (
    sop =&gt; 'SOP',
    sq =&gt; 'Sequoia',
    gpg =&gt; 'GnuPG',
);

sub new {
    my ($this, %opts) = @_;
    my $class = ref($this) || $this;

    my $self = {};
    bless $self, $class;

    my $backend = $opts{backend} // 'auto';
    my %backend_opts = (
        cmdv =&gt; $opts{cmdv} // 'auto',
        cmd =&gt; $opts{cmd} // 'auto',
    );

    if ($backend eq 'auto') {
        # Defaults for stateless full API auto-detection.
        $opts{needs}{api} //= 'full';
        $opts{needs}{keystore} //= 0;

        if (none { $opts{needs}{api} eq $_ } qw(full verify)) {
            error(g_('unknown OpenPGP api requested %s'), $opts{needs}{api});
        }

        $self-&gt;{backend} = $self-&gt;_auto_backend($opts{needs}, %backend_opts);
    } elsif (exists $BACKEND{$backend}) {
        $self-&gt;{backend} = $self-&gt;_load_backend($BACKEND{$backend}, %backend_opts);
        if (! $self-&gt;{backend}) {
            error(g_('cannot load OpenPGP backend %s'), $backend);
        }
    } else {
        error(g_('unknown OpenPGP backend %s'), $backend);
    }

    return $self;
}

sub _load_backend {
    my ($self, $backend, %opts) = @_;

    my $module = "Dpkg::OpenPGP::Backend::$backend";
    eval qq{
        require $module;
    };
    return if $@;

    return $module-&gt;new(%opts);
}

sub _auto_backend {
    my ($self, $needs, %opts) = @_;

    foreach my $backend (@BACKENDS) {
        my $module = $self-&gt;_load_backend($BACKEND{$backend}, %opts);

        if ($needs-&gt;{api} eq 'verify') {
            next if ! $module-&gt;has_verify_cmd();
        } else {
            next if ! $module-&gt;has_backend_cmd();
        }
        next if $needs-&gt;{keystore} &amp;&amp; ! $module-&gt;has_keystore();

        return $module;
    }

    # Otherwise load a dummy backend.
    return Dpkg::OpenPGP::Backend-&gt;new();
}

sub can_use_secrets {
    my ($self, $key) = @_;

    return 0 unless $self-&gt;{backend}-&gt;has_backend_cmd();
    return 0 if $key-&gt;type eq 'keyfile' &amp;&amp; ! -f $key-&gt;handle;
    return 0 if $key-&gt;type eq 'keystore' &amp;&amp; ! -e $key-&gt;handle;
    return 0 unless $self-&gt;{backend}-&gt;can_use_key($key);
    return 1;
}

sub get_trusted_keyrings {
    my $self = shift;

    return $self-&gt;{backend}-&gt;get_trusted_keyrings();
}

sub armor {
    my ($self, $type, $in, $out) = @_;

    return $self-&gt;{backend}-&gt;armor($type, $in, $out);
}

sub dearmor {
    my ($self, $type, $in, $out) = @_;

    return $self-&gt;{backend}-&gt;dearmor($type, $in, $out);
}

sub inline_verify {
    my ($self, $inlinesigned, $data, @certs) = @_;

    return $self-&gt;{backend}-&gt;inline_verify($inlinesigned, $data, @certs);
}

sub verify {
    my ($self, $data, $sig, @certs) = @_;

    return $self-&gt;{backend}-&gt;verify($data, $sig, @certs);
}

sub inline_sign {
    my ($self, $data, $inlinesigned, $key) = @_;

    return $self-&gt;{backend}-&gt;inline_sign($data, $inlinesigned, $key);
}

=head1 CHANGES

=head2 Version 0.xx

This is a private module.

=cut

1;
</pre></body></html>