<html><head><meta name="color-scheme" content="light dark"></head><body><pre style="word-wrap: break-word; white-space: pre-wrap;">package LWP::Protocol::ftp;

# Implementation of the ftp protocol (RFC 959). We let the Net::FTP
# package do all the dirty work.
use parent qw(LWP::Protocol);
use strict;

our $VERSION = '6.76';

use Carp            ();
use HTTP::Status    ();
use HTTP::Negotiate ();
use HTTP::Response  ();
use LWP::MediaTypes ();
use File::Listing   ();


{

    package # hide from PAUSE
        LWP::Protocol::MyFTP;

    use strict;
    use parent qw(Net::FTP);

    sub new {
        my $class = shift;

        my $self = $class-&gt;SUPER::new(@_) || return undef;

        my $mess = $self-&gt;message;    # welcome message
        $mess =~ s|\n.*||s;           # only first line left
        $mess =~ s|\s*ready\.?$||;

        # Make the version number more HTTP like
        $mess =~ s|\s*\(Version\s*|/| and $mess =~ s|\)$||;
        ${*$self}{myftp_server} = $mess;

        #$response-&gt;header("Server", $mess);

        $self;
    }

    sub http_server {
        my $self = shift;
        ${*$self}{myftp_server};
    }

    sub home {
        my $self = shift;
        my $old  = ${*$self}{myftp_home};
        if (@_) {
            ${*$self}{myftp_home} = shift;
        }
        $old;
    }

    sub go_home {
        my $self = shift;
        $self-&gt;cwd(${*$self}{myftp_home});
    }

    sub request_count {
        my $self = shift;
        ++${*$self}{myftp_reqcount};
    }

    sub ping {
        my $self = shift;
        return $self-&gt;go_home;
    }
}

sub _connect {
    my ($self, $host, $port, $user, $account, $password, $timeout) = @_;

    my $key;
    my $conn_cache = $self-&gt;{ua}{conn_cache};
    if ($conn_cache) {
        $key = "$host:$port:$user";
        $key .= ":$account" if defined($account);
        if (my $ftp = $conn_cache-&gt;withdraw("ftp", $key)) {
            if ($ftp-&gt;ping) {

                # save it again
                $conn_cache-&gt;deposit("ftp", $key, $ftp);
                return $ftp;
            }
        }
    }

    # try to make a connection
    my $ftp = LWP::Protocol::MyFTP-&gt;new(
        $host,
        Port      =&gt; $port,
        Timeout   =&gt; $timeout,
        LocalAddr =&gt; $self-&gt;{ua}{local_address},
    );

    # XXX Should be some what to pass on 'Passive' (header??)
    unless ($ftp) {
        $@ =~ s/^Net::FTP: //;
        return HTTP::Response-&gt;new(HTTP::Status::RC_INTERNAL_SERVER_ERROR, $@);
    }

    unless ($ftp-&gt;login($user, $password, $account)) {

        # Unauthorized.  Let's fake a RC_UNAUTHORIZED response
        my $mess = scalar($ftp-&gt;message);
        $mess =~ s/\n$//;
        my $res = HTTP::Response-&gt;new(HTTP::Status::RC_UNAUTHORIZED, $mess);
        $res-&gt;header("Server",           $ftp-&gt;http_server);
        $res-&gt;header("WWW-Authenticate", qq(Basic Realm="FTP login"));
        return $res;
    }

    my $home = $ftp-&gt;pwd;
    $ftp-&gt;home($home);

    $conn_cache-&gt;deposit("ftp", $key, $ftp) if $conn_cache;

    return $ftp;
}


sub request {
    my ($self, $request, $proxy, $arg, $size, $timeout) = @_;

    $size = 4096 unless $size;

    # check proxy
    if (defined $proxy) {
        return HTTP::Response-&gt;new(HTTP::Status::RC_BAD_REQUEST,
            'You can not proxy through the ftp');
    }

    my $url = $request-&gt;uri;
    if ($url-&gt;scheme ne 'ftp') {
        my $scheme = $url-&gt;scheme;
        return HTTP::Response-&gt;new(HTTP::Status::RC_INTERNAL_SERVER_ERROR,
            "LWP::Protocol::ftp::request called for '$scheme'");
    }

    # check method
    my $method = $request-&gt;method;

    unless ($method eq 'GET' || $method eq 'HEAD' || $method eq 'PUT') {
        return HTTP::Response-&gt;new(HTTP::Status::RC_BAD_REQUEST,
            'Library does not allow method ' . "$method for 'ftp:' URLs");
    }

    my $host     = $url-&gt;host;
    my $port     = $url-&gt;port;
    my $user     = $url-&gt;user;
    my $password = $url-&gt;password;

    # If a basic authorization header is present than we prefer these over
    # the username/password specified in the URL.
    {
        my ($u, $p) = $request-&gt;authorization_basic;
        if (defined $u) {
            $user     = $u;
            $password = $p;
        }
    }

    # We allow the account to be specified in the "Account" header
    my $account = $request-&gt;header('Account');

    my $ftp
        = $self-&gt;_connect($host, $port, $user, $account, $password, $timeout);
    return $ftp if ref($ftp) eq "HTTP::Response";    # ugh!

    # Create an initial response object
    my $response = HTTP::Response-&gt;new(HTTP::Status::RC_OK, "OK");
    $response-&gt;header(Server               =&gt; $ftp-&gt;http_server);
    $response-&gt;header('Client-Request-Num' =&gt; $ftp-&gt;request_count);
    $response-&gt;request($request);

    # Get &amp; fix the path
    my @path = grep {length} $url-&gt;path_segments;
    my $remote_file = pop(@path);
    $remote_file = '' unless defined $remote_file;

    my $type;
    if (ref $remote_file) {
        my @params;
        ($remote_file, @params) = @$remote_file;
        for (@params) {
            $type = $_ if s/^type=//;
        }
    }

    if ($type &amp;&amp; $type eq 'a') {
        $ftp-&gt;ascii;
    }
    else {
        $ftp-&gt;binary;
    }

    for (@path) {
        unless ($ftp-&gt;cwd($_)) {
            return HTTP::Response-&gt;new(HTTP::Status::RC_NOT_FOUND,
                "Can't chdir to $_");
        }
    }

    if ($method eq 'GET' || $method eq 'HEAD') {
        if (my $mod_time = $ftp-&gt;mdtm($remote_file)) {
            $response-&gt;last_modified($mod_time);
            if (my $ims = $request-&gt;if_modified_since) {
                if ($mod_time &lt;= $ims) {
                    $response-&gt;code(HTTP::Status::RC_NOT_MODIFIED);
                    $response-&gt;message("Not modified");
                    return $response;
                }
            }
        }

        # We'll use this later to abort the transfer if necessary.
        # if $max_size is defined, we need to abort early. Otherwise, it's
        # a normal transfer
        my $max_size = undef;

        # Set resume location, if the client requested it
        if ($request-&gt;header('Range') &amp;&amp; $ftp-&gt;supported('REST')) {
            my $range_info = $request-&gt;header('Range');

            # Change bytes=2772992-6781209 to just 2772992
            my ($start_byte, $end_byte) = $range_info =~ /.*=\s*(\d+)-(\d+)?/;
            if (defined $start_byte &amp;&amp; !defined $end_byte) {

                # open range -- only the start is specified

                $ftp-&gt;restart($start_byte);

                # don't define $max_size, we don't want to abort early
            }
            elsif (defined $start_byte
                &amp;&amp; defined $end_byte
                &amp;&amp; $start_byte &gt;= 0
                &amp;&amp; $end_byte &gt;= $start_byte)
            {

                $ftp-&gt;restart($start_byte);
                $max_size = $end_byte - $start_byte;
            }
            else {

                return HTTP::Response-&gt;new(HTTP::Status::RC_BAD_REQUEST,
                    'Incorrect syntax for Range request');
            }
        }
        elsif ($request-&gt;header('Range') &amp;&amp; !$ftp-&gt;supported('REST')) {
            return HTTP::Response-&gt;new(HTTP::Status::RC_NOT_IMPLEMENTED,
                "Server does not support resume."
            );
        }

        my $data;    # the data handle
        if (length($remote_file) and $data = $ftp-&gt;retr($remote_file)) {
            my ($type, @enc) = LWP::MediaTypes::guess_media_type($remote_file);
            $response-&gt;header('Content-Type', $type) if $type;
            for (@enc) {
                $response-&gt;push_header('Content-Encoding', $_);
            }
            my $mess = $ftp-&gt;message;
            if ($mess =~ /\((\d+)\s+bytes\)/) {
                $response-&gt;header('Content-Length', "$1");
            }

            if ($method ne 'HEAD') {

                # Read data from server
                $response = $self-&gt;collect(
                    $arg,
                    $response,
                    sub {
                        my $content = '';
                        my $result = $data-&gt;read($content, $size);

                        # Stop early if we need to.
                        if (defined $max_size) {

                        # We need an interface to Net::FTP::dataconn for getting
                        # the number of bytes already read
                            my $bytes_received = $data-&gt;bytes_read();

                           # We were already over the limit. (Should only happen
                           # once at the end.)
                            if ($bytes_received - length($content) &gt; $max_size)
                            {
                                $content = '';
                            }

                            # We just went over the limit
                            elsif ($bytes_received &gt; $max_size) {

                                # Trim content
                                $content = substr($content, 0,
                                    $max_size
                                        - ($bytes_received - length($content)));
                            }

                            # We're under the limit
                            else {
                            }
                        }

                        return \$content;
                    }
                );
            }

            # abort is needed for HEAD, it's == close if the transfer has
            # already completed.
            unless ($data-&gt;abort) {

                # Something did not work too well.  Note that we treat
                # responses to abort() with code 0 in case of HEAD as ok
                # (at least wu-ftpd 2.6.1(1) does that).
                if ($method ne 'HEAD' || $ftp-&gt;code != 0) {
                    $response-&gt;code(HTTP::Status::RC_INTERNAL_SERVER_ERROR);
                    $response-&gt;message("FTP close response: "
                            . $ftp-&gt;code . " "
                            . $ftp-&gt;message);
                }
            }
        }
        elsif (!length($remote_file) || ($ftp-&gt;code &gt;= 400 &amp;&amp; $ftp-&gt;code &lt; 600))
        {
            # not a plain file, try to list instead
            if (length($remote_file) &amp;&amp; !$ftp-&gt;cwd($remote_file)) {
                return HTTP::Response-&gt;new(HTTP::Status::RC_NOT_FOUND,
                    "File '$remote_file' not found"
                );
            }

            # It should now be safe to try to list the directory
            my @lsl = $ftp-&gt;dir;

            # Try to figure out if the user want us to convert the
            # directory listing to HTML.
            my @variants = (
                ['html', 0.60, 'text/html'],
                ['dir',  1.00, 'text/ftp-dir-listing']
            );

            #$HTTP::Negotiate::DEBUG=1;
            my $prefer = HTTP::Negotiate::choose(\@variants, $request);

            my $content = '';

            if (!defined($prefer)) {
                return HTTP::Response-&gt;new(HTTP::Status::RC_NOT_ACCEPTABLE,
                    "Neither HTML nor directory listing wanted");
            }
            elsif ($prefer eq 'html') {
                $response-&gt;header('Content-Type' =&gt; 'text/html');
                $content = "&lt;HEAD&gt;&lt;TITLE&gt;File Listing&lt;/TITLE&gt;\n";
                my $base = $request-&gt;uri-&gt;clone;
                my $path = $base-&gt;path;
                $base-&gt;path("$path/") unless $path =~ m|/$|;
                $content .= qq(&lt;BASE HREF="$base"&gt;\n&lt;/HEAD&gt;\n);
                $content .= "&lt;BODY&gt;\n&lt;UL&gt;\n";
                for (File::Listing::parse_dir(\@lsl, 'GMT')) {
                    my ($name, $type, $size, $mtime, $mode) = @$_;
                    $content .= qq(  &lt;LI&gt; &lt;a href="$name"&gt;$name&lt;/a&gt;);
                    $content .= " $size bytes" if $type eq 'f';
                    $content .= "\n";
                }
                $content .= "&lt;/UL&gt;&lt;/body&gt;\n";
            }
            else {
                $response-&gt;header('Content-Type', 'text/ftp-dir-listing');
                $content = join("\n", @lsl, '');
            }

            $response-&gt;header('Content-Length', length($content));

            if ($method ne 'HEAD') {
                $response = $self-&gt;collect_once($arg, $response, $content);
            }
        }
        else {
            my $res = HTTP::Response-&gt;new(HTTP::Status::RC_BAD_REQUEST,
                "FTP return code " . $ftp-&gt;code);
            $res-&gt;content_type("text/plain");
            $res-&gt;content($ftp-&gt;message);
            return $res;
        }
    }
    elsif ($method eq 'PUT') {

        # method must be PUT
        unless (length($remote_file)) {
            return HTTP::Response-&gt;new(HTTP::Status::RC_BAD_REQUEST,
                "Must have a file name to PUT to"
            );
        }
        my $data;
        if ($data = $ftp-&gt;stor($remote_file)) {
            my $content = $request-&gt;content;
            my $bytes   = 0;
            if (defined $content) {
                if (ref($content) eq 'SCALAR') {
                    $bytes = $data-&gt;write($$content, length($$content));
                }
                elsif (ref($content) eq 'CODE') {
                    my ($buf, $n);
                    while (length($buf = &amp;$content)) {
                        $n = $data-&gt;write($buf, length($buf));
                        last unless $n;
                        $bytes += $n;
                    }
                }
                elsif (!ref($content)) {
                    if (defined $content &amp;&amp; length($content)) {
                        $bytes = $data-&gt;write($content, length($content));
                    }
                }
                else {
                    die "Bad content";
                }
            }
            $data-&gt;close;

            $response-&gt;code(HTTP::Status::RC_CREATED);
            $response-&gt;header('Content-Type', 'text/plain');
            $response-&gt;content("$bytes bytes stored as $remote_file on $host\n")

        }
        else {
            my $res = HTTP::Response-&gt;new(HTTP::Status::RC_BAD_REQUEST,
                "FTP return code " . $ftp-&gt;code);
            $res-&gt;content_type("text/plain");
            $res-&gt;content($ftp-&gt;message);
            return $res;
        }
    }
    else {
        return HTTP::Response-&gt;new(HTTP::Status::RC_BAD_REQUEST,
            "Illegal method $method");
    }

    $response;
}

1;

__END__

# This is what RFC 1738 has to say about FTP access:
# --------------------------------------------------
#
# 3.2. FTP
#
#    The FTP URL scheme is used to designate files and directories on
#    Internet hosts accessible using the FTP protocol (RFC959).
#
#    A FTP URL follow the syntax described in Section 3.1.  If :&lt;port&gt; is
#    omitted, the port defaults to 21.
#
# 3.2.1. FTP Name and Password
#
#    A user name and password may be supplied; they are used in the ftp
#    "USER" and "PASS" commands after first making the connection to the
#    FTP server.  If no user name or password is supplied and one is
#    requested by the FTP server, the conventions for "anonymous" FTP are
#    to be used, as follows:
#
#         The user name "anonymous" is supplied.
#
#         The password is supplied as the Internet e-mail address
#         of the end user accessing the resource.
#
#    If the URL supplies a user name but no password, and the remote
#    server requests a password, the program interpreting the FTP URL
#    should request one from the user.
#
# 3.2.2. FTP url-path
#
#    The url-path of a FTP URL has the following syntax:
#
#         &lt;cwd1&gt;/&lt;cwd2&gt;/.../&lt;cwdN&gt;/&lt;name&gt;;type=&lt;typecode&gt;
#
#    Where &lt;cwd1&gt; through &lt;cwdN&gt; and &lt;name&gt; are (possibly encoded) strings
#    and &lt;typecode&gt; is one of the characters "a", "i", or "d".  The part
#    ";type=&lt;typecode&gt;" may be omitted. The &lt;cwdx&gt; and &lt;name&gt; parts may be
#    empty. The whole url-path may be omitted, including the "/"
#    delimiting it from the prefix containing user, password, host, and
#    port.
#
#    The url-path is interpreted as a series of FTP commands as follows:
#
#       Each of the &lt;cwd&gt; elements is to be supplied, sequentially, as the
#       argument to a CWD (change working directory) command.
#
#       If the typecode is "d", perform a NLST (name list) command with
#       &lt;name&gt; as the argument, and interpret the results as a file
#       directory listing.
#
#       Otherwise, perform a TYPE command with &lt;typecode&gt; as the argument,
#       and then access the file whose name is &lt;name&gt; (for example, using
#       the RETR command.)
#
#    Within a name or CWD component, the characters "/" and ";" are
#    reserved and must be encoded. The components are decoded prior to
#    their use in the FTP protocol.  In particular, if the appropriate FTP
#    sequence to access a particular file requires supplying a string
#    containing a "/" as an argument to a CWD or RETR command, it is
#    necessary to encode each "/".
#
#    For example, the URL &lt;URL:ftp://myname@host.dom/%2Fetc/motd&gt; is
#    interpreted by FTP-ing to "host.dom", logging in as "myname"
#    (prompting for a password if it is asked for), and then executing
#    "CWD /etc" and then "RETR motd". This has a different meaning from
#    &lt;URL:ftp://myname@host.dom/etc/motd&gt; which would "CWD etc" and then
#    "RETR motd"; the initial "CWD" might be executed relative to the
#    default directory for "myname". On the other hand,
#    &lt;URL:ftp://myname@host.dom//etc/motd&gt;, would "CWD " with a null
#    argument, then "CWD etc", and then "RETR motd".
#
#    FTP URLs may also be used for other operations; for example, it is
#    possible to update a file on a remote file server, or infer
#    information about it from the directory listings. The mechanism for
#    doing so is not spelled out here.
#
# 3.2.3. FTP Typecode is Optional
#
#    The entire ;type=&lt;typecode&gt; part of a FTP URL is optional. If it is
#    omitted, the client program interpreting the URL must guess the
#    appropriate mode to use. In general, the data content type of a file
#    can only be guessed from the name, e.g., from the suffix of the name;
#    the appropriate type code to be used for transfer of the file can
#    then be deduced from the data content of the file.
#
# 3.2.4 Hierarchy
#
#    For some file systems, the "/" used to denote the hierarchical
#    structure of the URL corresponds to the delimiter used to construct a
#    file name hierarchy, and thus, the filename will look similar to the
#    URL path. This does NOT mean that the URL is a Unix filename.
#
# 3.2.5. Optimization
#
#    Clients accessing resources via FTP may employ additional heuristics
#    to optimize the interaction. For some FTP servers, for example, it
#    may be reasonable to keep the control connection open while accessing
#    multiple URLs from the same server. However, there is no common
#    hierarchical model to the FTP protocol, so if a directory change
#    command has been given, it is impossible in general to deduce what
#    sequence should be given to navigate to another directory for a
#    second retrieval, if the paths are different.  The only reliable
#    algorithm is to disconnect and reestablish the control connection.
</pre></body></html>