<html><head><meta name="color-scheme" content="light dark"></head><body><pre style="word-wrap: break-word; white-space: pre-wrap;"># Copyright Â© 2010-2011 RaphaÃ«l Hertzog &lt;hertzog@debian.org&gt;
# Copyright Â© 2012-2022 Guillem Jover &lt;guillem@debian.org&gt;
#
# This program is free software; you can redistribute it and/or modify
# it under the terms of the GNU General Public License as published by
# the Free Software Foundation; either version 2 of the License, or
# (at your option) any later version.
#
# This program is distributed in the hope that it will be useful,
# but WITHOUT ANY WARRANTY; without even the implied warranty of
# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
# GNU General Public License for more details.
#
# You should have received a copy of the GNU General Public License
# along with this program.  If not, see &lt;https://www.gnu.org/licenses/&gt;.

=encoding utf8

=head1 NAME

Dpkg::BuildFlags - query build flags

=head1 DESCRIPTION

This class is used by dpkg-buildflags and can be used
to query the same information.

=cut

package Dpkg::BuildFlags 1.06;

use strict;
use warnings;

use Dpkg ();
use Dpkg::Gettext;
use Dpkg::BuildEnv;
use Dpkg::ErrorHandling;
use Dpkg::Vendor qw(run_vendor_hook);

=head1 METHODS

=over 4

=item $bf = Dpkg::BuildFlags-&gt;new()

Create a new Dpkg::BuildFlags object. It will be initialized based
on the value of several configuration files and environment variables.

If the option B&lt;vendor_defaults&gt; is set to false, then no vendor defaults are
initialized (it defaults to true).

=cut

sub new {
    my ($this, %opts) = @_;
    my $class = ref($this) || $this;

    my $self = {
    };
    bless $self, $class;

    $opts{vendor_defaults} //= 1;

    if ($opts{vendor_defaults}) {
        $self-&gt;load_vendor_defaults();
    } else {
        $self-&gt;_init_vendor_defaults();
    }
    return $self;
}

sub _init_vendor_defaults {
    my $self = shift;

    my @flags = qw(
        ASFLAGS
        ASFLAGS_FOR_BUILD
        CPPFLAGS
        CPPFLAGS_FOR_BUILD
        CFLAGS
        CFLAGS_FOR_BUILD
        CXXFLAGS
        CXXFLAGS_FOR_BUILD
        OBJCFLAGS
        OBJCFLAGS_FOR_BUILD
        OBJCXXFLAGS
        OBJCXXFLAGS_FOR_BUILD
        DFLAGS
        DFLAGS_FOR_BUILD
        FFLAGS
        FFLAGS_FOR_BUILD
        FCFLAGS
        FCFLAGS_FOR_BUILD
        LDFLAGS
        LDFLAGS_FOR_BUILD
    );

    $self-&gt;{features} = {};
    $self-&gt;{builtins} = {};
    $self-&gt;{optvals} = {};
    $self-&gt;{flags} = { map { $_ =&gt; '' } @flags };
    $self-&gt;{origin} = { map { $_ =&gt; 'vendor' } @flags };
    $self-&gt;{maintainer} = { map { $_ =&gt; 0 } @flags };
}

=item $bf-&gt;load_vendor_defaults()

Reset the flags stored to the default set provided by the vendor.

=cut

sub load_vendor_defaults {
    my $self = shift;

    $self-&gt;_init_vendor_defaults();

    # The vendor hook will add the feature areas build flags.
    run_vendor_hook('update-buildflags', $self);
}

=item $bf-&gt;load_system_config()

Update flags from the system configuration.

=cut

sub load_system_config {
    my $self = shift;

    $self-&gt;update_from_conffile("$Dpkg::CONFDIR/buildflags.conf", 'system');
}

=item $bf-&gt;load_user_config()

Update flags from the user configuration.

=cut

sub load_user_config {
    my $self = shift;

    my $confdir = $ENV{XDG_CONFIG_HOME};
    $confdir ||= $ENV{HOME} . '/.config' if length $ENV{HOME};
    if (length $confdir) {
        $self-&gt;update_from_conffile("$confdir/dpkg/buildflags.conf", 'user');
    }
}

=item $bf-&gt;load_environment_config()

Update flags based on user directives stored in the environment. See
L&lt;dpkg-buildflags(1)&gt; for details.

=cut

sub load_environment_config {
    my $self = shift;

    foreach my $flag (keys %{$self-&gt;{flags}}) {
	my $envvar = 'DEB_' . $flag . '_SET';
	if (Dpkg::BuildEnv::has($envvar)) {
	    $self-&gt;set($flag, Dpkg::BuildEnv::get($envvar), 'env');
	}
	$envvar = 'DEB_' . $flag . '_STRIP';
	if (Dpkg::BuildEnv::has($envvar)) {
	    $self-&gt;strip($flag, Dpkg::BuildEnv::get($envvar), 'env');
	}
	$envvar = 'DEB_' . $flag . '_APPEND';
	if (Dpkg::BuildEnv::has($envvar)) {
	    $self-&gt;append($flag, Dpkg::BuildEnv::get($envvar), 'env');
	}
	$envvar = 'DEB_' . $flag . '_PREPEND';
	if (Dpkg::BuildEnv::has($envvar)) {
	    $self-&gt;prepend($flag, Dpkg::BuildEnv::get($envvar), 'env');
	}
    }
}

=item $bf-&gt;load_maintainer_config()

Update flags based on maintainer directives stored in the environment. See
L&lt;dpkg-buildflags(1)&gt; for details.

=cut

sub load_maintainer_config {
    my $self = shift;

    foreach my $flag (keys %{$self-&gt;{flags}}) {
	my $envvar = 'DEB_' . $flag . '_MAINT_SET';
	if (Dpkg::BuildEnv::has($envvar)) {
	    $self-&gt;set($flag, Dpkg::BuildEnv::get($envvar), undef, 1);
	}
	$envvar = 'DEB_' . $flag . '_MAINT_STRIP';
	if (Dpkg::BuildEnv::has($envvar)) {
	    $self-&gt;strip($flag, Dpkg::BuildEnv::get($envvar), undef, 1);
	}
	$envvar = 'DEB_' . $flag . '_MAINT_APPEND';
	if (Dpkg::BuildEnv::has($envvar)) {
	    $self-&gt;append($flag, Dpkg::BuildEnv::get($envvar), undef, 1);
	}
	$envvar = 'DEB_' . $flag . '_MAINT_PREPEND';
	if (Dpkg::BuildEnv::has($envvar)) {
	    $self-&gt;prepend($flag, Dpkg::BuildEnv::get($envvar), undef, 1);
	}
    }
}


=item $bf-&gt;load_config()

Call successively load_system_config(), load_user_config(),
load_environment_config() and load_maintainer_config() to update the
default build flags defined by the vendor.

=cut

sub load_config {
    my $self = shift;

    $self-&gt;load_system_config();
    $self-&gt;load_user_config();
    $self-&gt;load_environment_config();
    $self-&gt;load_maintainer_config();
}

=item $bf-&gt;unset($flag)

Unset the build flag $flag, so that it will not be known anymore.

=cut

sub unset {
    my ($self, $flag) = @_;

    delete $self-&gt;{flags}-&gt;{$flag};
    delete $self-&gt;{origin}-&gt;{$flag};
    delete $self-&gt;{maintainer}-&gt;{$flag};
}

=item $bf-&gt;set($flag, $value, $source, $maint)

Update the build flag $flag with value $value and record its origin as
$source (if defined). Record it as maintainer modified if $maint is
defined and true.

=cut

sub set {
    my ($self, $flag, $value, $src, $maint) = @_;
    $self-&gt;{flags}-&gt;{$flag} = $value;
    $self-&gt;{origin}-&gt;{$flag} = $src if defined $src;
    $self-&gt;{maintainer}-&gt;{$flag} = $maint if $maint;
}

=item $bf-&gt;set_feature($area, $feature, $enabled)

Update the boolean state of whether a specific feature within a known
feature area has been enabled. The only currently known feature areas
are "future", "qa", "sanitize", "optimize", "hardening" and "reproducible".

=cut

sub set_feature {
    my ($self, $area, $feature, $enabled) = @_;
    $self-&gt;{features}{$area}{$feature} = $enabled;
}

=item $bf-&gt;get_feature($area, $feature)

Returns the value for the given feature within a known feature area.
This is relevant for builtin features where the feature has a ternary
state of true, false and undef, and where the latter cannot be retrieved
with use_feature().

=cut

sub get_feature {
    my ($self, $area, $feature) = @_;

    return if ! $self-&gt;has_features($area);
    return $self-&gt;{features}{$area}{$feature};
}

=item $bf-&gt;use_feature($area, $feature)

Returns true if the given feature within a known feature areas has been
enabled, and false otherwise.
The only currently recognized feature areas are "future", "qa", "sanitize",
"optimize", "hardening" and "reproducible".

=cut

sub use_feature {
    my ($self, $area, $feature) = @_;

    return 0 if ! $self-&gt;has_features($area);
    return 0 if ! $self-&gt;{features}{$area}{$feature};
    return 1;
}

=item $bf-&gt;set_builtin($area, $feature, $enabled)

Update the boolean state of whether a specific feature within a known
feature area is handled (even if only in some architectures) as a builtin
default by the compiler.

=cut

sub set_builtin {
    my ($self, $area, $feature, $enabled) = @_;
    $self-&gt;{builtins}{$area}{$feature} = $enabled;
}

=item $bf-&gt;get_builtins($area)

Return, for the given area, a hash with keys as feature names, and values
as booleans indicating whether the feature is handled as a builtin default
by the compiler or not. Only features that might be handled as builtins on
some architectures are returned as part of the hash. Missing features mean
they are currently never handled as builtins by the compiler.

=cut

sub get_builtins {
    my ($self, $area) = @_;
    return if ! exists $self-&gt;{builtins}{$area};
    return %{$self-&gt;{builtins}{$area}};
}

=item $bf-&gt;set_option_value($option, $value)

B&lt;Private&gt; method to set the value of a build option.
Do not use outside of the dpkg project.

=cut

sub set_option_value {
    my ($self, $option, $value) = @_;

    $self-&gt;{optvals}{$option} = $value;
}

=item $bf-&gt;get_option_value($option)

B&lt;Private&gt; method to get the value of a build option.
Do not use outside of the dpkg project.

=cut

sub get_option_value {
    my ($self, $option) = @_;

    return $self-&gt;{optvals}{$option};
}

=item $bf-&gt;strip($flag, $value, $source, $maint)

Update the build flag $flag by stripping the flags listed in $value and
record its origin as $source (if defined). Record it as maintainer modified
if $maint is defined and true.

=cut

sub strip {
    my ($self, $flag, $value, $src, $maint) = @_;

    my %strip = map { $_ =&gt; 1 } split /\s+/, $value;

    $self-&gt;{flags}-&gt;{$flag} = join q{ }, grep {
        ! exists $strip{$_}
    } split q{ }, $self-&gt;{flags}{$flag};
    $self-&gt;{origin}-&gt;{$flag} = $src if defined $src;
    $self-&gt;{maintainer}-&gt;{$flag} = $maint if $maint;
}

=item $bf-&gt;append($flag, $value, $source, $maint)

Append the options listed in $value to the current value of the flag $flag.
Record its origin as $source (if defined). Record it as maintainer modified
if $maint is defined and true.

=cut

sub append {
    my ($self, $flag, $value, $src, $maint) = @_;
    if (length($self-&gt;{flags}-&gt;{$flag})) {
        $self-&gt;{flags}-&gt;{$flag} .= " $value";
    } else {
        $self-&gt;{flags}-&gt;{$flag} = $value;
    }
    $self-&gt;{origin}-&gt;{$flag} = $src if defined $src;
    $self-&gt;{maintainer}-&gt;{$flag} = $maint if $maint;
}

=item $bf-&gt;prepend($flag, $value, $source, $maint)

Prepend the options listed in $value to the current value of the flag $flag.
Record its origin as $source (if defined). Record it as maintainer modified
if $maint is defined and true.

=cut

sub prepend {
    my ($self, $flag, $value, $src, $maint) = @_;
    if (length($self-&gt;{flags}-&gt;{$flag})) {
        $self-&gt;{flags}-&gt;{$flag} = "$value " . $self-&gt;{flags}-&gt;{$flag};
    } else {
        $self-&gt;{flags}-&gt;{$flag} = $value;
    }
    $self-&gt;{origin}-&gt;{$flag} = $src if defined $src;
    $self-&gt;{maintainer}-&gt;{$flag} = $maint if $maint;
}


=item $bf-&gt;update_from_conffile($file, $source)

Update the current build flags based on the configuration directives
contained in $file. See L&lt;dpkg-buildflags(1)&gt; for the format of the directives.

$source is the origin recorded for any build flag set or modified.

=cut

sub update_from_conffile {
    my ($self, $file, $src) = @_;
    local $_;

    return unless -e $file;
    open(my $conf_fh, '&lt;', $file) or syserr(g_('cannot read %s'), $file);
    while (&lt;$conf_fh&gt;) {
        chomp;
        next if /^\s*#/; # Skip comments
        next if /^\s*$/; # Skip empty lines
        if (/^(append|prepend|set|strip)\s+(\S+)\s+(\S.*\S)\s*$/i) {
            my ($op, $flag, $value) = ($1, $2, $3);
            unless (exists $self-&gt;{flags}-&gt;{$flag}) {
                warning(g_('line %d of %s mentions unknown flag %s'), $., $file, $flag);
                $self-&gt;{flags}-&gt;{$flag} = '';
            }
            if (lc($op) eq 'set') {
                $self-&gt;set($flag, $value, $src);
            } elsif (lc($op) eq 'strip') {
                $self-&gt;strip($flag, $value, $src);
            } elsif (lc($op) eq 'append') {
                $self-&gt;append($flag, $value, $src);
            } elsif (lc($op) eq 'prepend') {
                $self-&gt;prepend($flag, $value, $src);
            }
        } else {
            warning(g_('line %d of %s is invalid, it has been ignored'), $., $file);
        }
    }
    close($conf_fh);
}

=item $bf-&gt;get($flag)

Return the value associated to the flag. It might be undef if the
flag doesn't exist.

=cut

sub get {
    my ($self, $key) = @_;
    return $self-&gt;{flags}{$key};
}

=item $bf-&gt;get_feature_areas()

Return the feature areas (i.e. the area values has_features will return
true for).

=cut

sub get_feature_areas {
    my $self = shift;

    return keys %{$self-&gt;{features}};
}

=item $bf-&gt;get_features($area)

Return, for the given area, a hash with keys as feature names, and values
as booleans indicating whether the feature is enabled or not.

=cut

sub get_features {
    my ($self, $area) = @_;
    return %{$self-&gt;{features}{$area}};
}

=item $bf-&gt;get_origin($flag)

Return the origin associated to the flag. It might be undef if the
flag doesn't exist.

=cut

sub get_origin {
    my ($self, $key) = @_;
    return $self-&gt;{origin}{$key};
}

=item $bf-&gt;is_maintainer_modified($flag)

Return true if the flag is modified by the maintainer.

=cut

sub is_maintainer_modified {
    my ($self, $key) = @_;
    return $self-&gt;{maintainer}{$key};
}

=item $bf-&gt;has_features($area)

Returns true if the given area of features is known, and false otherwise.
The only currently recognized feature areas are "future", "qa", "sanitize",
"optimize", "hardening" and "reproducible".

=cut

sub has_features {
    my ($self, $area) = @_;
    return exists $self-&gt;{features}{$area};
}

=item $bf-&gt;has($option)

Returns a boolean indicating whether the flags exists in the object.

=cut

sub has {
    my ($self, $key) = @_;
    return exists $self-&gt;{flags}{$key};
}

=item @flags = $bf-&gt;list()

Returns the list of flags stored in the object.

=cut

sub list {
    my $self = shift;
    my @list = sort keys %{$self-&gt;{flags}};
    return @list;
}

=back

=head1 CHANGES

=head2 Version 1.06 (dpkg 1.21.15)

New method: $bf-&gt;get_feature().

=head2 Version 1.05 (dpkg 1.21.14)

New option: 'vendor_defaults' in new().

New methods: $bf-&gt;load_vendor_defaults(), $bf-&gt;use_feature(),
$bf-&gt;set_builtin(), $bf-&gt;get_builtins().

=head2 Version 1.04 (dpkg 1.20.0)

New method: $bf-&gt;unset().

=head2 Version 1.03 (dpkg 1.16.5)

New method: $bf-&gt;get_feature_areas() to list possible values for
$bf-&gt;get_features.

New method $bf-&gt;is_maintainer_modified() and new optional parameter to
$bf-&gt;set(), $bf-&gt;append(), $bf-&gt;prepend(), $bf-&gt;strip().

=head2 Version 1.02 (dpkg 1.16.2)

New methods: $bf-&gt;get_features(), $bf-&gt;has_features(), $bf-&gt;set_feature().

=head2 Version 1.01 (dpkg 1.16.1)

New method: $bf-&gt;prepend() very similar to append(). Implement support of
the prepend operation everywhere.

New method: $bf-&gt;load_maintainer_config() that update the build flags
based on the package maintainer directives.

=head2 Version 1.00 (dpkg 1.15.7)

Mark the module as public.

=cut

1;
</pre></body></html>