<html><head><meta name="color-scheme" content="light dark"></head><body><pre style="word-wrap: break-word; white-space: pre-wrap;">package IO::Compress::Bzip2 ;

use strict ;
use warnings;
use bytes;
require Exporter ;

use IO::Compress::Base 2.204 ;

use IO::Compress::Base::Common  2.204 qw();
use IO::Compress::Adapter::Bzip2 2.204 ;



our ($VERSION, @ISA, @EXPORT_OK, %EXPORT_TAGS, $Bzip2Error);

$VERSION = '2.204';
$Bzip2Error = '';

@ISA    = qw(IO::Compress::Base Exporter);
@EXPORT_OK = qw( $Bzip2Error bzip2 ) ;
%EXPORT_TAGS = %IO::Compress::Base::EXPORT_TAGS ;
push @{ $EXPORT_TAGS{all} }, @EXPORT_OK ;
Exporter::export_ok_tags('all');



sub new
{
    my $class = shift ;

    my $obj = IO::Compress::Base::Common::createSelfTiedObject($class, \$Bzip2Error);
    return $obj-&gt;_create(undef, @_);
}

sub bzip2
{
    my $obj = IO::Compress::Base::Common::createSelfTiedObject(undef, \$Bzip2Error);
    $obj-&gt;_def(@_);
}


sub mkHeader
{
    my $self = shift ;
    return '';

}

sub getExtraParams
{
    my $self = shift ;

    use IO::Compress::Base::Common  2.204 qw(:Parse);

    return (
            'blocksize100k' =&gt; [IO::Compress::Base::Common::Parse_unsigned,  1],
            'workfactor'    =&gt; [IO::Compress::Base::Common::Parse_unsigned,  0],
            'verbosity'     =&gt; [IO::Compress::Base::Common::Parse_boolean,   0],
        );
}



sub ckParams
{
    my $self = shift ;
    my $got = shift;

    # check that BlockSize100K is a number between 1 &amp; 9
    if ($got-&gt;parsed('blocksize100k')) {
        my $value = $got-&gt;getValue('blocksize100k');
        return $self-&gt;saveErrorString(undef, "Parameter 'BlockSize100K' not between 1 and 9, got $value")
            unless defined $value &amp;&amp; $value &gt;= 1 &amp;&amp; $value &lt;= 9;

    }

    # check that WorkFactor between 0 &amp; 250
    if ($got-&gt;parsed('workfactor')) {
        my $value = $got-&gt;getValue('workfactor');
        return $self-&gt;saveErrorString(undef, "Parameter 'WorkFactor' not between 0 and 250, got $value")
            unless $value &gt;= 0 &amp;&amp; $value &lt;= 250;
    }

    return 1 ;
}


sub mkComp
{
    my $self = shift ;
    my $got = shift ;

    my $BlockSize100K = $got-&gt;getValue('blocksize100k');
    my $WorkFactor    = $got-&gt;getValue('workfactor');
    my $Verbosity     = $got-&gt;getValue('verbosity');

    my ($obj, $errstr, $errno) = IO::Compress::Adapter::Bzip2::mkCompObject(
                                               $BlockSize100K, $WorkFactor,
                                               $Verbosity);

    return $self-&gt;saveErrorString(undef, $errstr, $errno)
        if ! defined $obj;

    return $obj;
}


sub mkTrailer
{
    my $self = shift ;
    return '';
}

sub mkFinalTrailer
{
    return '';
}

#sub newHeader
#{
#    my $self = shift ;
#    return '';
#}

sub getInverseClass
{
    return ('IO::Uncompress::Bunzip2');
}

sub getFileInfo
{
    my $self = shift ;
    my $params = shift;
    my $file = shift ;

}

1;

__END__

=head1 NAME

IO::Compress::Bzip2 - Write bzip2 files/buffers

=head1 SYNOPSIS

    use IO::Compress::Bzip2 qw(bzip2 $Bzip2Error) ;

    my $status = bzip2 $input =&gt; $output [,OPTS]
        or die "bzip2 failed: $Bzip2Error\n";

    my $z = IO::Compress::Bzip2-&gt;new( $output [,OPTS] )
        or die "bzip2 failed: $Bzip2Error\n";

    $z-&gt;print($string);
    $z-&gt;printf($format, $string);
    $z-&gt;write($string);
    $z-&gt;syswrite($string [, $length, $offset]);
    $z-&gt;flush();
    $z-&gt;tell();
    $z-&gt;eof();
    $z-&gt;seek($position, $whence);
    $z-&gt;binmode();
    $z-&gt;fileno();
    $z-&gt;opened();
    $z-&gt;autoflush();
    $z-&gt;input_line_number();
    $z-&gt;newStream( [OPTS] );

    $z-&gt;close() ;

    $Bzip2Error ;

    # IO::File mode

    print $z $string;
    printf $z $format, $string;
    tell $z
    eof $z
    seek $z, $position, $whence
    binmode $z
    fileno $z
    close $z ;

=head1 DESCRIPTION

This module provides a Perl interface that allows writing bzip2
compressed data to files or buffer.

For reading bzip2 files/buffers, see the companion module
L&lt;IO::Uncompress::Bunzip2|IO::Uncompress::Bunzip2&gt;.

=head1 Functional Interface

A top-level function, C&lt;bzip2&gt;, is provided to carry out
"one-shot" compression between buffers and/or files. For finer
control over the compression process, see the L&lt;/"OO Interface"&gt;
section.

    use IO::Compress::Bzip2 qw(bzip2 $Bzip2Error) ;

    bzip2 $input_filename_or_reference =&gt; $output_filename_or_reference [,OPTS]
        or die "bzip2 failed: $Bzip2Error\n";

The functional interface needs Perl5.005 or better.

=head2 bzip2 $input_filename_or_reference =&gt; $output_filename_or_reference [, OPTS]

C&lt;bzip2&gt; expects at least two parameters,
C&lt;$input_filename_or_reference&gt; and C&lt;$output_filename_or_reference&gt;
and zero or more optional parameters (see L&lt;/Optional Parameters&gt;)

=head3 The C&lt;$input_filename_or_reference&gt; parameter

The parameter, C&lt;$input_filename_or_reference&gt;, is used to define the
source of the uncompressed data.

It can take one of the following forms:

=over 5

=item A filename

If the C&lt;$input_filename_or_reference&gt; parameter is a simple scalar, it is
assumed to be a filename. This file will be opened for reading and the
input data will be read from it.

=item A filehandle

If the C&lt;$input_filename_or_reference&gt; parameter is a filehandle, the input
data will be read from it.  The string '-' can be used as an alias for
standard input.

=item A scalar reference

If C&lt;$input_filename_or_reference&gt; is a scalar reference, the input data
will be read from C&lt;$$input_filename_or_reference&gt;.

=item An array reference

If C&lt;$input_filename_or_reference&gt; is an array reference, each element in
the array must be a filename.

The input data will be read from each file in turn.

The complete array will be walked to ensure that it only
contains valid filenames before any data is compressed.

=item An Input FileGlob string

If C&lt;$input_filename_or_reference&gt; is a string that is delimited by the
characters "&lt;" and "&gt;" C&lt;bzip2&gt; will assume that it is an
I&lt;input fileglob string&gt;. The input is the list of files that match the
fileglob.

See L&lt;File::GlobMapper|File::GlobMapper&gt; for more details.

=back

If the C&lt;$input_filename_or_reference&gt; parameter is any other type,
C&lt;undef&gt; will be returned.

=head3 The C&lt;$output_filename_or_reference&gt; parameter

The parameter C&lt;$output_filename_or_reference&gt; is used to control the
destination of the compressed data. This parameter can take one of
these forms.

=over 5

=item A filename

If the C&lt;$output_filename_or_reference&gt; parameter is a simple scalar, it is
assumed to be a filename.  This file will be opened for writing and the
compressed data will be written to it.

=item A filehandle

If the C&lt;$output_filename_or_reference&gt; parameter is a filehandle, the
compressed data will be written to it.  The string '-' can be used as
an alias for standard output.

=item A scalar reference

If C&lt;$output_filename_or_reference&gt; is a scalar reference, the
compressed data will be stored in C&lt;$$output_filename_or_reference&gt;.

=item An Array Reference

If C&lt;$output_filename_or_reference&gt; is an array reference,
the compressed data will be pushed onto the array.

=item An Output FileGlob

If C&lt;$output_filename_or_reference&gt; is a string that is delimited by the
characters "&lt;" and "&gt;" C&lt;bzip2&gt; will assume that it is an
I&lt;output fileglob string&gt;. The output is the list of files that match the
fileglob.

When C&lt;$output_filename_or_reference&gt; is an fileglob string,
C&lt;$input_filename_or_reference&gt; must also be a fileglob string. Anything
else is an error.

See L&lt;File::GlobMapper|File::GlobMapper&gt; for more details.

=back

If the C&lt;$output_filename_or_reference&gt; parameter is any other type,
C&lt;undef&gt; will be returned.

=head2 Notes

When C&lt;$input_filename_or_reference&gt; maps to multiple files/buffers and
C&lt;$output_filename_or_reference&gt; is a single
file/buffer the input files/buffers will be stored
in C&lt;$output_filename_or_reference&gt; as a concatenated series of compressed data streams.

=head2 Optional Parameters

The optional parameters for the one-shot function C&lt;bzip2&gt;
are (for the most part) identical to those used with the OO interface defined in the
L&lt;/"Constructor Options"&gt; section. The exceptions are listed below

=over 5

=item C&lt;&lt; AutoClose =&gt; 0|1 &gt;&gt;

This option applies to any input or output data streams to
C&lt;bzip2&gt; that are filehandles.

If C&lt;AutoClose&gt; is specified, and the value is true, it will result in all
input and/or output filehandles being closed once C&lt;bzip2&gt; has
completed.

This parameter defaults to 0.

=item C&lt;&lt; BinModeIn =&gt; 0|1 &gt;&gt;

This option is now a no-op. All files will be read in binmode.

=item C&lt;&lt; Append =&gt; 0|1 &gt;&gt;

The behaviour of this option is dependent on the type of output data
stream.

=over 5

=item * A Buffer

If C&lt;Append&gt; is enabled, all compressed data will be append to the end of
the output buffer. Otherwise the output buffer will be cleared before any
compressed data is written to it.

=item * A Filename

If C&lt;Append&gt; is enabled, the file will be opened in append mode. Otherwise
the contents of the file, if any, will be truncated before any compressed
data is written to it.

=item * A Filehandle

If C&lt;Append&gt; is enabled, the filehandle will be positioned to the end of
the file via a call to C&lt;seek&gt; before any compressed data is
written to it.  Otherwise the file pointer will not be moved.

=back

When C&lt;Append&gt; is specified, and set to true, it will I&lt;append&gt; all compressed
data to the output data stream.

So when the output is a filehandle it will carry out a seek to the eof
before writing any compressed data. If the output is a filename, it will be opened for
appending. If the output is a buffer, all compressed data will be
appended to the existing buffer.

Conversely when C&lt;Append&gt; is not specified, or it is present and is set to
false, it will operate as follows.

When the output is a filename, it will truncate the contents of the file
before writing any compressed data. If the output is a filehandle
its position will not be changed. If the output is a buffer, it will be
wiped before any compressed data is output.

Defaults to 0.

=back

=head2 Examples

Here are a few example that show the capabilities of the module.

=head3 Streaming

This very simple command line example demonstrates the streaming capabilities of the module.
The code reads data from STDIN, compresses it, and writes the compressed data to STDOUT.

    $ echo hello world | perl -MIO::Compress::Bzip2=bzip2 -e 'bzip2 \*STDIN =&gt; \*STDOUT' &gt;output.bz2

The special filename "-" can be used as a standin for both C&lt;\*STDIN&gt; and C&lt;\*STDOUT&gt;,
so the above can be rewritten as

    $ echo hello world | perl -MIO::Compress::Bzip2=bzip2 -e 'bzip2 "-" =&gt; "-"' &gt;output.bz2

=head3 Compressing a file from the filesystem

To read the contents of the file C&lt;file1.txt&gt; and write the compressed
data to the file C&lt;file1.txt.bz2&gt;.

    use strict ;
    use warnings ;
    use IO::Compress::Bzip2 qw(bzip2 $Bzip2Error) ;

    my $input = "file1.txt";
    bzip2 $input =&gt; "$input.bz2"
        or die "bzip2 failed: $Bzip2Error\n";

=head3 Reading from a Filehandle and writing to an in-memory buffer

To read from an existing Perl filehandle, C&lt;$input&gt;, and write the
compressed data to a buffer, C&lt;$buffer&gt;.

    use strict ;
    use warnings ;
    use IO::Compress::Bzip2 qw(bzip2 $Bzip2Error) ;
    use IO::File ;

    my $input = IO::File-&gt;new( "&lt;file1.txt" )
        or die "Cannot open 'file1.txt': $!\n" ;
    my $buffer ;
    bzip2 $input =&gt; \$buffer
        or die "bzip2 failed: $Bzip2Error\n";

=head3 Compressing multiple files

To compress all files in the directory "/my/home" that match "*.txt"
and store the compressed data in the same directory

    use strict ;
    use warnings ;
    use IO::Compress::Bzip2 qw(bzip2 $Bzip2Error) ;

    bzip2 '&lt;/my/home/*.txt&gt;' =&gt; '&lt;*.bz2&gt;'
        or die "bzip2 failed: $Bzip2Error\n";

and if you want to compress each file one at a time, this will do the trick

    use strict ;
    use warnings ;
    use IO::Compress::Bzip2 qw(bzip2 $Bzip2Error) ;

    for my $input ( glob "/my/home/*.txt" )
    {
        my $output = "$input.bz2" ;
        bzip2 $input =&gt; $output
            or die "Error compressing '$input': $Bzip2Error\n";
    }

=head1 OO Interface

=head2 Constructor

The format of the constructor for C&lt;IO::Compress::Bzip2&gt; is shown below

    my $z = IO::Compress::Bzip2-&gt;new( $output [,OPTS] )
        or die "IO::Compress::Bzip2 failed: $Bzip2Error\n";

It returns an C&lt;IO::Compress::Bzip2&gt; object on success and undef on failure.
The variable C&lt;$Bzip2Error&gt; will contain an error message on failure.

If you are running Perl 5.005 or better the object, C&lt;$z&gt;, returned from
IO::Compress::Bzip2 can be used exactly like an L&lt;IO::File|IO::File&gt; filehandle.
This means that all normal output file operations can be carried out
with C&lt;$z&gt;.
For example, to write to a compressed file/buffer you can use either of
these forms

    $z-&gt;print("hello world\n");
    print $z "hello world\n";

The mandatory parameter C&lt;$output&gt; is used to control the destination
of the compressed data. This parameter can take one of these forms.

=over 5

=item A filename

If the C&lt;$output&gt; parameter is a simple scalar, it is assumed to be a
filename. This file will be opened for writing and the compressed data
will be written to it.

=item A filehandle

If the C&lt;$output&gt; parameter is a filehandle, the compressed data will be
written to it.
The string '-' can be used as an alias for standard output.

=item A scalar reference

If C&lt;$output&gt; is a scalar reference, the compressed data will be stored
in C&lt;$$output&gt;.

=back

If the C&lt;$output&gt; parameter is any other type, C&lt;IO::Compress::Bzip2&gt;::new will
return undef.

=head2 Constructor Options

C&lt;OPTS&gt; is any combination of zero or more the following options:

=over 5

=item C&lt;&lt; AutoClose =&gt; 0|1 &gt;&gt;

This option is only valid when the C&lt;$output&gt; parameter is a filehandle. If
specified, and the value is true, it will result in the C&lt;$output&gt; being
closed once either the C&lt;close&gt; method is called or the C&lt;IO::Compress::Bzip2&gt;
object is destroyed.

This parameter defaults to 0.

=item C&lt;&lt; Append =&gt; 0|1 &gt;&gt;

Opens C&lt;$output&gt; in append mode.

The behaviour of this option is dependent on the type of C&lt;$output&gt;.

=over 5

=item * A Buffer

If C&lt;$output&gt; is a buffer and C&lt;Append&gt; is enabled, all compressed data
will be append to the end of C&lt;$output&gt;. Otherwise C&lt;$output&gt; will be
cleared before any data is written to it.

=item * A Filename

If C&lt;$output&gt; is a filename and C&lt;Append&gt; is enabled, the file will be
opened in append mode. Otherwise the contents of the file, if any, will be
truncated before any compressed data is written to it.

=item * A Filehandle

If C&lt;$output&gt; is a filehandle, the file pointer will be positioned to the
end of the file via a call to C&lt;seek&gt; before any compressed data is written
to it.  Otherwise the file pointer will not be moved.

=back

This parameter defaults to 0.

=item C&lt;&lt; BlockSize100K =&gt; number &gt;&gt;

Specify the number of 100K blocks bzip2 uses during compression.

Valid values are from 1 to 9, where 9 is best compression.

The default is 1.

=item C&lt;&lt; WorkFactor =&gt; number &gt;&gt;

Specifies how much effort bzip2 should take before resorting to a slower
fallback compression algorithm.

Valid values range from 0 to 250, where 0 means use the default value 30.

The default is 0.

=item C&lt;&lt; Strict =&gt; 0|1 &gt;&gt;

This is a placeholder option.

=back

=head2 Examples

TODO

=head1 Methods

=head2 print

Usage is

    $z-&gt;print($data)
    print $z $data

Compresses and outputs the contents of the C&lt;$data&gt; parameter. This
has the same behaviour as the C&lt;print&gt; built-in.

Returns true if successful.

=head2 printf

Usage is

    $z-&gt;printf($format, $data)
    printf $z $format, $data

Compresses and outputs the contents of the C&lt;$data&gt; parameter.

Returns true if successful.

=head2 syswrite

Usage is

    $z-&gt;syswrite $data
    $z-&gt;syswrite $data, $length
    $z-&gt;syswrite $data, $length, $offset

Compresses and outputs the contents of the C&lt;$data&gt; parameter.

Returns the number of uncompressed bytes written, or C&lt;undef&gt; if
unsuccessful.

=head2 write

Usage is

    $z-&gt;write $data
    $z-&gt;write $data, $length
    $z-&gt;write $data, $length, $offset

Compresses and outputs the contents of the C&lt;$data&gt; parameter.

Returns the number of uncompressed bytes written, or C&lt;undef&gt; if
unsuccessful.

=head2 flush

Usage is

    $z-&gt;flush;

Flushes any pending compressed data to the output file/buffer.

TODO

Returns true on success.

=head2 tell

Usage is

    $z-&gt;tell()
    tell $z

Returns the uncompressed file offset.

=head2 eof

Usage is

    $z-&gt;eof();
    eof($z);

Returns true if the C&lt;close&gt; method has been called.

=head2 seek

    $z-&gt;seek($position, $whence);
    seek($z, $position, $whence);

Provides a sub-set of the C&lt;seek&gt; functionality, with the restriction
that it is only legal to seek forward in the output file/buffer.
It is a fatal error to attempt to seek backward.

Empty parts of the file/buffer will have NULL (0x00) bytes written to them.

The C&lt;$whence&gt; parameter takes one the usual values, namely SEEK_SET,
SEEK_CUR or SEEK_END.

Returns 1 on success, 0 on failure.

=head2 binmode

Usage is

    $z-&gt;binmode
    binmode $z ;

This is a noop provided for completeness.

=head2 opened

    $z-&gt;opened()

Returns true if the object currently refers to a opened file/buffer.

=head2 autoflush

    my $prev = $z-&gt;autoflush()
    my $prev = $z-&gt;autoflush(EXPR)

If the C&lt;$z&gt; object is associated with a file or a filehandle, this method
returns the current autoflush setting for the underlying filehandle. If
C&lt;EXPR&gt; is present, and is non-zero, it will enable flushing after every
write/print operation.

If C&lt;$z&gt; is associated with a buffer, this method has no effect and always
returns C&lt;undef&gt;.

B&lt;Note&gt; that the special variable C&lt;$|&gt; B&lt;cannot&gt; be used to set or
retrieve the autoflush setting.

=head2 input_line_number

    $z-&gt;input_line_number()
    $z-&gt;input_line_number(EXPR)

This method always returns C&lt;undef&gt; when compressing.

=head2 fileno

    $z-&gt;fileno()
    fileno($z)

If the C&lt;$z&gt; object is associated with a file or a filehandle, C&lt;fileno&gt;
will return the underlying file descriptor. Once the C&lt;close&gt; method is
called C&lt;fileno&gt; will return C&lt;undef&gt;.

If the C&lt;$z&gt; object is associated with a buffer, this method will return
C&lt;undef&gt;.

=head2 close

    $z-&gt;close() ;
    close $z ;

Flushes any pending compressed data and then closes the output file/buffer.

For most versions of Perl this method will be automatically invoked if
the IO::Compress::Bzip2 object is destroyed (either explicitly or by the
variable with the reference to the object going out of scope). The
exceptions are Perl versions 5.005 through 5.00504 and 5.8.0. In
these cases, the C&lt;close&gt; method will be called automatically, but
not until global destruction of all live objects when the program is
terminating.

Therefore, if you want your scripts to be able to run on all versions
of Perl, you should call C&lt;close&gt; explicitly and not rely on automatic
closing.

Returns true on success, otherwise 0.

If the C&lt;AutoClose&gt; option has been enabled when the IO::Compress::Bzip2
object was created, and the object is associated with a file, the
underlying file will also be closed.

=head2 newStream([OPTS])

Usage is

    $z-&gt;newStream( [OPTS] )

Closes the current compressed data stream and starts a new one.

OPTS consists of any of the options that are available when creating
the C&lt;$z&gt; object.

See the L&lt;/"Constructor Options"&gt; section for more details.

=head1 Importing

No symbolic constants are required by IO::Compress::Bzip2 at present.

=over 5

=item :all

Imports C&lt;bzip2&gt; and C&lt;$Bzip2Error&gt;.
Same as doing this

    use IO::Compress::Bzip2 qw(bzip2 $Bzip2Error) ;

=back

=head1 EXAMPLES

=head2 Apache::GZip Revisited

See L&lt;IO::Compress::FAQ|IO::Compress::FAQ/"Apache::GZip Revisited"&gt;

=head2 Working with Net::FTP

See L&lt;IO::Compress::FAQ|IO::Compress::FAQ/"Compressed files and Net::FTP"&gt;

=head1 SUPPORT

General feedback/questions/bug reports should be sent to
L&lt;https://github.com/pmqs/IO-Compress/issues&gt; (preferred) or
L&lt;https://rt.cpan.org/Public/Dist/Display.html?Name=IO-Compress&gt;.

=head1 SEE ALSO

L&lt;Compress::Zlib&gt;, L&lt;IO::Compress::Gzip&gt;, L&lt;IO::Uncompress::Gunzip&gt;, L&lt;IO::Compress::Deflate&gt;, L&lt;IO::Uncompress::Inflate&gt;, L&lt;IO::Compress::RawDeflate&gt;, L&lt;IO::Uncompress::RawInflate&gt;, L&lt;IO::Uncompress::Bunzip2&gt;, L&lt;IO::Compress::Lzma&gt;, L&lt;IO::Uncompress::UnLzma&gt;, L&lt;IO::Compress::Xz&gt;, L&lt;IO::Uncompress::UnXz&gt;, L&lt;IO::Compress::Lzip&gt;, L&lt;IO::Uncompress::UnLzip&gt;, L&lt;IO::Compress::Lzop&gt;, L&lt;IO::Uncompress::UnLzop&gt;, L&lt;IO::Compress::Lzf&gt;, L&lt;IO::Uncompress::UnLzf&gt;, L&lt;IO::Compress::Zstd&gt;, L&lt;IO::Uncompress::UnZstd&gt;, L&lt;IO::Uncompress::AnyInflate&gt;, L&lt;IO::Uncompress::AnyUncompress&gt;

L&lt;IO::Compress::FAQ|IO::Compress::FAQ&gt;

L&lt;File::GlobMapper|File::GlobMapper&gt;, L&lt;Archive::Zip|Archive::Zip&gt;,
L&lt;Archive::Tar|Archive::Tar&gt;,
L&lt;IO::Zlib|IO::Zlib&gt;

The primary site for the bzip2 program is L&lt;https://sourceware.org/bzip2/&gt;.

See the module L&lt;Compress::Bzip2|Compress::Bzip2&gt;

=head1 AUTHOR

This module was written by Paul Marquess, C&lt;pmqs@cpan.org&gt;.

=head1 MODIFICATION HISTORY

See the Changes file.

=head1 COPYRIGHT AND LICENSE

Copyright (c) 2005-2023 Paul Marquess. All rights reserved.

This program is free software; you can redistribute it and/or
modify it under the same terms as Perl itself.
</pre></body></html>